Enregistrer un fichier .xlsm en macro complémentaire .xlam par VBA

Version imprimable

28/05/2020, 14h57
PierreE_67207

Enregistrer un fichier .xlsm en macro complémentaire .xlam par VBA

Bonjour,

Tout est dit dans le texte, je recherche désespéramment à enregistrer un fichier .XLSM en .XLAM par VBA, depuis ce même fichier .XLSM.

Les codes suivants ne fonctionnent visiblement pas :

Code:

ThisWorkbook.SaveAs Filename:="MACRO COMPLEMENTAIRES", FileFormat:="xlam

Code:

ThisWorkbook.SaveCopyAs Filename:="C:\Users\" & Environ("USERNAME") & "\AppData\Roaming\Microsoft\AddIns\MACRO COMPLEMENTAIRES.xlam"

Je ne trouve rien sur la toile, avez-vous une idée ?

Merci par avance,

PE
28/05/2020, 15h29
Menhir

Citation:

Les codes suivants ne fonctionnent visiblement pas :

Quels sont les symptômes de ce dysfonctionnement ?

Essaye ça :

Code:

ThisWorkbook.SaveAs Filename:=ThisWorkbook.Path & "\MACRO COMPLEMENTAIRES", FileFormat:=xlOpenXMLAddIn

Citation:

Je ne trouve rien sur la toile, avez-vous une idée ?

Le premier endroit où chercher une solution, c'est l'aide VBA.
Lire ça : https://docs.microsoft.com/fr-FR/off...ook.savecopyas

Bonjour Menhir,

C'est parfait merci !

Je n'avais pas trouvé l'information nécessaire pour définir un format .XLAM

Code:

FileFormat:=xlOpenXMLAddIn

J'ai donc ajusté comme ceci :
Code:

1 2 3 4 5 6 7 8 Dim CheminComplet As String: CheminComplet = "C:\Users\" & Environ("USERNAME") & "\AppData\Roaming\Microsoft\AddIns\MACRO COMPLEMENTAIRES PGI" '--> Si l'extension n'est pas XLAM, alors : If Mid(ThisWorkbook.FullNameURLEncoded, InStrRev(ThisWorkbook.FullNameURLEncoded, ".") + 1) <> "xlam" Then ThisWorkbook.SaveAs Filename:=CheminComplet, FileFormat:=xlOpenXMLAddIn End If
Maintenant il ne me reste plus qu'à trouver comment ajouter la macro complémentaire créée dans les compléments, la commande suivante :

Code:

Application.AddIns.Add(CheminComplet, True).Installed = True

m'apportant le message d'erreur suivant :

Citation:

"Impossible de lire la propriété Add de la classe AddIns"

28/05/2020, 19h53
laurent_ott

Pour importer un xlam, tu trouveras la réponse dans l'annexe 4 du tome 4, voir ma signature, (voir la 3eme façon).
Cordialement.
29/05/2020, 08h39
Menhir

Citation:

Envoyé par PierreE_67207

Maintenant il ne me reste plus qu'à trouver comment ajouter la macro complémentaire créée dans les compléments

Le plus simple est de placer le fichier dans le dossier XLOuvrir (ou XLStart suivant les versions) ou dans le répertoire définit dans Options > Options avancées > Général > "Au démarrage, ouvrir les fichiers du dossier". Le XLAM s'ouvrira automatiquement avec Excel.

Bonjour Menhir, laurent_ott,

Merci pour vos messages.

@Menhir, je vais distribuer un Add-In dans mon entreprise, et je souhaiterais ne pas avoir à transmettre une méthodologie pour son installation et ses mises-à-jour à venir, donc mon objectif est d'automatiser sa mise en place à l'ouverture d'un fichier d'installation.

@laurent_ott, impressionnant le travail effectué dans tes ouvrages ! j'ai parcouru l'annexe 4 du tome 4, et j'ai testé la méthode décrite. Si je comprends bien celle-ci consiste à installer une référence de VBProject. L'inconvénient, toujours si j'ai bien compris, c'est que dans ce cas ma référence est associé à un fichier donné et non pas à Excel, comme c'est le cas pour les compléments (ruban Développeur / Compléments)

Voici par conséquent mon code qui fonctionne à présent, et qui répond à mon besoin.
La procédure est appelée dans "Private Sub Workbook_Open" du classeur du futur Complément, enregistré en format .xlsm :
Code:

1 2 3 4 5 6 7 8 9 10 11 12 13 14 15 16 17 18 19 20 21 22 23 24 25 26 27 28 29 30 31 32 33 34 35 Sub AjoutComplémentExcel() '*****************************************' 'Ajout du complément macro complémentaire : '*****************************************' Dim CheminFichier As String: CheminFichier = Application.UserLibraryPath '=> équivalent à : "C:\Users\" & Environ("USERNAME") & "\AppData\Roaming\Microsoft\AddIns\" 'Nota : NomFichier est une constante public String qui définit le nom de fichier pour la copie Dim NomCompletFichier As String: NomCompletFichier = CheminFichier & NomFichier & ".xlam" Dim Complément As AddIn If Mid(ThisWorkbook.FullNameURLEncoded, InStrRev(ThisWorkbook.FullNameURLEncoded, ".") + 1) <> "xlam" Then 'Si le complément existe déjà, on le supprime pour pouvoir le regénérer (permet les mises-à-jour) If Len(Dir(NomCompletFichier)) > 0 Then Application.AddIns.Add(NomCompletFichier).Installed = False Kill NomCompletFichier End If 'Enregistrement du fichier en cours en format .xlam dans le dossier des compléments Excel : ThisWorkbook.SaveAs Filename:=CheminFichier & NomFichier, FileFormat:=xlOpenXMLAddIn 'Installation et activation du complément : Application.AddIns.Add(NomCompletFichier).Installed = True 'Validation de l'installation du fichier et fermeture du fichier d'installation : MsgBox "Complément " & NomFichier & " chargé avec succès !" & Chr(13) & Chr(13) & _ "Le fichier d'installation va maintenant se fermer.", vbOkOnly, "Terminé" ThisWorkbook.Close SaveChanges:=False End If End sub
PE

31/05/2020, 08h39
Menhir

Citation:

Envoyé par PierreE_67207

@Menhir, je vais distribuer un Add-In dans mon entreprise, et je souhaiterais ne pas avoir à transmettre une méthodologie pour son installation et ses mises-à-jour à venir, donc mon objectif est d'automatiser sa mise en place à l'ouverture d'un fichier d'installation.

Il suffit que ton fichier d'installation copie le xlam dans XLStart.
Même un simple fichier .BAT pourrait faire ça.
01/06/2020, 22h05
PierreE_67207

Citation:

Envoyé par Menhir

Il suffit que ton fichier d'installation copie le xlam dans XLStart.
Même un simple fichier .BAT pourrait faire ça.

Bonsoir Menhir,

C'est sensiblement ce que j'ai fait finalement, mais en passant par le dossier \AppData\Roaming\Microsoft\AddIns\.
J'avais aussi pensé à un .BAT, mais n'ayant aucune connaissance dans ce domaine, j'ai opté par un fichier .XLSM qui contient le .XLAM :)

Sujet résolu, merci encore.

PE

Citation:

Envoyé par PierreE_67207

Voici par conséquent mon code qui fonctionne à présent, et qui répond à mon besoin.
La procédure est appelée dans "Private Sub Workbook_Open" du classeur du futur Complément, enregistré en format .xlsm :

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
Sub AjoutComplémentExcel()
 
'*****************************************'
'Ajout du complément macro complémentaire :
'*****************************************'
 
    Dim CheminFichier As String: CheminFichier = Application.UserLibraryPath
        '=> équivalent à : "C:\Users\" & Environ("USERNAME") & "\AppData\Roaming\Microsoft\AddIns\"
    'Nota : NomFichier est une constante public String qui définit le nom de fichier pour la copie
    Dim NomCompletFichier As String: NomCompletFichier = CheminFichier & NomFichier & ".xlam"
    Dim Complément As AddIn
 
 
    If Mid(ThisWorkbook.FullNameURLEncoded, InStrRev(ThisWorkbook.FullNameURLEncoded, ".") + 1) <> "xlam" Then
 
    'Si le complément existe déjà, on le supprime pour pouvoir le regénérer (permet les mises-à-jour)
        If Len(Dir(NomCompletFichier)) > 0 Then
            Application.AddIns.Add(NomCompletFichier).Installed = False
            Kill NomCompletFichier
        End If
 
    'Enregistrement du fichier en cours en format .xlam dans le dossier des compléments Excel :
        ThisWorkbook.SaveAs Filename:=CheminFichier & NomFichier, FileFormat:=xlOpenXMLAddIn
 
    'Installation et activation du complément :
        Application.AddIns.Add(NomCompletFichier).Installed = True
 
    'Validation de l'installation du fichier et fermeture du fichier d'installation :
        MsgBox "Complément " & NomFichier & " chargé avec succès !" & Chr(13) & Chr(13) & _
                   "Le fichier d'installation va maintenant se fermer.", vbOkOnly, "Terminé"
        ThisWorkbook.Close SaveChanges:=False
 
    End If
 
End sub

Bonjour.
C'est en lisant ton code que j'ai compris ce que tu voulais faire, et que tu as réussi à faire.
Je trouve l'idée très intéressante et je me suis permis de recopier ton code dans ma boîte à outils VBA personnelle (en citant la source), au cas où un jour j'en aurai besoin.
Félicitations.

03/06/2020, 22h37
PierreE_67207

Citation:

Envoyé par laurent_ott

Bonjour.
C'est en lisant ton code que j'ai compris ce que tu voulais faire, et que tu as réussi à faire.
Je trouve l'idée très intéressante et je me suis permis de recopier ton code dans ma boîte à outils VBA personnelle (en citant la source), au cas où un jour j'en aurai besoin.
Félicitations.

Merci beaucoup ! venant d'un expert, ça fait très plaisir :)