Comment sélectionner une ligne d'un tableau (array)

Version imprimable

Bonjour à tous,
J'ai voulu tester une nouvelle façon de coder, en mettant mes résultats dans des tableaux "fictifs" pour ne pas les afficher sur Excel. Mais du coup il me manque quelques notions.

j'ai :
- tabl1(d_ligne , n) , ici d_ligne = 31 et n = 3
- tabl2(d_ligne , 3) , le 3 n'a rien à voir avec le n de précédemment

Je voudrais savoir s'il est possible de trouver le minimum d'une ligne i du tabl1 et enregistrer dans tabl2(i,1) le numéro de colonne de tabl1 dans laquelle le minimum a été trouvé
Exemple
tabl1 :
5 2 4
3 4 1

je souhaite avoir tabl2 :
2
3 /!\ update j veux bien le numero colonne et pas le chiffre le plus petit

J'ai testé ça :
Code:

1 2 3 4 5 6 7 ReDim Preserve tabl2(d_ligne, 3) For i = 2 To d_ligne For j = 1 To 3n tabl2(i, 1) = Application.Min(tabl1(i,1 to n)) Next j Next i
Mais cela n'est pas une écriture correcte... comment sélectionner une ligne i d'un tableau svp ?

Merci d'avance :)!

Citation:

Envoyé par chloe.secli

Bonjour,

Preserve ne s'applique que sur la dernière dimension d'une matrice.

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
 
Public Tbl1() As Variant, Tbl2() As Variant
 
Sub ChargerMatriceTbl1()
 
 
       ReDim Tbl1(2, 1)
       Tbl1(0, 0) = 5
       Tbl1(1, 0) = 2
       Tbl1(2, 0) = 4
 
       Tbl1(0, 1) = 3
       Tbl1(1, 1) = 4
       Tbl1(2, 1) = 1
 
End Sub
 
 
Sub ChargeTbl2()
 
 Dim I As Integer, J As Integer, IndexMatrice As Integer, MinColonne As Integer
 
     ChargerMatriceTbl1
 
        IndexMatrice = 0
        For I = LBound(Tbl1, 2) To UBound(Tbl1, 2) ' To d_ligne
            MinColonne = 10000
            ReDim Preserve Tbl2(1, IndexMatrice)
            Tbl2(0, IndexMatrice) = I
 
            For J = LBound(Tbl1, 1) To UBound(Tbl1, 1)
              If Tbl1(J, I) < MinColonne Then
                 MinColonne = Tbl1(J, I)
                 'Debug.Print "I : " & I & ", " & J
                 Tbl2(1, IndexMatrice) = J
              End If
            Next J
            IndexMatrice = IndexMatrice + 1
        Next I
 
        For IndexMatrice = LBound(Tbl2, 2) To UBound(Tbl2, 2)
           Debug.Print "Ligne : " & Tbl2(0, IndexMatrice) + 1 & ", colonne : " & Tbl2(1, IndexMatrice) + 1
        Next IndexMatrice
 
End Sub

Bonjour,

Essaies comme ça :

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
Option Explicit
Sub test()
Dim tabl1, tabl2, x, d_ligne&, i&, j&
  '...
  '...
  ReDim tabl2(1 To UBound(tabl1), 1 To 3)
  For i = LBound(tabl1) To UBound(tabl1)
    x = tabl1(i, LBound(tabl1, 2))
    tabl2(i, 1) = LBound(tabl1, 2)
    For j = LBound(tabl1, 2) To UBound(tabl1, 2)
      If tabl1(i, j) < x Then
        x = tabl1(i, j)
        tabl2(i, 1) = j
      End If
    Next j
  Next i
End Sub

13/05/2020, 09h02
chloe.secli

Bonjour,
Merci à vous deux, j'ai pris la solution de Patrice ça marche!