Récupérer une portion de l'emplacement du batch

Version imprimable

15/04/2020, 15h55
Devnbi

Récupérer une portion de l'emplacement du batch

Bonjour à tous,

Je possède un script batch situé sur un mappage réseau dont le chemin s'apparente à celui-ci : Y:\abc\def\ghi\jkl\script.bat

Dans ce script, je récupère le chemin de celui-ci à l'aide de %~dp0 auquel je rajoute le chemin vers une application située dans un sous dossier "outils", ce qui donne ceci : "%~dp0\outils\application.exe"

Si ce lecteur réseau n'est plus mappé pour une raison quelconque, je dois exécuter le script depuis le chemin complet, à savoir : \\serveur123\partage$\abc\def\ghi\jkl\script.bat

Ce que je voudrais en fait c'est que le script récupère toujours le chemin complet (\\serveur123\partage$\abc...) même lorsqu'il est lancé depuis le lecteur Y:

Je ne souhaite pas écrire en dur le chemin complet dans mon script au cas où il sera amené à changer. Je peux néanmoins conserver cette portion : \\serveur123\partage$\abc

Comment puis-je faire concrètement cela ? Il faudrait pouvoir segmenter l'emplacement actuel et récupérer l'emplacement à partir du dossier abc

Merci d'avance pour votre éclairage.

Test ceci

Code:

1
2
3
4
5
6
7
8
9
10
11
12
@echo off
cls
 
IF "%~d0" == "\\" (
	SET chemin=%~dp0
) ELSE (
	FOR /F "tokens=2,*" %%a IN ('net use %~d0 2^>nul^|find "Nom distant"') DO set chemin=%%~b%~p0
)
 
echo chemin : %chemin%
pause
exit

Ou comme ceci ça permet aussi de fonctionner si le fichier est en local

Code:

1
2
3
4
5
6
7
8
9
@echo off
cls
 
FOR /F "tokens=2,*" %%a IN ('net use %~d0 2^>nul^|find "Nom distant"') DO set chemin=%%~b%~p0
IF NOT DEFINED chemin SET chemin=%~dp0
 
echo chemin : %chemin%
pause
exit

15/04/2020, 23h12
Devnbi
Que signifie %%~b%~p0 dans la commande ?

Comment puis-je l'intégrer au sein d'une boucle existante comme celle-ci :
Code:

1 2 3 4 for /f "tokens=*" %%I in ('dir /a:d-h /b "%SystemDrive%\Users\*" ^| findstr /x /i /l /v /g:"%~dp0\outils\exclude_users.txt"') do if exist "%Destination%\%%~nxI\" ( ... )
J'ai essayé mais la variable %chemin% a été ignorée..
16/04/2020, 00h40
ericlm128

Essai déjà juste le bout de code seulement pour voir si le résultat est correcte. On l'intégrera après
16/04/2020, 00h55
Devnbi

Oui ça fonctionne bien. Je préfère intégrer le 2ème toutefois.

Citation:

Que signifie %%~b%~p0 dans la commande ?

%%b représente le tokens * de la boucle ForInDo et %~p0 le chemin du script courant
Extrait de for /? sur la substitution de références de variables :
Code:

1 2 3 4 5 6 %~I - étend %I en supprimant les guillemets (") %~fI - étend %I en nom de chemin d’accès reconnu %~dI - étend %I en lettre de lecteur uniquement %~pI - étend %I en chemin d’accès uniquement %~nI - étend %I en nom de fichier uniquement %~xI - étend %I en extension de fichier uniquement
Citation:

Comment puis-je l'intégrer au sein d'une boucle existante comme celle-ci

Je dirais comme ceci mais je ne connait pas ta variable Destination.
Code:

1 2 3 4 5 6 7 8 9 @echo off cls FOR /F "tokens=2,*" %%a IN ('net use %~d0 2^>nul^|find "Nom distant"') DO set chemin=%%~b%~p0 IF NOT DEFINED chemin SET chemin=%~dp0 for /f "tokens=*" %%I in ('dir /a:d-h /b "%SystemDrive%\Users\*" ^| findstr /x /i /l /v /g:"%chemin%outils\exclude_users.txt"') do if exist "%Destination%\%%~nxI\" ( ... )

Voici le contenu de mon script :
(si vous voyez au passage des choses à améliorer/simplifier je suis preneur).

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
 
@echo off
SETLOCAL ENABLEDELAYEDEXPANSION
 
set BackupDest=\\server01\users$\utilisateurs
set BkpFolder=Bkp2_%computername%_%DATE:~0,2%-%DATE:~3,2%-%DATE:~6,4%
 
rem vérif accesibilité du serveur
if not exist "%BackupDest%\test-folder\" (
"%~dp0bin\cecho\%PROCESSOR_ARCHITECTURE%\cecho.exe" {0c} Serveur "%BackupDest%" non disponible.{\n}
"%~dp0bin\cecho\%PROCESSOR_ARCHITECTURE%\cecho.exe" {0c} Verifier qu'une connexion est possible et relancer le script.{\n silver}
goto end
)
rem récup du chemin UNC du script (pour raccourci)
for /f "tokens=2,*" %%a in ('net use %~d0 2^>nul^|find "Nom distant"') do set chemin=%%~b%~p0
if not defined chemin set chemin=%~dp0
rem récup des profils avec lecteur nominatif
set profil_max=0
for /f "tokens=*" %%I in ('dir /a:d-h /b "%SystemDrive%\Users\*" ^| findstr /x /i /l /v /g:"%~dp0bin\exclude_users.txt"') do if exist "%BackupDest%\%%~nI\" (set /a profil_max+=1)
set index=0
for /f "tokens=*" %%I in ('dir /a:d-h /b "%SystemDrive%\Users\*" ^| findstr /x /i /l /v /g:"%~dp0bin\exclude_users.txt"') do if exist "%BackupDest%\%%~nI\" (
set /a index+=1
Title Sauvegarde du profil en cours: %%I
"%~dp0bin\cecho\%PROCESSOR_ARCHITECTURE%\cecho.exe" {0c} ----------------------------------------------{\n}
"%~dp0bin\cecho\%PROCESSOR_ARCHITECTURE%\cecho.exe" {0b}      Sauvegarde du profil [!index!/!profil_max!]: %%I{\n}
"%~dp0bin\cecho\%PROCESSOR_ARCHITECTURE%\cecho.exe" {0c} ----------------------------------------------{\n}
"%~dp0bin\cecho\%PROCESSOR_ARCHITECTURE%\cecho.exe" {0D}
rem vérif si droits d'écriture sur lecteur nominatif
copy /y nul "%BackupDest%\%%~nI\.%computername%" >nul 2>&1
if errorlevel 1 (echo  %username% n'a pas la permission d'ecrire sur le lecteur Z de %%I) else (
del "%BackupDest%\%%~nI\.%computername%" 2>nul
rem démarrage de la sauvegarde
"%~dp0bin\Backup.exe" /BACKUP /LANGUAGE="Francais" /SOURCEDRIVE=C /TO="%BackupDest%\%%~nI" /SUBFOLDER="%BkpFolder%" /SOURCEUSERSPROFILESNAMES="%%I" /ALWAYSKEEPBOTH /DESKTOP /MYDOCUMENTS /MYPICTURES /IEFAVORITES /IESTARTPAGE /IESETTINGS /FIREFOX /OUTLOOKPST /OUTLOOKSIGNATURES /OUTLOOKNK2 /TEMPLATES /EXCLUSIONS="*.ost;*.exe;*.mp3;*.avi" /LOGSTORAGE="%~dp0logs\%%~nI_%computername%\"
rem création du raccourci pour la restauration
"%~dp0bin\shortcut.exe" /F:"%BackupDest%\%%~nI\%BkpFolder%\restore_user_profile.lnk" /A:C /T:%SystemRoot%\System32\cmd.exe /P:"/c """"""%chemin%bin"\Backup.exe"""" /LANGUAGE=""Francais"""" /SAVELOGLEVEL=0 /LOADCONF=""Z:\%BkpFolder%\Backup.conf"""""" /r:7 >nul
rem activation du mode admin dans le raccourci
"%~dp0bin\hexalter.exe" "%BackupDest%\%%~nI\%BkpFolder%\restore_user_profile.lnk" 0x15=32 >nul
)
)
rem avertissement des profils sans lecteur nominatif
for /f "tokens=*" %%I in ('dir /a:d-h /b "%SystemDrive%\Users\*" ^| findstr /x /i /l /v /g:"%~dp0bin\exclude_users.txt"') do if not exist "%BackupDest%\%%~nI\" (
"%~dp0bin\cecho\%PROCESSOR_ARCHITECTURE%\cecho.exe" {0c} ----------------------------------------------{\n}
"%~dp0bin\cecho\%PROCESSOR_ARCHITECTURE%\cecho.exe" {0a}      %%I n'a pas de lecteur Z{\n}
"%~dp0bin\cecho\%PROCESSOR_ARCHITECTURE%\cecho.exe" {0c} ----------------------------------------------{\n}
"%~dp0bin\cecho\%PROCESSOR_ARCHITECTURE%\cecho.exe" {0D}
)
"%~dp0bin\cecho\%PROCESSOR_ARCHITECTURE%\cecho.exe" {0c} --------------------------------------------------------------{\n silver}
rem suppression logs de backup >30 jours
forfiles /p "%~dp0logs" /d -30 /c "cmd /c IF @isdir == TRUE rd /S /Q @path" >nul 2>&1
 
:end
echo  Appuyez sur une touche pour quitter.
pause >nul
exit

Voici quelques propositions mineures :
- Indentation et saut de ligne pour la lisibilité du code
- Utilise plutôt %%~I que %%I pour t'éviter des problèmes potentiels
- Le cls de début pour effacé l'avertissement d’exécution sur le réseau
- Création de variable bin, log et cecho pour éviter la réécriture massive de chaine similaire. Ceci permet aussi de centraliser des paramètres.
- Je ne fait pas confiance à ERRORLEVEL je préfère && et ||

A noter que :
- Tu affiche des messages sur le lecteur Z: sans le tester vraiment
- On aurait peut être aussi pu variabiliser : dir /a:d-h /b "%SystemDrive%\Users\*" ^| findstr /x /i /l /v /g:"%bin%\exclude_users.txt"
- Tu aurais pu réduire le code avec un if else pour les profils non traités mais il s'afficherait dans un ordre différents. Si tu veux les regrouper tu peux les traiter en têtes plutôt qu'a la fin (dans la première boucle ForInDo)

Je trouve ton code propre sinon ;)

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
@echo off
cls
SETLOCAL ENABLEDELAYEDEXPANSION
 
set BackupDest=\\server01\users$\utilisateurs
set BkpFolder=Bkp2_%computername%_%DATE:~0,2%-%DATE:~3,2%-%DATE:~6,4%
 
set bin=%~dp0bin
set log=%~dp0logs
set cecho="%bin%\cecho\%PROCESSOR_ARCHITECTURE%\cecho.exe"
 
rem vérif accesibilité du serveur
if not exist "%BackupDest%\test-folder\" (
	%cecho% {0c} Serveur "%BackupDest%" non disponible.{\n}
	%cecho% {0c} Verifier qu'une connexion est possible et relancer le script.{\n silver}
	goto end
)
 
rem récup du chemin UNC du script (pour raccourci)
for /f "tokens=2,*" %%a in ('net use %~d0 2^>nul^|find "Nom distant"') do set chemin=%%~b%~p0
if not defined chemin set chemin=%~dp0
 
rem récup des profils avec lecteur nominatif
set profil_max=0
for /f "tokens=*" %%I in ('dir /a:d-h /b "%SystemDrive%\Users\*" ^| findstr /x /i /l /v /g:"%bin%\exclude_users.txt"') do if exist "%BackupDest%\%%~nI\" (set /a profil_max+=1)
set index=0
 
for /f "tokens=*" %%I in ('dir /a:d-h /b "%SystemDrive%\Users\*" ^| findstr /x /i /l /v /g:"%bin%\exclude_users.txt"') do if exist "%BackupDest%\%%~nI\" (
	set /a index+=1
	Title Sauvegarde du profil en cours: %%~I
	%cecho% {0c} ----------------------------------------------{\n}
	%cecho% {0b}      Sauvegarde du profil [!index!/!profil_max!]: %%~I{\n}
	%cecho% {0c} ----------------------------------------------{\n}
	%cecho% {0D}
 
	rem vérif si droits d'écriture sur lecteur nominatif
	copy /y nul "%BackupDest%\%%~nI\.%computername%" >nul 2>&1 || (echo %username% n'a pas la permission d'ecrire sur le lecteur Z de %%~I) && (
		del "%BackupDest%\%%~nI\.%computername%" 2>nul
		rem démarrage de la sauvegarde
		"%bin%\Backup.exe" /BACKUP /LANGUAGE="Francais" /SOURCEDRIVE=C /TO="%BackupDest%\%%~nI" /SUBFOLDER="%BkpFolder%" /SOURCEUSERSPROFILESNAMES="%%~I" /ALWAYSKEEPBOTH /DESKTOP /MYDOCUMENTS /MYPICTURES /IEFAVORITES /IESTARTPAGE /IESETTINGS /FIREFOX /OUTLOOKPST /OUTLOOKSIGNATURES /OUTLOOKNK2 /TEMPLATES /EXCLUSIONS="*.ost;*.exe;*.mp3;*.avi" /LOGSTORAGE="%log%\%%~nI_%computername%\"
		rem création du raccourci pour la restauration
		"%bin%\shortcut.exe" /F:"%BackupDest%\%%~nI\%BkpFolder%\restore_user_profile.lnk" /A:C /T:%SystemRoot%\System32\cmd.exe /P:"/c """"""%chemin%bin"\Backup.exe"""" /LANGUAGE=""Francais"""" /SAVELOGLEVEL=0 /LOADCONF=""Z:\%BkpFolder%\Backup.conf"""""" /r:7 >nul
		rem activation du mode admin dans le raccourci
		"%bin%\hexalter.exe" "%BackupDest%\%%~nI\%BkpFolder%\restore_user_profile.lnk" 0x15=32 >nul
	)
)
 
rem avertissement des profils sans lecteur nominatif
for /f "tokens=*" %%I in ('dir /a:d-h /b "%SystemDrive%\Users\*" ^| findstr /x /i /l /v /g:"%bin%\exclude_users.txt"') do if not exist "%BackupDest%\%%~nI\" (
	%cecho% {0c} ----------------------------------------------{\n}
	%cecho% {0a}      %%~I n'a pas de lecteur Z{\n}
	%cecho% {0c} ----------------------------------------------{\n}
	%cecho% {0D}
)
%cecho% {0c} --------------------------------------------------------------{\n silver}
 
rem suppression logs de backup >30 jours
forfiles /p "%log%" /d -30 /c "cmd /c IF @isdir == TRUE rd /S /Q @path" >nul 2>&1
 
:end
echo  Appuyez sur une touche pour quitter.
pause >nul
exit

16/04/2020, 14h25
Devnbi

Citation:

Envoyé par ericlm128

A noter que :
- Tu affiche des messages sur le lecteur Z: sans le tester vraiment Le lecteur Z: n'est mappé que sur la session des utilisateurs. En théorie, si ils ont bien un dossier à leur nom sur le serveur, il devrait être mappé à l'ouverture de leur session
- On aurait peut être aussi pu variabiliser : dir /a:d-h /b "%SystemDrive%\Users\*" ^| findstr /x /i /l /v /g:"%bin%\exclude_users.txt" Oui pourquoi pas
- Tu aurais pu réduire le code avec un if else pour les profils non traités mais il s'afficherait dans un ordre différents. Si tu veux les regrouper tu peux les traiter en têtes plutôt qu'a la fin (dans la première boucle ForInDo) J'aurais pu effectivement les traiter dans la première boucle mais ils se seraient retrouvés noyés avec les profils traités. Et puis admettons que le 1er profil ne puisse être traité et que tous les autres le puissent, et que ces derniers soient nombreux (par exemple +10), à la fin du processus, on n'aurait pas eu l'info au sujet du profil non traité (à moins de remonter la barre de défilement). Même chose en les regroupant en têtes. C'est plus par souci de clarté qu'autre chose.

Je trouve ton code propre sinon ;) Merci !
16/04/2020, 14h36
Devnbi

En utilisant && et || à la place de ERRORLEVEL, le script n'exécute les lignes en dessous que si il n'arrive pas à créer le fichier .%computername% or ce n'est pas ce que je souhaite. Je souhaite l'inverse.

Vraiment, tu peux essayer comme ceci ?

Code:

1
2
3
4
5
6
7
8
9
	copy /y nul "%BackupDest%\%%~nI\.%computername%" >nul 2>nul || (echo %username% n'a pas la permission d'ecrire sur le lecteur Z de %%~I) && (
		del "%BackupDest%\%%~nI\.%computername%" 2>nul
		rem démarrage de la sauvegarde
		"%bin%\Backup.exe" /BACKUP /LANGUAGE="Francais" /SOURCEDRIVE=C /TO="%BackupDest%\%%~nI" /SUBFOLDER="%BkpFolder%" /SOURCEUSERSPROFILESNAMES="%%~I" /ALWAYSKEEPBOTH /DESKTOP /MYDOCUMENTS /MYPICTURES /IEFAVORITES /IESTARTPAGE /IESETTINGS /FIREFOX /OUTLOOKPST /OUTLOOKSIGNATURES /OUTLOOKNK2 /TEMPLATES /EXCLUSIONS="*.ost;*.exe;*.mp3;*.avi" /LOGSTORAGE="%log%\%%~nI_%computername%\"
		rem création du raccourci pour la restauration
		"%bin%\shortcut.exe" /F:"%BackupDest%\%%~nI\%BkpFolder%\restore_user_profile.lnk" /A:C /T:%SystemRoot%\System32\cmd.exe /P:"/c """"""%chemin%bin"\Backup.exe"""" /LANGUAGE=""Francais"""" /SAVELOGLEVEL=0 /LOADCONF=""Z:\%BkpFolder%\Backup.conf"""""" /r:7 >nul
		rem activation du mode admin dans le raccourci
		"%bin%\hexalter.exe" "%BackupDest%\%%~nI\%BkpFolder%\restore_user_profile.lnk" 0x15=32 >nul
	)

Ou essayer d'inverser les && et || même si je pense qu'il sont correctement positionner

16/04/2020, 14h53
Devnbi

En mettant >nul 2>nul à la place de >nul 2>&1 = idem
En inversant || et && = il affiche l'erreur dans echo si il arrive à créer le fichier %.computername%, sans aller plus loin, sinon si il ne peut pas le créer, il exécute quand même les lignes en dessous
16/04/2020, 15h03
ericlm128

Bon et bien remet errorlevel :/

Me revoilà car ça ma comme même troublé ce truc :?
Après vérification, il semblerait que l'ordre à une importance (il est vrai que je l'avais toujours fait dans un certain ordre), donc peux tu essayer comme ceci.

Code:

1
2
3
4
5
6
7
8
9
copy /y nul "%BackupDest%\%%~nI\.%computername%" >nul 2>nul && (
	del "%BackupDest%\%%~nI\.%computername%" 2>nul
	rem démarrage de la sauvegarde
	"%bin%\Backup.exe" /BACKUP /LANGUAGE="Francais" /SOURCEDRIVE=C /TO="%BackupDest%\%%~nI" /SUBFOLDER="%BkpFolder%" /SOURCEUSERSPROFILESNAMES="%%~I" /ALWAYSKEEPBOTH /DESKTOP /MYDOCUMENTS /MYPICTURES /IEFAVORITES /IESTARTPAGE /IESETTINGS /FIREFOX /OUTLOOKPST /OUTLOOKSIGNATURES /OUTLOOKNK2 /TEMPLATES /EXCLUSIONS="*.ost;*.exe;*.mp3;*.avi" /LOGSTORAGE="%log%\%%~nI_%computername%\"
	rem création du raccourci pour la restauration
	"%bin%\shortcut.exe" /F:"%BackupDest%\%%~nI\%BkpFolder%\restore_user_profile.lnk" /A:C /T:%SystemRoot%\System32\cmd.exe /P:"/c """"""%chemin%bin"\Backup.exe"""" /LANGUAGE=""Francais"""" /SAVELOGLEVEL=0 /LOADCONF=""Z:\%BkpFolder%\Backup.conf"""""" /r:7 >nul
	rem activation du mode admin dans le raccourci
	"%bin%\hexalter.exe" "%BackupDest%\%%~nI\%BkpFolder%\restore_user_profile.lnk" 0x15=32 >nul
) || (echo %username% n'a pas la permission d'ecrire sur le lecteur Z de %%~I)

Le problème c'est que l'erreur s'appliquera à l'ensemble des commandes. Ce qui veut dire si l'une d'elles échoue, le message d'erreur dira que l'utilisateur n'a pas la permission d'écrire alors que ce n'est pas le cas ici.

Finalement, j'ai utilisé le code qui suit :
Code:

1 2 3 md "%BackupDest%\%%~nI\_%computername%_" 2>nul if not exist "%BackupDest%\%%~nI\_%computername%_\" (echo %username% n'a pas la permission d'ecrire sur le lecteur W de %%~I) else ( rd /s /q "%BackupDest%\%%~nI\_%computername%_\" 2>nul

17/04/2020, 09h47
ericlm128

Citation:

Le problème c'est que l'erreur s'appliquera à l'ensemble des commandes. Ce qui veut dire si l'une d'elles échoue, le message d'erreur dira que l'utilisateur n'a pas la permission d'écrire alors que ce n'est pas le cas ici.

Oui

Ok mais ça peut être un problème réseau ici qui empêche la création, non ?
17/04/2020, 10h05
Devnbi

Une interdiction d'écriture éventuelle, faute de droits suffisants.