Modification nom dossier de Majuscule en Minuscule

Version imprimable

Bonjour,

J'aimerai modifier des noms de dossiers (nom de commune) de majuscule en minuscule en gardant la première lettre en majuscule de chaque mot.

Ex: MONT en Mont
LIT ET MIX en Lit Et Mix

J'ai réussi a trouver ce code (qui n'est pas optimal je pense) qui me transforme tout en minuscule...

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
for /f "delims=" %%i in ('dir /a:d /b') do set VrNamRep=%%i& call :majMin 
goto finmajMin 
 
:majMin 
set VrNamRep2=%VrNamRep:A=a%
set VrNamRep3=%VrNamRep2:B=b%
set VrNamRep4=%VrNamRep3:C=c%
set VrNamRep5=%VrNamRep4:D=d%
set VrNamRep6=%VrNamRep5:E=e%
set VrNamRep7=%VrNamRep6:F=f%
set VrNamRep8=%VrNamRep7:G=g%
set VrNamRep9=%VrNamRep8:H=h%
set VrNamRep10=%VrNamRep9:I=i%
set VrNamRep11=%VrNamRep10:J=j%
set VrNamRep12=%VrNamRep11:K=k%
set VrNamRep13=%VrNamRep12:L=l%
set VrNamRep14=%VrNamRep13:M=m%
set VrNamRep15=%VrNamRep14:N=n%
set VrNamRep16=%VrNamRep15:O=o%
set VrNamRep17=%VrNamRep16:P=p%
set VrNamRep18=%VrNamRep17:Q=q%
set VrNamRep19=%VrNamRep18:R=r%
set VrNamRep20=%VrNamRep19:S=s%
set VrNamRep21=%VrNamRep20:T=t%
set VrNamRep22=%VrNamRep21:U=u%
set VrNamRep23=%VrNamRep22:V=v%
set VrNamRep24=%VrNamRep23:W=w%
set VrNamRep25=%VrNamRep24:X=x%
set VrNamRep26=%VrNamRep25:Y=y%
set VrNamRep27=%VrNamRep26:Z=z%
 
ren "%VrNamRep%" "%VrNamRep27%"
 
goto :eof
 
:finmajMin

Je recherche donc à savoir ce que je dois modifier pour avoir la lettre de chaque mot en majuscule.

Je vous remercie par avance

Jujudeo

UP1Letter.bat

:salut:
Voici une solution en passant par un vbscript : UP1Letter.bat

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
@echo off
Title Modification nom dossier de Majuscule en Minuscule
SetLocal EnableDelayedExpansion
for /f "delims=" %%i in ('dir /a:d /b') do set "VrNamRep=%%i" & Call :Maj_Letter "!VrNamRep!"
pause
Exit
::------------------------------------------------------------------
:Maj_Letter
(
    echo wscript.echo UpFirstLetter("%~1"^)
    echo Function UpFirstLetter(str^)
    echo    str = Ucase(Left(str,1^)^) ^& LCase(Right(str,Len(str^)-1^)^)
    echo    UpFirstLetter = str
    echo End Function
)>"%tmp%\%~n0.vbs"
cscript //nologo "%tmp%\%~n0.vbs" "%~1" 
If Exist "%tmp%\%~n0.vbs" Del "%tmp%\%~n0.vbs"
Exit /B
::------------------------------------------------------------------

Bonjour,

Voilà une solution en batch pur :

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
@echo off
setlocal enableextensions enabledelayedexpansion
chcp 28591 >nul
 
for /f "delims=" %%i in ('dir /ad /b') do call :majMin "%%~dpni"
 
echo. & pause
exit 
 
 
:majMin
 
set VrNamRep=%~n1
set chaine=!VrNamRep:~1!
 
for %%A in (A B C D E F G H I J K L M N O P Q R S T U V W X Y Z) do (
 
	for %%B in (a b c d e f g h i j k l m n o p q r s t u v w x y z) do (
 
		if /i "%%A"=="%%B" (set chaine=!chaine:%%A=%%B!)
 
	)
)
 
echo. & echo.###!VrNamRep!
 
ren %1 "!VrNamRep:~0,1!!chaine!"
 
goto :eof

13/04/2020, 14h32
ericlm128

Citation:

en gardant la première lettre en majuscule de chaque mot

Avez vous bien intégré cette demande (en gras) exprimée dans le besoin initiale ?
Il ne me semble pas.

Citation:
Envoyé par barnabe0057
Bonjour,

Voilà une solution en batch pur :
Code:

1 2 3 4 5 6 7 8 9 10 11 12 13 14 15 16 17 18 19 20 21 22 23 24 25 26 27 28 29 @echo off setlocal enableextensions enabledelayedexpansion chcp 28591 >nul for /f "delims=" %%i in ('dir /ad /b') do call :majMin "%%~dpni" echo. & pause exit :majMin set VrNamRep=%~n1 set chaine=!VrNamRep:~1! for %%A in (A B C D E F G H I J K L M N O P Q R S T U V W X Y Z) do ( for %%B in (a b c d e f g h i j k l m n o p q r s t u v w x y z) do ( if /i "%%A"=="%%B" (set chaine=!chaine:%%A=%%B!) ) ) echo. & echo.###!VrNamRep! ren %1 "!VrNamRep:~0,1!!chaine!" goto :eof
Bonjour,

ce code me correspond mieux car il est plus amélioré que le mien.

Cependant, il ne met pas la première lettre en MAJUSCULE de chaque mot.

Dans l'attente de votre réponse.

Jujudeo

14/04/2020, 09h39
hackoofr

Citation:

Envoyé par jujudeo

Bonjour,
Cependant, il ne met pas la première lettre en MAJUSCULE de chaque mot.
Dans l'attente de votre réponse.
Jujudeo

Déjà répondu plus haut :mouarf:
14/04/2020, 09h45
jujudeo

Citation:

Envoyé par hackoofr

Déjà répondu plus haut :mouarf:

Je m'excuse, il marche, mais il ne met pas la premiere lettre en majuscule...
14/04/2020, 13h18
hackoofr

Citation:

Envoyé par jujudeo

Je m'excuse, il marche, mais il ne met pas la premiere lettre en majuscule...

Donc, tu veux convertir un nom de dossier avec espaces : "DUPONT DUPOND TINTIN MILOU HADDOCK" en "Dupont Dupond Tintin Milou Haddock"
C'est ça ? :roll:
14/04/2020, 15h06
jujudeo

Citation:

Envoyé par hackoofr

Donc, tu veux convertir un nom de dossier avec espaces : "DUPONT DUPOND TINTIN MILOU HADDOCK" en "Dupont Dupond Tintin Milou Haddock"
C'est ça ? :roll:

C'est exactement ca !!

:salut:

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
@echo off
Set "Str=TINTIN MILOU HADDOCK TOURNESOL DUPOND DUPONT"
echo %str%
Call :Maj_Letter "%str%"
pause 
SetLocal EnableDelayedExpansion
for /f "delims=" %%i in ('dir /a:d /b') do set "VrNamRep=%%i" & Call :Maj_Letter "!VrNamRep!"
pause
exit
::------------------------------------------------------------------
:Maj_Letter
(
    echo wscript.echo UpFirstLetter("%~1"^)
    echo Function UpFirstLetter(str^)
    echo    ArrStr = Split(str,chr(32^)^)
    echo    For i=LBound(ArrStr^) To UBound(ArrStr^)
    echo        O = O ^& Ucase(Left(ArrStr(i^),1^)^) ^& LCase(Right(ArrStr(i^),Len(ArrStr(i^)^)-1^)^) ^& chr(32^) 
    echo     Next
    echo     UpFirstLetter = Trim(O^)
    echo  End Function
)>"%tmp%\%~n0.vbs"
cscript //nologo "%tmp%\%~n0.vbs" "%~1" 
If Exist "%tmp%\%~n0.vbs" Del "%tmp%\%~n0.vbs"
Exit /B
::------------------------------------------------------------------

Version pur batch :

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
@echo off
setlocal enableextensions enabledelayedexpansion
chcp 28591 >nul
 
for /f "delims=" %%i in ('dir /ad /b') do (
 
	call :majMin %%~i
	set dossier=!dossier:~1!
	ren "%%~dpni" "!dossier!"
 
)
 
echo. & pause
exit 
 
 
:majMin
 
set "dossier="
 
:boucle
 
set mot=%1
set majuscule=!mot:~0,1!
set minuscules=!mot:~1!
 
for %%A in (A B C D E F G H I J K L M N O P Q R S T U V W X Y Z) do (
 
	for %%B in (a b c d e f g h i j k l m n o p q r s t u v w x y z) do (
 
		if /i "%%A"=="%%B" (set minuscules=!minuscules:%%A=%%B!)
 
	)
)
 
set "dossier=!dossier! !majuscule!!minuscules!"
 
shift
 
if "%~1"=="" (goto :eof) else (goto :boucle)

14/04/2020, 18h28
barnabe0057

Le mien ou celui de hackoofr ?
14/04/2020, 18h33
jujudeo

Citation:

Envoyé par barnabe0057

Le mien ou celui de hackoofr ?

Je tiens tout d'abord a vous remercier tous les deux.

Je n'avais pas vu le tien barnabe0057, il est parfait, il correspond a 100% a mes attentes.

En ce qui concerne celui de hackoofr, il ne se lance pas je ne comprends pas pourquoi :calim2:

En tout cas merci beaucoup a tous les deux, le sujet est résolu !!