VBA convertir CSV en TXT

Version imprimable

10/04/2020, 15h56
Patasimov

VBA convertir CSV en TXT

Bonjour le forum,

Je cherche en VBA à convertir et renommer un fichier source toto.CSV en tata.TXT.

Ayant fait plusieurs recherche c'est en vain que je poste ici :D

Si vous avez des pistes je suis preneur ;)

Merci.

Désolé, je me suis rendu compte, trop tard, que j'étais resté sur le forum Excel alors que je pensais poster sur Macro et VBA Excel !
Je ne sais pas comment déplacer mon poste ?
Merci au modérateur qui le fera :?
10/04/2020, 16h42
Alex020181

Bonjour,

Citation:

Envoyé par Patasimov

Je cherche en VBA à convertir et renommer un fichier source toto.CSV en tata.TXT.

Voici la ligne de code à insérer pour renommer votre fichier

Code:

Name "D:\DATA\alex\Desktop\toto.csv" As "D:\DATA\alex\Desktop\tata.txt"

A vous d'adapter le chemin d'accès au fichier.
10/04/2020, 17h27
Patasimov

Bonjour,Alex020181

Citation:

Voici la ligne de code à insérer pour renommer votre fichier

Je me suis peut être mal exprimé :aie:
Je cherche à convertir de CSV en TXT, pour le renommage je pense plutôt créer un nouveau fichier

Code:

NewFichierTxt "C:\Users\Patrick\Desktop\Test.txt", txt

Mais merci pour l'info ;)
10/04/2020, 17h34
Alex020181

Un fichier csv est lui-même un fichier texte. Il suffit de l'ouvrir avec un éditeur de texte (exemple bloc note Windows) et pas avec Excel. Il n'y a pas de conversion à faire.

Par contre il se peut que, individuellement de cette conversion, vous souhaitiez faire des modifications de formats (de données et pas de fichier).

Pourriez-vous nous donner un exemple de votre fichier csv d'origine et du txt correspondant attendu ?
10/04/2020, 18h28
Patrice740

Bonjour,

Citation:

Envoyé par Patasimov

Je cherche à convertir de CSV en TXT, ...

Si tu veux convertit un fichier .csv qui représente un tableau de valeurs en fichier .txt qui représente ce même tableau, c'est pas vraiment simple !!!

Soit tu passes par Excel pour charger les valeurs dans une feuille puis tu enregistres au format .txt
Soit tu fais tout avec VBA (chargement dans une variable VBA, Traitement, enregistrement).

Dans les 2 cas la difficulté est le traitement du fichier csv.
Il faut connaitre le format du csv, à minima :
- le séparateur de texte
- le séparateur de valeurs
- l'identificateur de texte
et souvent en plus :
- l'encodage des caractères
- le séparateur décimal
- le séparateur de milliers
- le format des nombres négatifs
- le format des colonnes date / temps

Ici un exemple pour ouvrir avec Excel un csv : [XL-2016] Problème à l'importation d'un fichier CSV via Workbooks.OpenText - Macros et VBA Excel
10/04/2020, 19h50
Patasimov

1 pièce(s) jointe(s)

C'est vrai que les fichiers exemples seront là pour bien comprendre des données.
En fait je récupère des fichiers de valeurs numériques en real d'un automatisme, que je dois insérer dans les feuilles d'un classeur Excel pour afficher des courbes et calculs sur ces valeurs.
Classeur protégé existant que je souhaite pas casser.

Voici un exemple de fichier source csv et le fichier txt que je dois insérer.
Pièce jointe 554975

Bonjour,

Avec une procédure spécialisée (d'après les deux fichiers fournis .txt et .csv) qui fonctionne avec les 2 types de fichier :

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
Private Sub ChargerLesDonnees(nomCompletFichierSource As String, celCible As Range)
Dim buf As String                 'buffer
Dim n°F As Integer                'numéro du fichier
Dim tbL As Variant                'tableau de lignes
Dim tbV As Variant                'tableau de valeurs
Dim tbR As Variant                'tableau résultat
Dim nbC As Long                   'nombre de colonnes
Dim ixL As Long                   'index ligne
Dim ixC As Long                   'index colonne
  ' Chargement des données contenues dans le fichier source
  n°F = FreeFile
  Open nomCompletFichierSource For Binary Access Read As #n°F
  buf = Space$(LOF(n°F))
  Get #n°F, , buf
  Close #n°F
  ' Traitement des données
  If Mid(buf, Len(buf) - 1) = vbCrLf Then buf = Left(buf, Len(buf) - 2)
  If Right(nomCompletFichierSource, 4) = ".csv" Then buf = Replace(Replace(buf, """", ""), ";", " ")
  buf = Replace(buf, ",", ".")
  tbL = Split(buf, vbCrLf)
  ' Création du résultat
  nbC = UBound(Split(tbL(0), " "))
  ReDim tbR(1 To UBound(tbL) + 1, 1 To nbC + 1)
  For ixL = 0 To UBound(tbL)
    tbV = Split(tbL(ixL), " ")
    For ixC = 0 To nbC
      tbR(ixL + 1, ixC + 1) = tbV(ixC)
    Next ixC
  Next ixL
  ' Écriture dans le fichier cible
  celCible.Resize(UBound(tbR), UBound(tbR, 2)).Value = tbR
End Sub

Un exemple d'utilisation de la procédure ci-dessus :

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
Sub Exemple()
Dim wbk As Workbook               'classeur cible
Dim cel As Range                  'cellule cible
Dim nom As Variant                'nom complet du fichirer csv ou txt
  ' Définir le nom du fichier csv ou text à charger
  nom = Application.GetOpenFilename(, , , , False)
  If nom = False Then Exit Sub
  ' Définir le classeur cible et la cellule cible
  Set wbk = Application.Workbooks.Add(xlWBATWorksheet)
  Set cel = wbk.Worksheets(1).Range("B12")
  ' Charger les données
  Call ChargerLesDonnees(CStr(nom), cel)
End Sub

10/05/2020, 00h49
Patasimov

Merci Patrice740
J'ai placé le poste en résolu suite à tes deux messages qui n'ont bien aidé dans mon projet.