Controle Tableau sous Visual Studio

Version imprimable

31/03/2020, 00h46
HDU71000

Controle Tableau sous Visual Studio

Bonjour,

je cherche désespérément s'il y a un contrôle dans visual studio (vb.net) qui corresponde à un tableau, et dont je peux dés le départ choisir le nombre de colonnes et de lignes.

J'ai testé avec TableLayoutPanel, mais le souci est que je voudrais ensuite savoir sur quelle colonne l'utilisateur à cliqué. Le but est de créer un petit jeu.

Merci.

A+

Vu que tu cherches à avoir la ligne et la colonne de chaque contrôle,tu devras :
1/ ajouter tes contrôles par code
2/ utiliser un class utilitaire Position pour "storer" ligne et colonne
2/ assigner le class Position à la prop "Tag" du contrôle

code exemple .vb:

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
 
Imports System.Windows.Forms
Public Class Form1
    Friend WithEvents pnl As TableLayoutPanel
    Friend buttons As List(Of Button)
    Private nbColumn As Integer = 2
    Private nbRow As Integer = 3
    Private Sub Form1_Load(sender As System.Object, e As System.EventArgs) Handles MyBase.Load
        pnl = New TableLayoutPanel
        pnl.Location = New Point(100, 100)
        pnl.ColumnCount = 2
        pnl.RowCount = 3
        pnl.ColumnStyles.Add(New ColumnStyle(SizeType.Percent, 50.0))
        pnl.ColumnStyles.Add(New ColumnStyle(SizeType.Percent, 50.0))
        AddButtons()
        Me.Controls.Add(pnl)
    End Sub
    Private Sub AddButtons()
        For i As Integer = 0 To nbRow - 1
            For j As Integer = 0 To nbColumn - 1
                Dim btn As New Button
                btn.Name = "btn1"
                btn.Text = "button" + (i + 1).ToString() + (j + 1).ToString()
                btn.Location = New Point
                btn.Tag = New Position(j + 1, i + 1)
                AddHandler btn.Click, AddressOf btnClick
                pnl.Controls.Add(btn, j, i)
 
            Next
        Next
    End Sub
 
    Private Sub btnClick(sender As Object, e As EventArgs)
        Dim btn As Button = CType(sender, Button)
        Dim pos As Position = btn.Tag
        MessageBox.Show(pos.Col.ToString() + "," + pos.Row.ToString())
 
    End Sub
 
End Class
Public Class Position
    Public Property Col As Integer
    Public Property Row As Integer
 
    Public Sub New(xcol As Integer, yrow As Integer)
        Col = xcol
        Row = yrow
    End Sub
End Class

Tu peux aussi utiliser un DataGridView. C'est plus exepeditif si c'est des controles identiques comme dans l'exemple precedent .
code exemple .vb d'un dgv auquel j'ai ajouté :
- 2 colonnes de type Button en Mode Design
- mis sa prop ColumnHeaderVisible=False

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
 
 
Public Class Form2
 
    Private Sub Form2_Load(sender As Object, e As System.EventArgs) Handles Me.Load
        DataGridView1.RowCount = 3
    End Sub
 
    Private Sub DataGridView1_CellClick(sender As System.Object, e As System.Windows.Forms.DataGridViewCellEventArgs) Handles DataGridView1.CellClick
 
        MessageBox.Show(e.ColumnIndex.ToString() + "," + e.RowIndex.ToString())
 
    End Sub
End Class
bon code...

31/03/2020, 14h02
HDU71000

Bonjour et merci,

il n'existe pas de contrôle tableau "tout fait" ?

J'ai jeté un oeil sur le dataGridView, mais je ne peux pas afficher de lignes.

Merci
31/03/2020, 15h56
Pol63

plusieurs choses peuvent convenir
avec un tablelayoutpanel tu peux mettre un control par zone, tu peux alors mettre un bouton ou un picturebox et gérer l'évènement click
tu peux générer tout par code (y compris l'event click et la gestion de coordonnées) plutot que de poser tout à la main
31/03/2020, 16h03
HDU71000

Oui le tableLayoutPanel semble bien, mais à priori il faut mettre des contrôles dedans, j'aurais préféré un contrôle tableau avec les propriétés (x,y) pour repérer la cellule sur laquelle on clique.

Si ça n'existe pas, bah tant pis.

Merci
31/03/2020, 18h26
Pol63

le datagridview permet en effet d'avoir les coordonnées lors d'un clic, et il est possible d'ajouter autant de colonnes et de lignes que tu veux

sinon tu peux créer ton propre controle
31/03/2020, 19h21
HDU71000

Ouais, je vais voir, mais j'ai les besoins des 2 contrôles en fait :
pouvoir générer un nombre de colonnes et de lignes
pouvoir adapter en fonction de ces nombres la taille des cellules
pouvoir obtenir les coordonnées des cellules.

Merci.

A+

Rebonjour
Le TableLayoutPanel répond aux 2 premiers soucis soit en mode Design soit en mode code behind comme deja donne dans le code communiqu" sur TableLayoutPanel.

Reste le dernier souci ce que tu appelles les coordonnées des cellules, en fait les Columns et Rows .
L'artillerie lourde "russe" peut venir à bout de tout :un custom extender provider
permet d'affecter au boutons droppés sur le TableLayoutPanel les numeros de colonnes et lignes customs nécessaires en base 1 .
Comme le démontre cet Expentder Provider avec ses 2 props en mode Design :
- GridCol sur ComponentTableau1
- GridRow sur ComponentTableau1
ou en code behind
- ComponentTableau1.SetGridCol(Control, indexCol)
- ComponentTableau1.SetGridRow(Control, indexRow)

code .vb de l'extender provider:

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
Imports System.ComponentModel
Imports System.Globalization
 
<ToolboxBitmap(GetType(ComponentTableau), "control_array.bmp")>
 <ProvideProperty("GridCol", GetType(Button))>
 <ProvideProperty("GridRow", GetType(Button))>
 <DefaultEvent("Click")>
Public Class ComponentTableau
    Inherits Component
    Implements IExtenderProvider
    Public Event Click(ByVal IndexRow As Integer, indexCol As Integer)
    Private Class IndexInfo
        Public ClientControl As Button
        Public Col As Integer
        Public Row As Integer
        ' Initialize ArrayIndex to the default value.
        Public Sub New(ByVal client_control As Button)
            ClientControl = client_control
            Col = -1
            Row = -1
        End Sub
 
        ' Return True if ArrayIndex is the default.
        Public Function IsDefault() As Boolean
            Return (Col = -1 And Row = -1)
        End Function
    End Class
    ' Information about our client controls.
    Private m_IndexInfo As New Hashtable
    ' We can only extend buttons.
    Public Function CanExtend(extendee As Object) As Boolean Implements System.ComponentModel.IExtenderProvider.CanExtend
        Return TypeOf extendee Is Button
    End Function
    ' Return this control's ArrayIndex.
    <Category("Data"), DefaultValue("-1")>
    Public Function GetGridCol(ByVal client_control As Button) As Integer
        ' Get the button's IndexInfo if it exists.
        Return GetIndexInfo(client_control).Col
    End Function
    <Category("Data"), DefaultValue("-1")>
    Public Function GetGridRow(ByVal client_control As Button) As Integer
        ' Get the button's IndexInfo if it exists.
        Return GetIndexInfo(client_control).Row
    End Function
 
 
    ' Set this control's ArrayIndex.
    <Category("Data"), DefaultValue("-1")>
    Public Sub SetGridCol(ByVal client_control As Button, ByVal indexCol As Integer)
        ' Get this control's info.
        Dim index_info As IndexInfo = GetIndexInfo(client_control)
 
        ' Set the new minimum value.
        index_info.Col = indexCol
 
        ' Add or remove the IndexInfo if necessary.
        AddOrRemoveIfNecessary(client_control, index_info)
    End Sub
    <Category("Data"), DefaultValue("-1")>
    Public Sub SetGridRow(ByVal client_control As Button, ByVal indexRow As Integer)
        ' Get this control's info.
        Dim index_info As IndexInfo = GetIndexInfo(client_control)
 
        ' Set the new minimum value.
        index_info.Row = indexRow
 
        ' Add or remove the IndexInfo if necessary.
        AddOrRemoveIfNecessary(client_control, index_info)
    End Sub ' Remove the control from the array.
    <Category("Data")>
    Public Sub RemoveGridCol(ByVal client_control As Button)
        ' Set the control's index to the default -1.
        SetGridCol(client_control, -1)
    End Sub
    <Category("Data")>
    Public Sub RemoveGridRow(ByVal client_control As Button)
        ' Set the control's index to the default -1.
        SetGridRow(client_control, -1)
    End Sub
    ' Return this control's IndexInfo.
    Private Function GetIndexInfo(ByVal client_control As Button) As IndexInfo
        ' See if we have IndexInfo for this control.
        If m_IndexInfo.Contains(client_control) Then
            ' We have IndexInfo for this control. Return it.
            Return CType(m_IndexInfo(client_control), IndexInfo)
        Else
            ' We do not have IndexInfo for this control.
            ' Return a new default IndexInfo.
            Return New IndexInfo(client_control)
        End If
    End Function
 
    ' Add or remove this IndexInfo if necessary.
    Private Sub AddOrRemoveIfNecessary(ByVal client_control As Button, ByVal index_info As IndexInfo)
        ' See if the IndexInfo should be present but is not,
        ' or should not be present but is.
        If index_info.IsDefault <> Not m_IndexInfo.Contains(client_control) Then
            If index_info.IsDefault Then
                ' The IndexInfo should not be present but is.
                m_IndexInfo.Remove(client_control)
                RemoveHandler client_control.Click, AddressOf Client_Click
            Else
                ' The IndexInfo should be present but is not.
                m_IndexInfo.Add(client_control, index_info)
                AddHandler client_control.Click, AddressOf Client_Click
            End If
        End If
    End Sub
    ' Handles client button Click events by raising our
    ' Click event, passing it the button's index.
    Private Sub Client_Click(ByVal sender As System.Object, ByVal e As System.EventArgs)
        ' Get the client and its IndexInfo.
        Dim client_button As Button = DirectCast(sender, Button)
        Dim index_info As IndexInfo = GetIndexInfo(client_button)
        RaiseEvent Click(index_info.Col, index_info.Row)
    End Sub
    ' Return an Collection holding
    ' the controls in the array.
    Public Function Controls() As Collection
        ' Build the collection.
        Dim result As New Collection
        For Each index_info As IndexInfo In m_IndexInfo.Values
            result.Add(index_info.ClientControl)
        Next index_info
 
        ' Return the collection.
        Return result
    End Function
End Class

code du form user avec un TableLayoutPanel dotés de 3 colonnes et 3 rows + le composant ComponentTableau &
Les 9 buttons droppes (1 à 9) ont reçu leur coord -colonne et ligne - en mode Design.

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
Imports System.Windows.Forms
Public Class Form1
    Private nbColumn As Integer = 3
    Private nbRow As Integer = 3
    Private Sub Form1_Load(sender As System.Object, e As System.EventArgs) Handles MyBase.Load
        TableLayoutPanel1.Location = New Point(100, 100)
        TableLayoutPanel1.ColumnCount = nbColumn
        TableLayoutPanel1.RowCount = nbRow
        TableLayoutPanel1.ColumnStyles.Add(New ColumnStyle(SizeType.Percent, 50.0))
        TableLayoutPanel1.ColumnStyles.Add(New ColumnStyle(SizeType.Percent, 50.0))
 
    End Sub
 
 
 
    Private Sub Button9_Click(sender As System.Object, e As System.EventArgs) Handles Button9.Click, Button8.Click, Button7.Click, Button6.Click, Button5.Click, Button4.Click, Button3.Click, Button2.Click, Button1.Click
        Dim btn As Button = CType(sender, Button)
        Dim col As Integer = ComponentTableau1.GetGridCol(btn)
        Dim row As Integer = ComponentTableau1.GetGridRow(btn)
        MessageBox.Show(btn.Name + " col:" + col.ToString() + " row :" + row.ToString())
    End Sub
End Class

capture d'ecran attaché ci -joint du form user.
Pièce jointe 551490

bon code...

01/04/2020, 14h11
HDU71000
Bonjour,
merci, mais c'est sortir le bazooka pour tuer une pov' mouche là !! :ptdr:

Cependant, je ne comprends pas dans ton dernier code pourquoi tu mets 2 fois la même ligne, et surtout qu'il y a 3 colonnes du coup :
Code:

1 2 3 TableLayoutPanel1.ColumnStyles.Add(New ColumnStyle(SizeType.Percent, 50.0)) TableLayoutPanel1.ColumnStyles.Add(New ColumnStyle(SizeType.Percent, 50.0))
Merci à toi
01/04/2020, 15h09
MABROUKI

En fait c'est une erreur de frappe à 2 heures du matin.
la 2 e ligne c'est un "New RowStyle" au vu de la capture d’écran.
Quant au bazooka il devra être encore plus puissant si tu veux un custom Control doté d'une grille réactive.
En fait tu ne sais probablement pas ce que tu veux.
01/04/2020, 15h17
HDU71000

Si, je sais très bien ce que je veux :
L'utilisateur saisi le nombre de lignes et de colonnes qu'il veut.
De là se génère un tableau autodimensionné (cellules carrées) avec le nombre de lignes et de colonnes
Le programme doit être capable de savoir sur quelle cellule l'utilisateur clique (un peu comme le jeu du morpion).

Merci !