Script de déplacement de fichier et archivage

Version imprimable

06/03/2020, 10h04
GADENSEB

Script de déplacement de fichier et archivage

Bonjour le Forum,
J'ai une question toute bête

J'ai un dossier "A" qui a comme sous-dossiers :
-"a1"
-"a2"
-"a3"
- "Ok Archivé"

je voudrais copiés les fichiers nouvellement arrivés dans ce dossier A et ses-sous dossiers (sauf "OK Archivé") vers un autre dossier appelé B

puis replacer ces fichiers copiés dans les mm sous-dossiers "A1"..... dans "ok archivé" qui est l'archive de sauvegarde de "A"

Je ne sais pas si j'ai étais clair

Bonjour,

Voilà un exemple :

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
@echo off
setlocal enabledelayedexpansion
chcp 28591 >nul
 
set "source=D:\Dossier A"
set "destination=Q:\Dossier B"
set "archivage=%source%\Ok archivé"
 
cd /d %source% || exit /b 1
 
if not exist "%destination%" (mkdir "%destination%")
if not exist "%archivage%" (mkdir "%archivage%")
 
for /r %%A in (*.*) do (
 
	echo.
	xcopy /Y "%%~A" "%destination%" && call :fonction "%%~A"
 
)
 
pause
exit /b 0
 
:fonction
 
set "fichier=%~dp1"
 
echo.!fichier! | find "%archivage%" >nul || (
	set "archive=!fichier:%source%=%archivage%!"
	echo.
	xcopy /Y %1 "!archive!"
)
 
goto :eof

N'oublie pas de modifier la variable source et la variable destination en début de script.

09/03/2020, 10h19
GADENSEB

Hello
Merci à toi.
Je teste cela ce soir

Bonjour,
Bon j'ai du me planter quelque part…….
L'adresse source : D:\PHOTOS\ADO- SAUVEGARDE TELEPHONE
L'adresse destination : D:\PHOTOS\SGA - A TRIER

Il me signale une erreur sur la première ligne

Où je me suis planté ?

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
@echo off
setlocal enabledelayedexpansion
chcp 28591 >nul
 
set "source=D:\PHOTOS\ADO - SAUVEGARDE TELEPHONE"
set "destination=D:\PHOTOS\SGA  -  A  TRIER"
set "archivage=%source%\Ok archivé"
 
cd /d %source% || exit /b 1
 
if not exist "%destination%" (mkdir "%destination%")
if not exist "%archivage%" (mkdir "%archivage%")
 
for /r %%A in (*.*) do (
 
 echo.
 xcopy /Y "%%~A" "%destination%" && call :fonction "%%~A"
 
)
 
pause
exit /b 0
 
:fonction
 
set "fichier=%~dp1"
 
echo.!fichier! | find "%archivage%" >nul || (
 set "archive=!fichier:%source%=%archivage%!"
 echo.
 xcopy /Y %1 "!archive!"
)
 
goto :eof

13/03/2020, 09h27
enki31

Bonjour,

Question : avec quoi tu lances ce script?

Bonne journée.
13/03/2020, 09h49
GADENSEB

Hello
J'ai fais un .VBS
13/03/2020, 10h05
enki31

Citation:

Envoyé par GADENSEB

Hello
J'ai fais un .VBS

je ne suis pas expert, mais il me semble que ce script est un .BAT
13/03/2020, 10h07
GADENSEB

Ok
Je teste ce soir.
Merci à toi
22/03/2020, 14h23
GADENSEB

1 pièce(s) jointe(s)

Hello
J'ai testé le script et cela semble fonctionné.
Par contre j'ai eu un beug a cause des accent "ok archivé" et cela à resync ce dossier en faisant un dossier "ok achiv@"
Du coup j'ai transformé le dossier en "OK ARCHIVE"
voici la copie d'écran du dossier concerné
Pièce jointe 548155
Est-ce que ton code fonctionne sur ce schéma ?

Est-ce possible de rajouter un critère de transformation dans le dossier de destination ?
--> Créer un dossier avec la date par regroupement de fichiers, a 99% des photos.

--> Si j'ai un des photos qui contient, par titre, de fichiers 20200321 cela créer un dossier avec ts les fichiers avec cette date/nom de fichier vers un dossier "2020 03 21"

Merci à toi, j’espère que tu vas bien dans cette période compliquée.
22/03/2020, 15h53
barnabe0057

Salut tout va bien pour moi merci.

Pas de problème mon code est compatible avec ton arborescence.

Pour le critère avec la date des fichiers, il faudrait que je sache comment sont nommées les photos actuellement.
Est-ce qu'elles sont toutes nommées de la même façon ?
23/03/2020, 13h56
GADENSEB

1 pièce(s) jointe(s)

Bonjour
Merci de ton aide
voici le format des différents fichiers. je pense qu'il ne faut tenir compte que de 2019011 au centre du nom de fichier par exemple

Pièce jointe 548426

Concernant l'atterrissage dans un dossier de type "2019 09 11", pourrait on dire que si le dossier existe déjà, les nouvelles photos seront importées dans ce mm dossier sans en créer un nouveau ?
Merci à toi
28/03/2020, 14h21
GADENSEB

Hello
As-tu une idée pour ce petit programme ? :-)
28/03/2020, 15h17
barnabe0057

Slt oui j'ai une idée, je te recontacte rapidement, j'étais occupé sur un projet ces derniers jours.
28/03/2020, 15h25
GADENSEB

Hello pas de soucis !
Bonne am à toi

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
@echo off
setlocal enabledelayedexpansion
chcp 28591 >nul
 
set "source=D:\PHOTOS\ADO - SAUVEGARDE TELEPHONE"
set "destination=D:\PHOTOS\SGA  -  A  TRIER"
set "archivage=%source%\OK ARCHIVE"
 
 
cd /d %source% || exit /b 1
 
if not exist "%destination%" (mkdir "%destination%")
if not exist "%archivage%" (mkdir "%archivage%")
 
for /r %%A in (*.*) do (
	for /f "tokens=2 delims=_-" %%E in ("%%~nA") do (
 		echo.%%E | findstr /R "[0-9][0-9][0-9][0-9][0-9][0-9]" >nul && (
			set "dossier=%%E"
			set "dossier=!dossier:~0,4! !dossier:~4,2! !dossier:~6,2!"
			if not exist "%destination%\!dossier!" (mkdir "%destination%\!dossier!")
			echo.
			xcopy /Y "%%~A" "%destination%\!dossier!" && call :fonction "%%~A"
		)
	) 
)
 
pause
exit /b 0
 
:fonction
 
set "fichier=%~dp1"
 
echo.!fichier! | find "%archivage%" >nul || (
	set "archive=!fichier:%source%=%archivage%!"
	echo.
	xcopy /Y %1 "!archive!"
)
 
goto :eof

30/03/2020, 13h43
GADENSEB

Hello
Je te remercie.
Je regarde cela dés ce soir !

Hello
Cela semble fonctionner parfaitement.
j'ai juste fait une modif dans le dossier d'archivage.
Je l'ai déplacé du dossier source

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
@echo offsetlocal enabledelayedexpansion
chcp 28591 >nul
 
set "source=D:\PHOTOS\ADO - SAUVEGARDE TELEPHONE"
set "destination=D:\PHOTOS\A  TRIER"
set "archivage=D:\PHOTOS\ADO - ARCHIVAGE"
 
 
cd /d %source% || exit /b 1
 
if not exist "%destination%" (mkdir "%destination%")
if not exist "%archivage%" (mkdir "%archivage%")
 
for /r %%A in (*.*) do (
    for /f "tokens=2 delims=_-" %%E in ("%%~nA") do (
         echo.%%E | findstr /R "[0-9][0-9][0-9][0-9][0-9][0-9]" >nul && (
            set "dossier=%%E"
            set "dossier=!dossier:~0,4! !dossier:~4,2! !dossier:~6,2!"
            if not exist "%destination%\!dossier!" (mkdir "%destination%\!dossier!")
            echo.
            xcopy /Y "%%~A" "%destination%\!dossier!" && call :fonction "%%~A"
        )
    ) 
)
 
pause
exit /b 0
 
:fonction
 
set "fichier=%~dp1"
 
echo.!fichier! | find "%archivage%" >nul || (
    set "archive=!fichier:%source%=%archivage%!"
    echo.
    xcopy /Y %1 "!archive!"
)
 
goto :eof

Question en plus :
Je serais intéressé de reprendre le mm code mais sans la notion d'archivage....
quelles lignes dois-je supprimer ?
autant dans un code VBA excel, je vois, mais la je suis débutant
Je dirais

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
@echo offsetlocal enabledelayedexpansion
chcp 28591 >nul
 
set "source=D:\PHOTOS\ADO - SAUVEGARDE TELEPHONE"
set "destination=D:\PHOTOS\SGA  -  A  TRIER"
 
 
cd /d %source% || exit /b 1
 
if not exist "%destination%" (mkdir "%destination%")
 
 
for /r %%A in (*.*) do (
    for /f "tokens=2 delims=_-" %%E in ("%%~nA") do (
         echo.%%E | findstr /R "[0-9][0-9][0-9][0-9][0-9][0-9]" >nul && (
            set "dossier=%%E"
            set "dossier=!dossier:~0,4! !dossier:~4,2! !dossier:~6,2!"
            if not exist "%destination%\!dossier!" (mkdir "%destination%\!dossier!")
            echo.
            xcopy /Y "%%~A" "%destination%\!dossier!"        )
    ) 
)
 
pause
exit /b 0
  goto :eof

C'est bien cela ?

Autre complément les fichiers ne semblent pas avoir été supprimés de la source après déplacement/création de dossier/archivage.
ya til un code à rajouter ? aussi pour le code en Version sans archivage ?

Salut, merci bonne journée également.

Voilà le code sans l'archivage et avec le déplacement des fichiers au lieu de la copie :

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
@echo off
setlocal enabledelayedexpansion
chcp 28591 >nul
 
set "source=D:\PHOTOS\ADO - SAUVEGARDE TELEPHONE"
set "destination=D:\PHOTOS\SGA  -  A  TRIER"
 
cd /d %source% || exit /b 1
 
if not exist "%destination%" (mkdir "%destination%")
 
for /r %%A in (*.*) do (
	for /f "tokens=2 delims=_-" %%E in ("%%~nA") do (
 		echo.%%E | findstr /R "[0-9][0-9][0-9][0-9][0-9][0-9]" >nul && (
			set "dossier=%%E"
			set "dossier=!dossier:~0,4! !dossier:~4,2! !dossier:~6,2!"
			if not exist "%destination%\!dossier!" (mkdir "%destination%\!dossier!")
			echo.
			move /Y "%%~A" "%destination%\!dossier!"
		)
	) 
)
 
pause
exit /b 0

31/03/2020, 14h03
GADENSEB

hello
Merci à toi
Je regarde dans la journée
01/04/2020, 09h30
GADENSEB

Hello
J'ai testé hier soir et ca marche super bien !!!
good job :)

Dans le code avec l'archivage, est-ce que l'on pourrait inclure le déplacement (suppression) des fichiers après archivage ?
Pour résumer dans ce code :
- On copie
- On archive
- on supprime

J e n'ai peut être pas les bons mots !

Merci à toi
01/04/2020, 09h36
barnabe0057

Salut,

Pour déplacer au lieu de copier il suffit de remplacer la deuxième commande XCOPY par la commande MOVE, c'est aussi simple que ça.

Je te souhaite une bonne journée.
01/04/2020, 09h45
GADENSEB

ok ok
J'en apprends tous les jours !
je regarde
01/04/2020, 09h48
barnabe0057

Si tu veux des explications sur le fonctionnement du code, n'hésite pas.

C'est vrai que je n'ai pas mis beaucoup de commentaires pour expliquer ce que font les différentes parties.
01/04/2020, 09h53
GADENSEB

Je veux bien la version avec les commentaires !!

Voilà j'espère que c'est plus clair maintenant :

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
@echo off
 
: --------------------------------------------------------------
: on active l'expansion retardée des variables
: --------------------------------------------------------------
 
setlocal enabledelayedexpansion
 
: --------------------------------------------------------------
: on modifie le codepage pour prendre en compte les accents
: --------------------------------------------------------------
 
chcp 28591 >nul
 
: --------------------------------------------------------------
: on définit les variables dont on aura besoin
: --------------------------------------------------------------
 
set "source=D:\PHOTOS\ADO - SAUVEGARDE TELEPHONE"
set "destination=D:\PHOTOS\SGA  -  A  TRIER"
set "archivage=%source%\OK ARCHIVE"
 
: --------------------------------------------------------------
: on se positionne dans le dossier contenant les fichiers
: tout en vérifiant que le dossier existe bien, sinon on
: quitte le script
: --------------------------------------------------------------
 
cd /d %source% || exit /b 1
 
: --------------------------------------------------------------
: on crée les dossiers où vont arriver les fichiers
: --------------------------------------------------------------
 
if not exist "%destination%" (mkdir "%destination%")
if not exist "%archivage%" (mkdir "%archivage%")
 
: --------------------------------------------------------------
: on traite tous les fichiers du dossier
: --------------------------------------------------------------
 
for /r %%A in (*.*) do (
	for /f "tokens=2 delims=_-" %%E in ("%%~nA") do (
 		echo.%%E | findstr /R "[0-9][0-9][0-9][0-9][0-9][0-9]" >nul && (                 %rem on récupère la deuxième partie (tokens=2) du nom et on vérifie qu'il s'agit bien de 6 chiffres %
			set "dossier=%%E"
			set "dossier=!dossier:~0,4! !dossier:~4,2! !dossier:~6,2!"               %rem on découpe la date récupérée dans le nom de fichier pour créer un nouveau nom de dossier %
			echo.                                                                    %rem on saute une ligne %
			if not exist "%destination%\!dossier!" (mkdir "%destination%\!dossier!") %rem on crée le nouveau dossier s'il n'existe pas %
			xcopy /Y "%%~A" "%destination%\!dossier!" && call :fonction "%%~A"       %rem on copie le fichier dans le dossier d'arrivée et on appelle (CALL) la routine d'archivage %
		)
	) 
)
 
echo. & pause
 
: --------------------------------------------------------------
: fin du script, on quitte (le code erreur 0 est facultatif)
: --------------------------------------------------------------
 
exit /b 0
 
: --------------------------------------------------------------
: on crée une routine pour déplacer les fichiers dans l'archive
: --------------------------------------------------------------
 
:fonction
 
set "fichier=%~dp1"					%rem on récupère le chemin du fichier qu'on doit archiver %
 
echo.!fichier! | find "%archivage%" >nul || (           %rem astuce pour exclure les fichiers déjà archivés %
	set "archive=!fichier:%source%=%archivage%!"    %rem on substitue le chemin du fichier avec le chemin de l'archive %
	>nul move /Y %1 "!archive!"                     %rem on déplace le fichier dans l'archive %
)
 
: --------------------------------------------------------------
: on quitte la routine, on revient à la ligne succédant le CALL
: --------------------------------------------------------------
 
goto :eof

En testant le script incluant les commentaires je me suis rendu compte d'un petit problème, je vais essayer de rectifier et je reviens vers toi.

Voilà la version corrigée :

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
@echo off
 
: --------------------------------------------------------------
: on active l'expansion retardée des variables
: --------------------------------------------------------------
 
setlocal enabledelayedexpansion
 
: --------------------------------------------------------------
: on modifie le codepage pour prendre en compte les accents
: --------------------------------------------------------------
 
chcp 28591 >nul
 
: --------------------------------------------------------------
: on définit les variables dont on aura besoin
: --------------------------------------------------------------
 
set "source=D:\PHOTOS\ADO - SAUVEGARDE TELEPHONE"
set "destination=D:\PHOTOS\SGA  -  A  TRIER"
set "archivage=%source%\OK ARCHIVE"
 
: --------------------------------------------------------------
: on se positionne dans le dossier contenant les fichiers
: tout en vérifiant que le dossier existe bien, sinon on
: quitte le script
: --------------------------------------------------------------
 
cd /d %source% || exit /b 1
 
: --------------------------------------------------------------
: on crée les dossiers où vont arriver les fichiers
: --------------------------------------------------------------
 
if not exist "%destination%" (mkdir "%destination%")
if not exist "%archivage%" (mkdir "%archivage%")
 
: --------------------------------------------------------------
: on traite tous les fichiers du dossier
: --------------------------------------------------------------
 
for /r %%A in (*.*) do (
 
	echo.%%A | findstr /i /C:"%archivage%" /C:"%destination%" >nul || (                                          %rem on exclut les fichiers de l'archive et du dossier d'arrivée %
 
		for /f "tokens=2 delims=_-" %%E in ("%%~nA") do (
 
 			echo.%%E | findstr /R "[0-9][0-9][0-9][0-9][0-9][0-9]" >nul && call:fonction "%%~E" "%%~A"   %rem on récupère la deuxième partie (tokens=2) du nom et on vérifie qu'il s'agit bien de 6 chiffres %
 
		)
	)
)
 
echo. & pause
 
: --------------------------------------------------------------
: fin du script, on quitte (le code erreur 0 est facultatif)
: --------------------------------------------------------------
 
exit /b 0
 
: --------------------------------------------------------------
: on crée une routine pour déplacer les fichiers et les archiver
: --------------------------------------------------------------
 
:fonction
 
set "dossier=%~1"
set "dossier=!dossier:~0,4! !dossier:~4,2! !dossier:~6,2!"               %rem on découpe la date récupérée dans le nom de fichier pour créer un nouveau nom de dossier %
 
if not exist "%destination%\!dossier!" (mkdir "%destination%\!dossier!") %rem on crée le nouveau dossier s'il n'existe pas %
 
echo.                                                                    %rem on saute une ligne %
 
xcopy /Y "%~2" "%destination%\!dossier!" && (                            %rem on copie le fichier dans le dossier d'arrivée %
 
	set "fichier=%~dp2"					         %rem on récupère le chemin du fichier qu'on doit archiver %
	set "archive=!fichier:%source%=%archivage%!"                     %rem on substitue le chemin du fichier par le chemin de l'archive %
	>nul move /Y "%~2" "!archive!"                                   %rem on déplace le fichier dans l'archive %
 
)
 
: --------------------------------------------------------------
: on quitte la routine, on revient à la ligne succédant le CALL
: --------------------------------------------------------------
 
goto :eof

La correction concerne le scénario dans lequel le dossier d'archive ou bien le dossier d'arrivée ferait partie du dossier de départ, ce qui entrainerait une prise en compte inutile de ces fichiers.

01/04/2020, 13h40
GADENSEB

Merci à toi !
Je vais étudier !!!
07/04/2020, 13h51
GADENSEB

Hello
Merci pour le descriptif je pense avoir compris l'enchainement !
Petite question :
Est-ce que je peux enchaine les différents codes ?
Cela ne posera de problème pour les variable "Source....." ?