Ouvrir via une macro les formats .xls

Version imprimable

03/01/2020, 14h40
Anthony WA

Ouvrir via une macro les formats .xls
Bonjour,

Après quelques recherches, je ne trouve pas la solution à mon problème, donc je fait appel à vous ...

Mon problème est assez simple.

Je souhaiterais ouvrir les fichiers au format .xls présent dans un dossier et UNIQUEMENT ceux ci.

Voici le début de macro que j'ai :
Code:

1 2 3 Set fldr = FSO.GetFolder(liendemondossier) For Each file In fldr.Files 'ici je traite ce qui m'intéresse avec mes fichiers
Seulement dans mon dossier j'ai également des fichiers PDF... mais ceux ci ne sont pas à prendre en compte

Voilà, n'hésitez pas si il manque des infos !

A bientôt

AW

Bonjour,

Essaies :

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
Sub Ouvre_Fichiers()
' Ouvre tous les fichiers excel contenus dans un répertoire.
'
Dim Système As Object           'Système de fichiers
Dim Dossier As Object           'Répertoire
Dim Fichiers As Object          'Collection de fichiers du répertoire
Dim Fichier As Object           'Fichier (élément de la collection Fichiers)
Dim Nom_Dossier As String       'Nom du répertoire
Dim Nom_Fichier As String       'Nom du fichier
 
'Lecture du répertoire
Nom_Dossier = "D:\TEMP"  'à adapter
Set Système = CreateObject("Scripting.FileSystemObject")
Set Dossier = Système.GetFolder(Nom_Dossier)
Set Fichiers = Dossier.Files
'Contrôler chaque fichier du répertoire
For Each Fichier In Fichiers
  '- Vérifier s'il s'agit d'un fichier Excel...
  If StrComp(Système.GetExtensionName(Fichier.Name), "xls", vbTextCompare) = 0 Then
    '... dans l'affirmative, ouvrir le fichier et mettre à jour les liaisons
    Nom_Fichier = Nom_Dossier & "\" & Fichier.Name
    Workbooks.Open Filename:=Nom_Fichier, UpdateLinks:=xlUpdateLinksAlways
  End If
Next Fichier
 
End Sub

Bonjour,

Tu peux essayer avec like

Code:

1
2
3
4
5
6
 
 Set fldr = FSO.GetFolder(liendemondossier)
              For Each file In fldr.Files
                   'ici je traite ce qui m'intéresse avec mes fichiers
'Seulement dans mon dossier j'ai également des fichiers PDF... mais ceux ci ne sont pas à prendre en compte
                 if file like "*.xls" then ...  'ou file.name like

03/01/2020, 16h12
Anthony WA

C'est parfait,

je l'ai légèrement adapté, mais tout y est ! merci !