[XL-2013] Probleme avec Combobox

Probleme avec Combobox

Bonjour tout le monde
J ai un petit souci avec ma ComboBox (userForm), elle récupère une colonne d'une feuille de Calcule.
Le problème c'est que j ai des valeurs qui se répètent dans cette colonne et je veux qu'elles soient récupérées ou apparaissent qu'une seule fois dans la camboBox
Merci Bonne journée

Bonjour Taha, bonjour le forum,

Imaginons que ce soient les données de la colonne 1 qui alimentent ta ComboBox (tu adapteras...). Le plus rapide est de passer par un objet Dictionnaire avec un code du type :

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
Private Sub UserForm_Initialize() 'à l'initalisation de l'Userform
Dim O As Worksheet 'déclare la variable O (Onglet)
Dim DL As Integer 'déclare la variable DL (Derniere Ligne)
Dim TV As Variant 'déclare la variable TV (Tableau des Valeurs)
Dim D As Object 'déclare la variable D (Dictionnaire)
Dim I As Integer 'déclare la variable I (Incrément)
 
Set O = Worksheets("Feuil1") 'définit l'onglet O (à adapter a ton cas)
DL = O.Cells(Application.Rows.Count, "A").End(xlUp).Row 'définit la dernière ligne éditée DL de la colonne A de l'onglet O (colonne à adapter à ton cas)
TV = Range("A1:A" & DL) 'de'finit la tableau des valeurs TV (à adapter avec lea colonne)
Set D = CreateObject("Scripting.Dictionary") 'définit le dictionanire D
For I = 2 To DL 'boucle sur toutes les lignes I du tableau des valeurs (en partant de la seconde car souvent la première contient le titre)
    D(TV(I, 1)) = "" 'alimente le dictionnaire D avec les données en colonne 1 du tableau des valeurs TV
Next I 'prochaine ligne de la boucle
Me.ComboBox1.List = D.Keys 'alimente la ComboBox1 avec la liste des éléments du dictionanire D sans doublon
End Sub

Merci beaucoup Thauthème je vais essayer ton Code