Extraire les nombres dans une cellule

Version imprimable

Bonjour,

Après avoir parcouru le forum j'ai trouvé une fonction se rapprochant de ce que je souhaite effectuer :
Code:

1 2 3 4 5 6 7 8 9 10 11 Function LesMinuscules(Cellule As Range) As String Dim i As Integer If Cellule.Cells.Count > 1 Then Exit Function For i = 1 To Len(Cellule.Value) If UCase(Mid(Cellule.Value, i, 1)) <> Mid(Cellule.Value, i, 1) Then LesMinuscules = LesMinuscules & Mid(Cellule.Value, i, 1) End If Next i End Function
Je souhaiterais comprendre la fonction suivante et la modifier pour récupérer seulement les nombres/chiffres dans une cellule ex : aaaa34ZZZ -> 34 54AAAzzzzzz ->54 aaaaZZZ87 -> 87

Bien Cordialement,

Dolgar

Source :
https://www.developpez.net/forums/d1...lphanumerique/
https://www.developpez.net/forums/d1...s/#post8239065
Merci à joe.levrai pour sa fonction LesMinuscules

Bonjour,

j'ai annoté la fonction pour la compréhension

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
Function LesMinuscules(Cellule As Range) As String
Dim i As Integer
' Si la plage indiquée dans la formule contient plus d'une cellule on ne traite pas
If Cellule.Cells.Count > 1 Then Exit Function
 
' pour chaque caractère dans la cellule
For i = 1 To Len(Cellule.Value)
    ' si le caractère, mis en majuscule, est différent du caractère réel
    If UCase(Mid(Cellule.Value, i, 1)) <> Mid(Cellule.Value, i, 1) Then
        ' on l'ajoute dans la chaine de résultat (car c'est un minuscule)
        LesMinuscules = LesMinuscules & Mid(Cellule.Value, i, 1)
    End If
Next i
 
End Function

Maintenant, pour extraire les chiffres, on peut procéder de la même manière, mais au lieu de comparer le caractère en majuscule, on va tester si le caractère est numérique

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
Function ExtraireChiffres(Cellule As Range) As String
Dim i As Integer
 
' Si la plage indiquée dans la formule contient plus d'une cellule on ne traite pas
If Cellule.Cells.Count > 1 Then Exit Function
 
' pour chaque caractère dans la cellule
For i = 1 To Len(Cellule.Value)
    ' si le caractère est numérique
    If IsNumeric(Mid(Cellule.Value, i, 1)) Then
        ' on l'ajoute dans la chaine de résultat (car c'est un chiffre)
        ExtraireChiffres = ExtraireChiffres & Mid(Cellule.Value, i, 1)
    End If
Next i
 
End Function

ceci est un cas général qui va concaténer tous les chiffres
xx41qq31 >> 4131

s'il faut y mettre un espace, il suffit de modifier la ligne qui concatène en ajoutant un " "

06/12/2019, 11h52
Dolgar

Merci beaucoup joe.levrai pour les explications !

Bonne continuation,

Dolgar