Module avec plusieurs conditions

Version imprimable

05/11/2019, 17h38
ElMizuno41

Module avec plusieurs conditions

Bonjour,

J'aimerais si possible, éditer une macro afin d'envoyer un e-mail de relance à plusieurs clients.

Cependant, étant donné que certaines lignes concernent un seul client, j'aimerai qu'un seul e-mail lui soit envoyé.

Voici mon mail type :

"Référence :

- Equipement n°(Cellule A2) situé à (Cellule A3) pour (Cellule A4)"

Donc, si un client a 3 lignes, je souhaites que la macro lui envoie un seul mail mais avec 3 références...
Et si, un client a 1 ligne, ça lui envoie qu'une référence...

Et si par la suite, j'aimerais savoir si il est possible d'ajouter automatiquement des pièces jointes en fonction du numéro d'équipement "A2" ?

Je suis désolé si je me suis mal exprimé...

Cordialement,
06/11/2019, 08h02
Theze

Bonjour,

Il faudrait savoir comment sont organisés tes valeurs (à priori, en colonnes et pas en lignes) mais je pense que le mieux est d'utiliser un dictionnaire en concaténant les références et où la clé serait le nom du client.
06/11/2019, 11h00
ElMizuno41

Bonjour,

Ma première ligne contient mes valeurs comme :
A1 : Nom du client
A2 : Numéro d'équipement
A3 : Adresse
A4 : Montant

Ensuite, mes lignes sont spécifiques à un numéro d'équipement.
Cependant, parfois, deux lignes (donc deux numéros d'équipements) appartiennent à un seul client.
06/11/2019, 14h43
Theze

2 pièce(s) jointe(s)

Tes enregistrements sont comme ceci ?
Pièce jointe 515404

ou comme cela ?

Pièce jointe 515407
06/11/2019, 15h00
ElMizuno41

1 pièce(s) jointe(s)

Comme ceci... Désolé pour mon explications bidon !
Pièce jointe 515444

1 pièce(s) jointe(s)

Donc, voici une piste pour la récup des valeurs :

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
 
Sub Test()
 
    Dim Dico As Object
    Dim Cle As Variant
    Dim Plage As Range
    Dim Cel As Range
    Dim T As Variant
    Dim Chaine1 As String
    Dim Chaine2 As String
    Dim I As Integer
 
    Set Dico = CreateObject("Scripting.Dictionary")
 
    'défini la plage sur la colonne A de la feuille active à partir de A1 (colonne des noms)
    With ActiveSheet: Set Plage = .Range(.Cells(2, 1), .Cells(.Rows.Count, 1).End(xlUp)): End With
 
    'cocatène le Numéro d'équipement avec le montant séparés par un tiret bas et ensuite, sépare
    'les enregistrements par une virgule
    For Each Cel In Plage
 
        Dico(Cel.Value) = Dico(Cel.Value) & Cel.Offset(, 1).Value & "_" & Cel.Offset(, 3).Value & ","
 
    Next Cel
 
    For Each Cle In Dico.Keys
 
        'splite dans un tableau
        T = Split(Dico(Cle), ",")
 
        'construction des deux chaînes
        Chaine1 = Cle & "," & vbCrLf & vbCrLf
        Chaine2 = "Sauf erreur de notre part, vous nous êtes redevable " & IIf(UBound(T) > 1, "des sommes", "de la somme") & " ci-dessous :" & vbCrLf & vbCrLf
 
        'extrait le numéro d'équipement et le montant et inscrit les enregistrement les uns sous les autres
        For I = 0 To UBound(T) - 1
            Chaine2 = Chaine2 & "pour le numéro d'équipement " & Split(T(I), "_")(0) & " d'un montant de " & Split(T(I), "_")(1) & vbCrLf
        Next I
 
        'finalise
        Chaine1 = Chaine1 & Chaine2 & vbCrLf & "En l'attente de votre règlement, veuillez agréer, " & Cle & ", mes sincères salutations."
        Chaine1 = Chaine1 & vbCrLf & vbCrLf & "ElMizuno41"
 
        'ici, il faut envoyer les mails
        MsgBox Chaine1
 
        'vide pour le suivant
        Chaine1 = "": Chaine2 = ""
 
    Next Cle
 
End Sub

Je n'ai rien fais pour l'envoi par mail car je ne sais pas où sont les adresses !
Le classeur est monté de cette façon :

Pièce jointe 515451

et tu auras des boites de messages successives pour le test !

06/11/2019, 15h56
ElMizuno41

Ah oui, tu es rapide et hyper efficace ! J'ai regardé ce que tu as fait et c'est propre.

Je suis en train d'essayer de modifier car en réalité la ligne 1 se situe comme ceci :
• Nom du client est colonne N
• Numéro d'équipement est colonne O
• Adresse du site est colonne M
• Montant est colonne AB
Et les adresses mails sont colonnes Y

Voici le code par rapport à tes précisions ainsi qu'une procédure d'envoi de mails. Fais un test sur 3 ou 4 clients en mettant ton adresse mail pour tous afin de contrôler ce qui sera envoyé et de l'adapter à tes envies :

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
 
Sub Test()
 
    Dim Dico As Object
    Dim Cle As Variant
    Dim Plage As Range
    Dim Cel As Range
    Dim T As Variant
    Dim Chaine1 As String
    Dim Chaine2 As String
    Dim AdresseMail As String
    Dim I As Integer
 
    Set Dico = CreateObject("Scripting.Dictionary")
 
    'défini la plage sur la colonne N de la feuille active à partir de N2 (colonne des noms)
    With ActiveSheet: Set Plage = .Range(.Cells(2, 14), .Cells(.Rows.Count, 14).End(xlUp)): End With
 
    'concatène le Numéro d'équipement avec le montant et l'adresse mail séparés par un tiret bas et ensuite, sépare
    'les enregistrements par une virgule
    For Each Cel In Plage
 
        Dico(Cel.Value) = Dico(Cel.Value) & Cel.Offset(, 1).Value & "_" & Cel.Offset(, 14).Value & "_" & Cel.Offset(, 11).Value & ","
 
    Next Cel
 
    For Each Cle In Dico.Keys
 
        'splite dans un tableau
        T = Split(Dico(Cle), ",")
 
        'construction des deux chaînes
        Chaine1 = Cle & "," & vbCrLf & vbCrLf
        Chaine2 = "Sauf erreur de notre part, vous nous êtes redevable " & IIf(UBound(T) > 1, "des sommes", "de la somme") & " ci-dessous :" & vbCrLf & vbCrLf
 
        For I = 0 To UBound(T) - 1
 
            'mémorise l'adresse mail
            If AdresseMail = "" Then AdresseMail = Split(T(I), "_")(2)
 
            'extrait le numéro d'équipement et le montant et inscrit les enregistrement les uns sous les autres
            Chaine2 = Chaine2 & "pour le numéro d'équipement " & Split(T(I), "_")(0) & " d'un montant de " & Split(T(I), "_")(1) & vbCrLf
 
        Next I
 
        'finalise la chaîne
        Chaine1 = Chaine1 & Chaine2 & vbCrLf & "En l'attente de votre règlement, veuillez agréer, " & Cle & ", mes sincères salutations."
        Chaine1 = Chaine1 & vbCrLf & vbCrLf & "ElMizuno41"
 
        'envoi des mails
        EnvoiMail Chaine1, AdresseMail, "Relance ElMizuno41."
 
        'vide pour le suivant
        Chaine1 = "": Chaine2 = "": AdresseMail = ""
 
    Next Cle
 
End Sub
 
Sub EnvoiMail(TexteMail As String, AdresseMail As String, Sujet As String)
 
    Dim AppOutlook As Object
    Dim OutMail As Object
 
    Set AppOutlook = CreateObject("Outlook.Application")
    Set OutMail = AppOutlook.CreateItem(0)
 
    With OutMail
 
        .To = AdresseMail
 
        .Subject = Sujet
 
        .Body = TexteMail
 
        '.Display 'montre l'application
 
        .Send
 
    End With
 
    Set OutMail = Nothing
    Set AppOutlook = Nothing
 
End Sub

07/11/2019, 10h37
ElMizuno41

C'est PARFAIT ! Tu es un génie :D

Juste une question qui a mon avis est bête...
Il est possible d'envoyer les mails via Courrier ?

En tout cas, je te remercie énormément pour ton travail, et ta gentillesse !

Un gros merci.
08/11/2019, 13h57
Theze

Bonjour,

Citation:

Il est possible d'envoyer les mails via Courrier ?

Tu veux dire quoi par "via Courrier" ? C'est un logiciel ? Ou tu veux un envoi par lettre postale ? Dans ce dernier cas, il te faut construire une lettre type et modifier certains champs puis imprimer !