Recordset : Modification par Edit

Version imprimable

Voir 40 message(s) de cette discussion en une page

Bonjour,

Je voudrais au départ ajouter les enregistrements de rs1 à rs.
Puis si rs1 à des nouveaux enregistrements les rajouter à rs,
ou si rs1 à des champs modifiés mettre à jour rs.

Comment intégrer dans ce code la mise à jour par Edit, en sachant que la table est vide au départ.
Code:

1 2 3 4 5 6 7 8 9 10 11 12 13 14 15 16 17 18 19 '--- Boucle sur la table rs1 Do While Not rs1.EOF '--- Rechercher si le numéro de licence existe rs.FindFirst "[NuméroLicence]=" & rs1!Licence '--- Pas de numéro de licence trouvé, crée l'enregistrement If rs.NoMatch Then '--- Enregistrement des données des nouveaux rs.AddNew rs("Nom") = rs1!Nom rs("Prénom") = rs1!Prénom rs("Titre") = rs1!Civil rs("NuméroLicence") = rs1!Licence End If rs.Update rs1.MoveNext Loop
Merci de votre aide

Salutations.

Bonjour,

J'ai pas testé, mais je ferrai comme ceci

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
Dim blnExistePas as Boolean
 
'--- Boucle sur la table rs1
      Do While Not rs1.EOF
 
 '--- Rechercher si le numéro de licence existe
      If rs.EOF Then 
         blnExistePas = True
      Else
         rs.FindFirst "[NuméroLicence]=" & rs1!Licence
         blnExistePas = rs.NoMatch
      End If
 
 '--- Pas de numéro de licence trouvé, crée l'enregistrement
      If blnExistePas Then
         rs.AddNew
         rs("NuméroLicence") = rs1!Licence
      Else
 '--- Existe on met à jours 
         rs.Edit
      End If
 
 '--- Ajout/Mise à jour des autres champs     
      rs("Nom") = rs1!Nom
      rs("Prénom") = rs1!Prénom
      rs("Titre") = rs1!Civil
      rs.Update
 
     rs1.MoveNext    
 
     Loop

A+

26/08/2006, 23h52
jmde

Bonsoir LeepZepII,

Merci pour ta réponse, cela fonctionne correctement.

Par contre plus tard je dois liéer un champ de la table rs à un autre champ d'une table rs3, est-ce que je pourrai faire les ajouts ou modifications de la table rs de la même manière ?

Salutations et bon Dimanche.
27/08/2006, 16h46
LedZeppII

Bonjour jme,

Si tu veux mettre à jour rs à partir de rs3 comme tu mets à jour rs à partir de rs1, et que la clé est toujours [NuméroLicence],
je pense que la méthode est valable.
Par contre si il y a des ajouts tu auras dans rs des enregistrements avec des champs vides (Nom,Prénom,Titre)

Que représentent rs, rs1, rs3 ?
Est-ce que rs1 et rs3 sont des données de référence et tu veux synchroniser rs sur celles-ci ?

A+
27/08/2006, 22h32
jmde

Bonsoir LeepZepII,

rs est une table qui contient tous les adhérents avec un champ RéfFamille

rs1 est une table que j’importe dans ma base et qui me permet de rajouter à rs les nouveaux adhérents, ou de les mettre à jours.

rs3 correspondra à une table qui me permettra de donner un numéro de famille à chaque adhérent et sera liée à rs par réfFamille.

Par contre je m’aperçois que le code marche uniquement lorsque la table rs est vide,
Mais si je dois faire une mise à jour ou rajouter un enregistrement cela ne marche pas.

Salutations

Oula oui.
Le test sur EOF est un mauvais choix.
Bien qu'on ajoute des enregistrement EOF reste Vrai.
J'ai modifié le code pour ne tester EOF qu'au début, avant d'entrer dans la boucle.

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
Dim blnExistePas As Boolean, blnCibleVide As Boolean

If rs.EOF Then blnCibleVide = True Else blnCibleVide = False

'--- Boucle sur la table rs1
      Do While Not rs1.EOF

 '--- Rechercher si le numéro de licence existe
      If blnCibleVide Then
         blnExistePas = True
      Else
         rs.FindFirst "[NuméroLicence]=" & rs1![NuméroLicence]
         blnExistePas = rs.NoMatch
      End If
     
 '--- Pas de numéro de licence trouvé, crée l'enregistrement
      If blnExistePas Then
         rs.AddNew
         rs("NuméroLicence") = rs1![NuméroLicence]
         blnCibleVide = False
      Else
 '--- Existe on met à jours
         rs.Edit
      End If

 '--- Ajout/Mise à jour des autres champs
      rs("Nom") = rs1!Nom
      rs("Prénom") = rs1!Prénom
      rs("Titre") = rs1!Titre
      rs.Update

     rs1.MoveNext

     Loop

Concernant rs3 et rs, j'ai l'impression qu'il s'agit de mettre à jour un champ de rs à partir de rs3.
Ca peut peut-être se faire par une requête mise à jour ?

A+

29/08/2006, 23h30
jmde

Bonsoir LeepZepII,

Merci pour ta réponse, cela fonctionne correctement.

Pour ma table rs3 je reviendrai plus tard, lorsque je tenterai de la faire, et j'espère que tu pourras maider.

Salutations
01/09/2006, 23h10
jmde

Bonsoir LeepZepII,

Je reviens vers toi pour ma table (rs3),

Donc je mets à jour, ou je rajoute à ma table Adhérents(rs) des enregistrements, puis sur un champ « NuméroFamille » j’affecte un numéro à chaque adhérent.

Ma table Adhérents (rs) se présente comme ceci :

tbl Adhérents

RéfAdhérent……….NuméroFamille………Nom………Prénom………Adresse
1………………………….1000001………………..A…………..A1………………A2
2………………………….1000002………………..B……………B1………………B2
3………………………….1000002………………..B……………B1………………B2
4………………………….1000003………………..C……………C1………………C2

A partir de cette table je voudrai un regroupement par NuméroFamille, et rajouter ces enregistrements pour avoir une table famille(rs3) de ce type:

Tbl Familles

RéfFamille……………NuméroFamille………Nom………Prénom………Adresse
1………………………….1000001………………..A…………..A1………………A2
2………………………….1000002………………..B……………B1………………B2
3………………………….1000003………………..C……………C1………………C2

Si cela est possible par quel champ lier la tbl Adhérents à tbl Familles ?

Merci pour ton aide.

Salutations.

Bonjour jmde,

super les couleurs!

On peut réutiliser le principe de code de l'autre fois.
Le recordset sur le lequel on boucle est rs (Adhérents).
Celui qu'on met à jour est rs3 (Familles)
La recherche se fait sur le champ NuméroFamille
Pour rs on peut utiliser une requête SQL avec DISTINCT:

Code:

1
2
3
4
5
6
7
8
 
Dim strSQL As String, db As DAO.Database, rs As DAO.RecordSet
 
strSQL = "SELECT DISTINCT [NuméroFamille], Nom, [Prénom], Adresse " & _
         "FROM [Adhérents] ORDER BY [NuméroFamille]"
 
Set db = CurrentDb
Set rs = db.OpenRecordSet(strSQL)

Le code de l'autre fois adapté au cas présent:

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
Dim blnExistePas As Boolean, blnCibleVide As Boolean

' rs : SELECT DISTINCT [NuméroFamille], Nom, [Prénom], Adresse 
'       FROM [Adhérents] ORDER BY [NuméroFamille]

If rs3.EOF Then blnCibleVide = True Else blnCibleVide = False

'--- Boucle sur la table rs (Adhérents)
      Do While Not rs.EOF

 '--- Rechercher si le numéro de Famille existe
      If blnCibleVide Then
         blnExistePas = True
      Else
         rs3.FindFirst "[NuméroFamille]=" & rs![NuméroFamille]
         blnExistePas = rs3.NoMatch
      End If
     
 '--- Pas de numéro de Famille trouvé, crée l'enregistrement
      If blnExistePas Then
         rs3.AddNew
         rs3("NuméroFamille") = rs![NuméroFamille]
         blnCibleVide = False
      Else
  '--- Existe on met à jours
         rs3.Edit
      End If

  '--- Ajout/Mise à jour des autres champs
      rs3("Nom") = rs!Nom
      rs3("Prénom") = rs![Prénom]
      rs3("Adresse") = rs!Adresse
      rs3.Update

     rs.MoveNext

     Loop

J'espère ne pas avoir fait d'erreurs dans la transposition du code et des noms de champs.
Fais un petit essai dans une copie de ta base avec nombre d'enregistrements restreint.

Bon courage

02/09/2006, 20h54
jmde

Bonsoir LeepZepII,

Merci pour ton compliment sur la couleur!

Le code est parfait, mais comment liéer les deux tables, ne manque t'il pas un champ à l'une des tables?

Merci pour ton aide, et bon Dimanche.

Salutations.
03/09/2006, 00h29
LedZeppII

Bonsoir jmde,

Je crois que je ne vois pas ce que tu veux dire par lien entre les tables.
Voyons si j'ai bien compris.
- La table Familles est alimentée à partir de la table Adhérents.
- Si une famille identifiée par son NuméroFamille est dans Adhérents mais pas dans Familles,
  on l'ajoute dans Familles.

La question que je me pose c'est comment tu attribue le numéro de famille dans la table Adhérents ?

Ou bien justement, peut-être cherche tu à attribuer automatiquement un nouveau de numéro de famille
qui irait à la fois dans la table Familles et dans la table Adhérents ?

A+
03/09/2006, 17h47
jmde

Bonjour LeepZepII,

Par liées j’entends Relations (Schéma relationnel).

Actuellement j’attribue le numéro de famille manuellement, et en effet je cherche bien à attribuer automatiquement un nouveau de numéro de famille qui irait à la fois dans la table Familles et dans la table Adhérents.

Si tu as une solution ça sera avec plaisir.

Pour mémoire voici le cheminement actuel :

Je capte sur un site une Feuille EXCEL que j’importe dans la Table "tbl Adhérents Excel" (rs1).

Avec cette Table et comme on la vue ensemble je rajoute ou je mets à jour la Table "tbl Adhérents" (rs).

Manuellement je rajoute un numéro de famille à chaque adhérent.

Puis comme on la vue également ensemble je rajoute ou je mets à jour la Table "tbl Familles" (rs3).

Salutations.

Bonjour jmde,

J'ai mis un clé sur NuméroFamille dans la table Familles et créé une relation entre les tables Familles (1) et Adhérents (plusieurs)
par le champ NuméroFamille.

Voici le code qui crée les familles inéxistantes dans Familles et met à jour NuméroFamille dans Adhérents.
Le principe est Nom + Adresse est unique.
Donc j'espère qu'une même adresse n'est pas saisie de plusieurs manières.

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
Sub MajFamille()
Dim blnExistePas As Boolean, blnCibleVide As Boolean
Dim db As DAO.database, rs As DAO.Recordset, rs3 As DAO.Recordset
Dim DernNumFam As Long

Set db = CurrentDb
Set rs = db.OpenRecordset("SELECT * FROM Adhérents WHERE Nz([NuméroFamille],0)=0")
Set rs3 = db.OpenRecordset("Familles", dbOpenDynaset)

If rs3.EOF Then
   blnCibleVide = True
   DernNumFam = 1000000
Else
   blnCibleVide = False
   DernNumFam = DMax("NuméroFamille", "Familles")
End If

 '--- Boucle sur la table rs (Adhérents)
      Do While Not rs.EOF

 '--- Rechercher si famille existe par Nom+Adresse
      If blnCibleVide Then
         blnExistePas = True
      Else
          rs3.FindFirst "[Nom]='" & rs("Nom") & "' AND " & _
                       "[Adresse]='" & rs("Adresse") & "'"
         blnExistePas = rs3.NoMatch
      End If
     
      If blnExistePas Then
 '--- Famille Non trouvée, Création dans Familles
          rs3.AddNew
             DernNumFam = DernNumFam + 1
             rs3("NuméroFamille") = DernNumFam
             rs3("Nom") = rs("Nom")
             rs3("Adresse") = rs("Adresse")
          rs3.Update
          rs3.Bookmark = rs3.LastModified ' va à enregistrement créé
         blnCibleVide = False
      End If

  '--- Mise à jour Adhérents
       rs.Edit
          rs("NuméroFamille") = rs3("NuméroFamille")
       rs.Update

       rs.MoveNext

      Loop

      db.Close
End Sub

A+

04/09/2006, 12h11
jmde

Bonjour LeepZepII,

Le code fonctionne très bien.

J’ai mis la clé sur le champ numéroFamille de la tbl Familles et lorsque je fais la relation avec le même champ de la tbl Adhérents j’ai un type de relation « non définie » et lorsque je coche Appliquer l’intégrité référentiel j’ai « Index unique introuvable pour le champ référencé d’une table principale » Est-ce normal ?

Par contre j’ai modifié cette ligne car dans la table j’ai des adhérents qui non pas renouvelé leurs adhésions.

Set rs = db.OpenRecordset("SELECT * FROM [tbl adhérents] WHERE Nz([NuméroFamille],0)=0 AND [tbl adhérents].Départ=False")

Comment faire si cela se produit cette année pour cocher la case départ de tbl Familles lorsque la case départ de tbl Adhérents est cochée, et vice versa.

Pour ma compréhension a quoi correspond le ,0) après NuméroFamille de cette ligne :
SELECT * FROM Adherents WHERE Nz([NuméroFamille],0)=0")

Je te remercie vivement pour l’aide que tu m’apportes.

Salutations

Bonsoir jmde,

Voila ce que j'ai fait (clés en gras)
Code:

1 2 3 4 5 6 7 8 9 Familles Adhérents NuméroFamille ----- RéfAdhérent Nom \ NuméroLicence Prénom ----- NuméroFamille Adresse Nom Prénom Titre Adresse
Nz([NuméroFamille],0) renvoie 0 si [NuméroFamille] est Null.
De cette manière je capte les enregistrements pour lesquels le champ est Null et ceux qui ont 0 (valeur par défaut d'un champ numérique le plus souvent).

Pour la case départ de la table Familles, je ferai une requête mise à jour :
Code:

1 2 3 UPDATE Familles SET Familles.Départ = DMax("Départ", "Adhérents", "NuméroFamille = " & CStr([Familles].[NuméroFamille]));
Tant qu'au moins un adhérent d'une famille a une case Départ non cochée,
Dmax(...) renvoie 0, donc Faux.
Par contre, lorsque tous les adhérents d'une famille ont la case Départ cochée,
Dmax(...) renvoie -1, donc Vrai.

La mise à jour du champ Départ dans l'autre sens pose un problème.
On met à jour tous les adhérents d'un famille.
Ou alors on ne le fait que pour une famille ayant le champ Départ coché:
Code:

1 2 3 4 UPDATE Adhérents SET Adhérents.Départ = True WHERE (Adhérents.NuméroFamille) In (SELECT NuméroFamille FROM Familles WHERE Départ=True)
A+

Bonsoir LeepZepII,

Ok pour la tbl Familles la relation se fait correctement.
Je n’ai pas encore testé le code pour le départ des adhérents, car j’ai un autre petit souci :
Code:

1 2 rs3.FindFirst "[Nom]='" & rs("Nom") & "' AND " & _ "[Adresse]='" & rs("Adresse") & "'"
Les adresses que j’importe dans la tbl Adhérents comportent beaucoup d’erreur au sein d’une même famille, j’ai pensé agir sur le nom uniquement, mais je me suis retrouver avec le cas des Dupont, Durant.
Alors j’ai créer trois cases à cocher FamillesA, FamillesB, FamillesC que je renseigne manuellement:

Nom Familles A Familles B Familles C
Dupont A.............-1.................0...............0
Dupont A.............-1.................0...............0

Dupont B...............0................-1...............0
Dupont B...............0................-1...............0

Dupont C...............0.................0..............-1
Dupont C...............0.................0..............-1

Dupont E...............0.................0................0

Et j’ai modifié le FindFirst comme ceci sans succès :

« Le moteur,,,,,,,,, ne reconnaît pas vrai en tant que non de champ ou expression »
Code:

1 2 3 4 rs3.FindFirst "[Nom]='" & rs("Nom") & "' AND " & _ "[FamillesA]=" & rs("FamillesA") & " AND " & _ "[FamillesB]=" & rs("FamillesB") & " AND " & _ "[FamillesC]=" & rs("FamillesC")
Merci pour ton aide, et si tu as une solution plus élégante n’hésite pas.

Salutations.

Bonsoir,

Peut-être en forçant le type en booléen :
Code:

1 2 3 4 5 rs3.FindFirst "[Nom]='" & rs("Nom") & "' AND " & _ "[FamillesA]=" & CBool(rs("FamillesA")) & " AND " & _ "[FamillesB]=" & CBool(rs("FamillesB")) & " AND " & _ "[FamillesC]=" & CBool(rs("FamillesC"))
On est souvent ennuyé par tout ce qui est traduit en français.
C'est bien pour les utilisateurs qui font une requête pour la première fois de leur vie,
mais quand on mixte utilisation + VBA + SQL ça devient confus.

A part l'adresse, il n'y aurait pas un autre champ à combiner avec le nom de famille, de manière à obtenir quelque chose d'unique ?
Ou alors peut-on au moins extraire un nom de ville et de rue de l'adresse ?
Sans quoi j'ai bien peur que ma routine ne serve à rien.
La logique était basé sur l'unicité Nom+Adresse.

A+

07/09/2006, 01h31
jmde
Bonsoir LeepZepII,

Ta routine dans mon cas me semble parfaite car ce n’est pas très gênant pour moi de renseigner les cases à cocher, c’est un peu fastidieux au départ, mais après au fur et à mesure des entrées c’est faisable.

J’ai dû mettre CCurr pour que cela marche, mais ça n’a plus d’importance car j’ai supprimé les 3 cases à cocher, que je remplace par un champ qui a pour valeur par défaut 0, 1 pour une famille, 2 pour une famille différente.
Code:

1 2 rs3.FindFirst "[Nom]='" & rs("Nom") & "' AND " & _ "[GroupeFamille]=" & rs("GroupeFamille")
Pour revenir à la case à cocher départ c’est lorsque toutes les cases de la famille tbl Adhérents sont cochées que l’on met à jour la case à cocher départ de la tbl Familles.

Par contre je n’arrive pas à déboguer cette ligne qui s’arrête sur SET et message Erreur de syntaxe.

Code:

UPDATE [tbl Familles] SET [tbl Familles].Départ = DMax("Départ", "[tbl Adhérents]", "NuméroFamille = " & CStr([tbl Familles].[NuméroFamille]));

Salutations
07/09/2006, 20h38
jmde
Bonsoir LeepZepII,

Désolé pour le code il fonctionne très bien, je viens de m'apercevoir que je devais mettre db.excecute.
Code:

1 2 rq = "UPDATE [tbl Familles] SET [tbl Familles].Départ= DMax(""Départ"", ""tbl Adhérents"", ""NuméroFamille = "" & CStr([tbl Familles].[NuméroFamille]))" db.Execute rq
Une toute dernière question, d’après toi dans trois ou quatre ans que doit-on faire des familles qui sont parti, si on les supprime peut-on récupérer le numéro.
Comment faire ?

J’ai été très heureux de ton aide qui m’a beaucoup fait avancée et surtout beaucoup appris.

Salutations.

Bonsoir,

Le code que j'avais donné pour mettre à jour Départ dans Famille était celui d'une requête sauvée que j'exécute avec DoCmd.OpenQuery "NomDeLaRequête".

Pour la suppression et réafectation de NumeroFamille:

Si la ou les relations avec Familles.NuméroFamile n'ont pas la supression en cascade activée:
Il faut commencer par supprimer tous les enregistrements qui ont NuméroFamille dans la ou les tables qui ont une relation avec la table Familles.
Ensuite on peut supprimer NuméroFamille dans la table Familles.

Si la Supression en cascade est activée, on supprime NuméroFamile dans la table Familles.
Les enregistrements correspondants dans la ou les autres tables seront supprimés automatiquement.

Pour réatribuer un NuméroFamille libéré (supprimé) il faut écrire une fonction qui recherche le premier 'trou' disponible.
Code:

1 2 3 4 5 6 7 8 9 10 11 12 13 14 15 16 17 18 19 20 21 22 23 24 25 26 Function NvNumeroFamille() As Long Dim db As DAO.Database, rs3 As DAO.Recordset Dim NumFamille As Long Set db = CurrentDb Set rs3 = db.OpenRecordset("SELECT * FROM Familles ORDER BY NuméroFamille") If Not rs3.EOF Then ' Initialise NumFamille NumFamille = DMin("NuméroFamille", "Familles") Do While Not rs3.EOF If (rs3("Numérofamille") - NumFamille) > 1 Then NumFamille = NumFamille + 1 Exit Do End If NumFamille = rs3("Numérofamille") rs3.MoveNext If rs3.EOF Then NumFamille = NumFamille + 1 Loop Else NumFamille = 1000001 End If db.Close NvNumeroFamille = NumFamille End Function
Le code de l'autre fois
Code:

1 2 3 4 5 6 7 8 9 10 '--- Famille Non trouvée, Création dans Familles rs3.AddNew DernNumFam = DernNumFam + 1 rs3("NuméroFamille") = DernNumFam rs3("Nom") = rs("Nom") rs3("Adresse") = rs("Adresse") rs3.Update rs3.Bookmark = rs3.LastModified ' va à enregistrement créé blnCibleVide = False End If
devient
Code:

1 2 3 4 5 6 7 8 9 '--- Famille Non trouvée, Création dans Familles rs3.AddNew rs3("NuméroFamille") = NvNumeroFamille() rs3("Nom") = rs("Nom") rs3("Adresse") = rs("Adresse") rs3.Update rs3.Bookmark = rs3.LastModified ' va à enregistrement créé blnCibleVide = False End If
J'ai fait des tests rapides, mais il est tard et je n'ai peut-être toute ma lucidité, alors fais tes propres tests.

Citation:

Ta routine dans mon cas me semble parfaite car ce n’est pas très gênant pour moi de renseigner les cases à cocher, c’est un peu fastidieux au départ, mais après au fur et à mesure des entrées c’est faisable.

Tu pourrai faire celà avec un formulaire et un sous formulaire.
De ma routine, tu ne conserves que la partie qui génère un nouveau numéro de famille lorsque Nom n'est pas trouvé dans Familles.
Il ne reste à résoudre que les Noms déjà présents dans la table Famille.
Le formulaire filtre les Adhérents sans numéro de famille et le sous-formulaire montre les familles correspondant au Nom (Lien père-fils par le champ nom).
Là, deux options.
1. tu reconnais l'adresse visuellement et par un double-clic tu affectes le numéro de famille.
2. tu identifies une nouvelle famille et en cliquant sur un bouton tu génère un nouveau numéro de famille.

A+

Voir 40 message(s) de cette discussion en une page