Excel : Générer un tableau a partir de plusieurs

Version imprimable

26/08/2006, 09h45
Groov

Excel : Générer un tableau a partir de plusieurs
Bonjour,

Je dois faire un truc "très simple"... : Je dois générer une liste à partir d'un fichier principal et de deux feuilles de "paramètres"

J'ai 4 feuilles (donc une feuille "d'entré", 2 feuilles "source" et 1 feuille "d’export")

Exemple :

Fichier 1 (fichier d'entré) :
Code:

1 2 3 Nom | Date de naissance TOTO | 12/04/1956 TITI | 25/06/1972
Fichier 2 (fichier source 1) :
Code:

1 2 3 Nom | Année 1 | Année 2 | Année 3 | Année 4 TOTO | 2003 | 2004 | 2005 | 2006 TITI | 2004 | 2005
[Fichier 3 (fichier source 2) :
Code:

1 2 3 4 5 6 7 Année | Montant cotisation 2001 | 12€ 2002 | 14€ 2003 | 15€ 2004 | 16€ 2005 | 16€ 2006 | 19€
Fichier 4 (fichier destination) :
Code:

1 2 3 4 5 6 7 Nom | Année | Cotisation versée TOTO | 2003 | 15€ TOTO | 2004 | 16€ TOTO | 2005 | 16€ TOTO | 2006 | 19€ TITI | 2004 | 16€ TITI | 2004 | 16€
Je sais faire celà avec un algo basique qui
- Feuille 1 : pointe sur la première ligne "Nom" (ici TOTO) (boucle A)
- Feuille 2 : va chercher la valeur "Nom" (ici TOTO)
- Feuille 2 : lit la valeur de la "1ère année de cootisation" attachée au nom en question (ici 2003) (Boucle B)
- Feuille 3 : va chercher la valeur "1ère année de cootisation" (ici 2003)
- Feuille 3 : lit la valeur du montant de la cotisation correspondante (ici 15€)
- Feuille 4 exporte toutes les données sur une ligne

>Fini la boucle B
>Fini la boucle A

Bref... basique mais efficace...
Existe-t-il une manière plus sioux de faire ça ?
Merci d'avance pour vos lumières !!!

;)

bonsoir

difficile de répondre sans voir ce que tu as fais...

voici une methode similaire

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
Option Explicit
Option Compare Text
 
Sub ExtractionCotisation()
    '
    'Les tableaux de chaque classeur sont supposés commencer dans la cellule A1
    '
    Dim W1 As Worksheet, W2 As Worksheet, W3 As Worksheet, W4 As Worksheet
    Dim Ce1 As Range, Ce3 As Range
    Dim Plage2 As Range, Plage3 As Range, Plage4 As Range
    Dim x As Integer, y As Integer, z As Integer
 
    Set W1 = Workbooks("Fichier1.xls").Sheets("Feuil1")
    Set W2 = Workbooks("Fichier2.xls").Sheets("Feuil1")
    Set W3 = Workbooks("Fichier3.xls").Sheets("Feuil1")
    Set W4 = Workbooks("Fichier4.xls").Sheets("Feuil1")
 
    'Boucle sur les noms dans le Fichier1
    For Each Ce1 In W1.Range("A2:A" & W1.Range("A2").End(xlDown).Row)
 
        'Définit la Plage de recherche de noms dans le Fichier2
        Set Plage2 = W2.Range("A1:A" & W2.Range("A1").End(xlDown).Row)
 
        On Error Resume Next
        'Vérifie si le nom existe dans le Fichier2
        x = Application.WorksheetFunction.Match(Ce1, Plage2, 0)
            'Si oui
            If x > 0 Then
 
                'Récupère la plage des années de cotisation pour le nom spécifié
                Set Plage3 = W2.Range(W2.Cells(x, 2), _
                            W2.Cells(x, W2.Cells(x, 2).End(xlToRight).Column))
 
                'Boucle sur les années de cotisation
                For Each Ce3 In Plage3
 
                    'Définit la Plage des montants de cotisation
                    Set Plage4 = W3.Range("A1:A" & W3.Range("A2").End(xlDown).Row)
                    'Récupère le numéro de ligne de cotisation spécifié
                    y = Application.WorksheetFunction.Match(Ce3, Plage4, 0)
 
                    If y > 0 Then
                        z = W4.Range("A65536").End(xlUp).Row + 1
 
                        W4.Cells(z, 1) = Ce1
                        W4.Cells(z, 2) = Ce3
                        W4.Cells(z, 3) = W3.Cells(y, 2)
                    End If
                Next Ce3
            End If
    Next Ce1
 
End Sub

bonne soiree
michel

26/08/2006, 19h34
Groov

Ben alors... !!!

Merci beaucoup !
Je vais tester cet algo et te tiens au courant !!!
En fait, j'ai trouvé des info.
Pour les experts en gestion de BDB ce que je veut faire est simple et s'appelle une jointure...
J'ai rien trouvé d'équivalent sur Excel mais apparemment sous Acces c'est ultra simple...
Mais en tout cas merci pour ta macro elle m'a l'air super interessante !
a bientôt,

;)