Tester la valeur d'un with est-ce possible ?

Version imprimable

Bonjour à tous,

J'ai une petite question toute bête, est-ce qu'il est possible de tester de la valeur d'un with.

J'entend par là que j'ai le code suivant :
Code:

1 2 3 4 5 With ThisWorkbook.Worksheets("Reporting DO").Range("C:C").Find(Cells(CellPS.Row, Range("Code_NRA").Column).Value) Cells(CellPS.Row, Range("Ouverture_ADSL2").Column) = .Offset(0, 7) Cells(CellPS.Row, Range("Ouverture_TVNUM").Column) = .Offset(0, 8) Cells(CellPS.Row, Range("Ouverture_VDSL2").Column) = .Offset(0, 9) End With
Mon with étant un range.find il est possible que le find ne trouve rien et que donc mon résultat soit un nothing. Je voudrais donc tester cette possibilité avant d'effectuer mes décalage d'offset. Mais je ne vois comment faire.

En gros je voudrais faire un truc du genre :
Code:

1 2 3 4 5 6 7 With ThisWorkbook.Worksheets("Reporting DO").Range("C:C").Find(Cells(CellPS.Row, Range("Code_NRA").Column).Value) If Not mon with Is Nothing Then Cells(CellPS.Row, Range("Ouverture_ADSL2").Column) = .Offset(0, 7) Cells(CellPS.Row, Range("Ouverture_TVNUM").Column) = .Offset(0, 8) Cells(CellPS.Row, Range("Ouverture_VDSL2").Column) = .Offset(0, 9) End If End With
Vous savez si c'est possible ?

Bonjour Coco, bonjour le forum,

Peut-être comme ça :

Code:

1
2
3
4
5
6
7
8
9
10
Dim R As Range
 
With ThisWorkbook.Worksheets("Reporting DO").Range("C:C")
    Set R = .Find(Cells(CellPS.Row, Range("Code_NRA").Column).Value)
    If Not R Is Nothing Then
        Cells(CellPS.Row, Range("Ouverture_ADSL2").Column) = R.Offset(0, 7)
        Cells(CellPS.Row, Range("Ouverture_TVNUM").Column) = R.Offset(0, 8)
        Cells(CellPS.Row, Range("Ouverture_VDSL2").Column) = R.Offset(0, 9)
    End If
End With

Il suffit de faire les choses proprement en plaçant le résultat de ton Find dans une variable.

Code:

1
2
3
4
5
6
7
8
9
Dim Resultat As Range
Set Resultat = ThisWorkbook.Worksheets("Reporting DO").Range("C:C").Find(Cells(CellPS.Row, Range("Code_NRA").Column).Value)
If Not Resultat Is Nothing Then
    With Resultat
        Cells(CellPS.Row, Range("Ouverture_ADSL2").Column) = .Offset(0, 7)
       Cells(CellPS.Row, Range("Ouverture_TVNUM").Column) = .Offset(0, 8)
       Cells(CellPS.Row, Range("Ouverture_VDSL2").Column) = .Offset(0, 9)
    End With
End If

Et du coup, on peut se demander si le With est réellement utile...

16/10/2019, 10h29
Coco47

Merci à tous les deux.

En fait je voulais éviter de passer par une variable intermédiaire (je sais pas trop pourquoi j'ai cette habitude de vouloir éviter de créer des variables partout). Mais effectivement je pense que c'est la solution la plus simple.