Variable via une MessageBox

Version imprimable

25/09/2019, 01h09
agridede

Variable via une MessageBox

Bonjour,

je suis en train de créer un script en Batch et j'aimerais ouvrir une fenêtre type messagebox dans laquelle il sera possible d'entrer un nom.
Je devrais utiliser ce nom comme "variable" pour par exemple créer un dossier portant ce nom.

Je ne parviens pas du out à trouver la syntaxe.

Exemple: Dans une fenêtre s’afficherait

Donner un nom à votre activité?
nom: semer pomme de terre

Je voudrais récupérer l'information "semer pomme de terre" dans mon script Batch pour l'utiliser plus tard dans mon script.

Merci d'avance pour votre aide
27/09/2019, 11h47
ericlm128
Le batch n'a pas été créé pour une utilisation fenêtré (invite de commande en mode console).

Voici comment faire avec du batch :
Code:

1 2 set /P "activite=Donner un nom à votre activité : " echo nom: %activite%
Si tu veux vraiment une fenetre type MessageBox du FrameWork :
- Tu t'es peux être trompé de langage
- Tu doit utiliser un outil ou langage tiers
27/09/2019, 11h49
ericlm128

Voir un post récent : https://www.developpez.net/forums/d2...e-windows-bat/

:salut:
InputBox et non pas un MessageBox ;)

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
@echo off
Title Donner un nom à votre activité ?
(
    echo Option Explicit
    echo Dim Message, result
    echo Dim Title, Text1, Text2
    echo Message = "Donner un nom à votre activité ?"
    echo Title = "Question pour entrer les informations"
    echo Text1 = "Vous avez annuler"
    echo result = InputBox^(Message, Title, "semer pomme de terre"^)
    echo If result = "" Then
    echo     WScript.Echo Text1
    echo Else
    echo    WScript.Echo result
    echo End If
)>"%tmp%\inputbox.vbs"
for /f "tokens=* delims=*" %%a in ('Cscript //nologo "%tmp%\inputbox.vbs"') do (set "Reponse=%%a")
echo La variable Reponse contient ==^> "%Reponse%"
pause

29/09/2019, 22h01
agridede

Merci Beaucoup à tous pour avoir pris le temps de me répondre.
Un grand merci à Hackoofr pour le code. Ca marche au top :-):P