Selection par defaut dans menu deroulant combobox

Version imprimable

Bonjour,

Aprés plusieurs recherches et essais je me retrouve dans une impasse un peu ennuyeuse .... D’où ma demande d'aide .

j'ai un menu déroulant qui me déclanche des macros et je souhaiterais qu’après une sélection sur le menu ,ce dernier reviennent sur un choix par défaut.
J'ai essayé par les propriété du menu, en essayant de rappeler dans le menu la valeur "Choix", mais rien n'y fait,
après une sélection le menu reste sur la dernière valeur sélectionné

Comment peut-on faire ?
Voici le Code du Menu

Merci d'avance.
Code:

1 2 3 4 5 6 7 8 9 10 11 12 13 14 15 16 17 18 19 20 Private Sub ListUp_Change() Const Source As String = "ComboBox barre d'outils Contrôle" Select Case Me.ListUp.Value Case "Acceuil": Vers_Acceuil Source Case "VERROUILLAGE": Blocage_Deblocage Source Case "DEVERROUILLAGE": Deverrouiller Source Case "MISE A JOUR CHEVAUX": MAJ_Chevaux Source Case "AFFICHER TOUTES LES COLONNES": Affiche_Tout Source Case "AFFICHER SEMAINE REPRISES": Affiche_Reprises Source Case "AFFICHER SEMAINE STAGES": AFFICHE_STAGES Source Case "DEPLACER SEMAINE EN DERNIER": Deplacer_Feuilles_dernier Source Case "AIDE": Vers_Aide_Sxx Source Case "xxx": Vers_Aide_Sxx Source Case "CHOIX": Vers_Aide_Sxx Source Case "QUITTER": Enregistrer_Quitter Source End Select End Sub

09/07/2019, 13h13
Philippe Tulliez
Bonjour,
Deux propriétés permettent de sélectionner un élément de la liste d'un ComboBox
- ListIndex
- Value
Exemple avec Value (dépend de la valeur de la propriété BoundCoulumn qui par défaut est à 1)
Code:

1 2 3 4 With Me.ComboBox1 .List = Feuil1.ListObjects(1).DataBodyRange.Value .Value = "Samedi" End With
Exemple avec ListIndex
Code:

1 2 3 4 With Me.ComboBox1 .List = Feuil1.ListObjects(1).DataBodyRange.Value .ListIndex = 5 End With

re
pour créer un menu (d'action) avec une combo il te suffit de le remettre a listindex-1 et de l'excepter dans le select case par un if global

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
Private Sub ListUp_Change()
    Const Source As String = "ComboBox barre d'outils Contrôle"
    With ListUp
        If .ListIndex >= 0 Then
            Select Case .Value
            Case "Acceuil": Vers_Acceuil Source
            Case "VERROUILLAGE": Blocage_Deblocage Source
            Case "DEVERROUILLAGE": Deverrouiller Source
            Case "MISE A JOUR CHEVAUX": MAJ_Chevaux Source
            Case "AFFICHER TOUTES LES COLONNES": Affiche_Tout Source
            Case "AFFICHER SEMAINE REPRISES": Affiche_Reprises Source
            Case "AFFICHER SEMAINE STAGES": AFFICHE_STAGES Source
            Case "DEPLACER SEMAINE EN DERNIER": Deplacer_Feuilles_dernier Source
            Case "AIDE": Vers_Aide_Sxx Source
            Case "xxx": Vers_Aide_Sxx Source
            Case "CHOIX": Vers_Aide_Sxx Source
            Case "QUITTER": Enregistrer_Quitter Source
            End Select
        End If
        .ListIndex = -1
    End With
End Sub

cela dit c'est sensé te simplifier la vie et toi tu utilise une expression pour la faire correspondre a une autre
perso j'aurais mis les vrai nom de je suppose que ce sont des subs qui sont appelées avec l'argument "source"

voila comment j'aurais fait ton menu

dans le UserForm activate je rentre les items du menu

Code:

1
2
3
4
5
6
Private Sub UserForm_Activate()
    With ListUp
        .List = Array("Acceuil", "Blocage_Deblocage", "Deverrouiller", "MAJ_Chevaux", "Affiche_Tout", "Affiche_Reprises", "AFFICHE_STAGES", "Deplacer_Feuilles_dernier" _
              , "Vers_xxx_Sxx", "Vers_Aide_Sxx", "Vers_choix_Sxx", "Enregistrer_Quitter")
    End With
End Sub

l'avantage de l'évènement click de la combo ne se déclenché que si le click est fait sur un item ben..bingo

l'evenement click

Code:

1
2
3
4
5
6
7
Private Sub ListUp_Click()
    source = "toto"'j'ai mis ca pour les tests 
    With ListUp
        If .ListIndex >= 0 Then Application.Run .List(.ListIndex), source
        .ListIndex = -1
    End With
End Sub

il y a un inconveniant tout de meme c'est que cet evenement peut etre declenché quand on ajoute ou modifie l'index ou une valeur
pour cela rien de plus facile
on ajoute le control que c'est bien la listup l'activecontrol du UserForm

comme ceci

Code:

1
2
3
4
5
6
7
8
9
Private Sub ListUp_Click()
    If ActiveControl.Name = "ListUp" Then
        source = "toto"
        With ListUp
            If .ListIndex >= 0 Then Application.Run .List(.ListIndex), source
            .ListIndex = -1
        End With
    End If
End Sub

voila ni plus ni moins tu a ton menu en 3/4 lignes de code
pour les subs appelée comme je ne les ai pas les tiennes je les ai fait pour tester avec un simple msgbox

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
 
Sub Acceuil(source)
MsgBox source
End Sub
'
Sub Blocage_Deblocage(source)
MsgBox source
End Sub
'
Sub Deverrouiller(source)
MsgBox source
End Sub
'
Sub MAJ_Chevaux(source)
MsgBox source
End Sub
'
Sub Affiche_Tout(source)
MsgBox source
End Sub
'
Sub Affiche_Reprises(source)
MsgBox source
End Sub
'
Sub AFFICHE_STAGES(source)
MsgBox source
End Sub
'
Sub Deplacer_Feuilles_dernier(source)
MsgBox source
End Sub
'
Sub Vers_xxx_Sxx(source)
MsgBox source
End Sub
'
Sub Vers_Aide_Sxx(source)
MsgBox source
End Sub
'
Sub Vers_choix_Sxx(source)
MsgBox source
End Sub
'
Sub Enregistrer_Quitter(source)
MsgBox source
End Sub

voila
bonne route ;)
une petite dernière précision et/ou complément d'information
l'utilisation de application.run n'est pas annodynne on peut très bien appeler une sub d'un autre classeur ou d'un xla(m) en le précisant bien sur
j'ai tout dis :P

09/07/2019, 15h33
Gillou55

Merci pour ta réponse
mais j'essaie la encore sans succès.

Peux-tu m’éclairer encore plus a partir du code que j'ai fourni?

Salut.

@Patrick: Ton code ne remet pas de valeur par défaut mais vide le combobox. Or, c'est quand même l'objet de la discussion!

Voici un code qui affiche le choix par défaut après exécution de la macro. J'ai utilisé la colonne 1 d'un combobox à deux colonnes pour contenir le nom de la macro à utiliser. Il faut passer par une variable de userform (déclarée en haut du module du userform) pour neutraliser la remise à la valeur par défaut.
Code:

1 2 3 4 5 6 7 8 9 10 11 12 13 Option Explicit Dim AlreadyClicked As Boolean Private Sub ComboBox1_Click() If Not AlreadyClicked Then AlreadyClicked = True Run ComboBox1.Column(1) ComboBox1.ListIndex = 0 Else AlreadyClicked = False End If End Sub
Cela étant dit, sur le plan ergonomique va se poser le problème suivant: Et si la personne veut le choix par défaut, comment va-t-elle faire? Car l'ouverture de la liste et le choix de la valeur déjà choisie ne lève ni l'évènement Click, ni l'évènement Change => Elle ne pourra donc jamais utiliser le choix par défaut. je précise d'ailleurs que ce problème n'est pas uniquement présent avec une remise sur une valeur par défaut. Si tu laisses le combobox sur le choix précédent, comment l'utilisateur va-t-il opérer pour relancer ce choix?

Perso, je ne suis pas fan de cette ergonomie car ce n'est normalement pas le rôle d'un combobox d'activer une action. Il me semblerait plus judicieux de placer un bouton et de déclencher l'action sur le clic du bouton. Ca éviterait en plus de devoir passer par la variable de userform pour désactiver le retour au choix par défaut.

09/07/2019, 19h23
patricktoulon

re

re
bonjour pierre
non je la vide pas je la met a index-1

et oui je la met a -1 car justement j'ai entrevu les problèmes qu'un item par default pourrait causer a moins que ce soit simplement un titre au quel cas c'est pareil que le -1 mais un visuel sur un intitulé en plus mais la gestion se ferait de la mémé manière "if .listindex<>x then"
un dérouler-> une sélection->remet a -1 pour la prochaine sélection qui pourrait être la même d'ailleurs
09/07/2019, 22h13
Gillou55

Merci pour le code, j'y vois deja bien plus clair.
Et en plus ca fonctionne nickel :P

de Plus la 2eme version et trés bien expliqué pour un novice comme moi,
me reste plus qu'a l'essayer en essayant de comprendre ce que je fais :D.

Grand merci a toi et a toute la team de "developpez.net"