Supprimer La formule et le format d'une MFC créé par une fonction VBA

Version imprimable

Bonjour à tous
ce code ou module ci-dessous:
Code:

1 2 3 4 5 6 7 8 9 10 Sub LuS2M() Range("B8:M38").Select Selection.FormatConditions.Add Type:=xlExpression, Formula1:= _ "=mod(b8;14)=9" Selection.FormatConditions(Selection.FormatConditions.Count).SetFirstPriority With Selection.FormatConditions(1).Interior .Color = RGB(255, 214, 83) End With Selection.FormatConditions(1).StopIfTrue = True End Sub
qui renseigne la MFC, avec l'aide d'un menu déroulante, me permet de colorer différentes cellules d'un calendrier suivant les jours et périodes de la journée (matin, soir) et ce sur plusieurs années.
C'est ici que je me tourne vers vous car je ne trouve pas de solutions pour supprimer certaines MFC, en exemple le code joint =mod("B8:M38")=9 le 9 correspondant à un jour donc une cellule précise celle que je désire effacé de son contenu coloré.
Merci d'avance de me proposer une solution

01/02/2019, 04h24
ARTURO83

Bonjour,

Vous n'allez pas refaire les MFC à chaque changement de calendrier.

Les MFC sont suffisamment élaborées pour ce passer le plus possible du VBA, surtout dans des cas simples comme vous le présentez.

Au lieu d'effacer les MFC qui répondent à certains critères, modifier votre première formule avec la fonction ET.
Exemple: =ET(votre première condition, MOD(b8;14)<>9)) on met la couleur désirée, tout autre cas ne sera pas retenu, donc pas de couleur.

A adapter à votre tableau.

Cdlt
01/02/2019, 15h04
furtif13780

Mille Merci ARTURO83 de m'avoir mis sur la voie, malheureusement mon niveau débutant me focalise sur ce code VBA et je ne saisie pas la manière d'intégrer les modifications que vous m'apportez.

Dans votre exemple:

1°) votre première condition: qui est celle du code VBA ? =MOD(b8;14)=9 et celui-ci doit devenir =ET(MOD(b8;14)=9;MOD(b8;14)<>9)) (j'ai un gros doute à ce que j'ai écrit ?)

2°) on met la couleur désirée: où la mettre ? Celle-ci est déjà dans le code entre With et End With Color=RGB(255,214,83).

Conclusion: est-ce que je garde bien ce code VBA modifié ? Ou tout doit être mis manuellement dans la MFC ?

Avez-vous encore un peu de temps à me consacrer afin de répondre aux questions que je me pose et peut-être solutionner ce cas simple ?
Encore merci.
Cdlt
01/02/2019, 15h37
ARTURO83

Bonjour,

Les MFC devraient suffire, mais pour cela il faudrait connaître les conditions pour les appliquer.

Donnez un descriptif de ce que vous attendez
exemples:
si cellule A1 >10, et A10 <= 20, mettre couleur orange
si cellule A1 >20, et A10 <= 40, mettre couleur rouge
etc..
et à appliquer sur la plage A1:J10
01/02/2019, 17h44
furtif13780

Bonjour ARTURO83

Je préfère rester en VBA pour des raisons pratiques.

Je reprends mon explication différemment:

La formule du code =mod(b8;14)=9 permet de colorer la 9 ème cellule qui correspond à la 2ème semaine (14) soit un lundi .Color = RGB(255, 214, 83).
un autre code parmi les 11 autres: =mod(b8,14)=10 permet de colorer etc..

et ceci bien sûr sur l'ensemble du calendrier pour différentes années ce qui me fait une accumulation de ces FormatConditions qui sont installés dans la MFC.

Mon idée était avant de lancer le code contenant la formule "=mod(b8;14)=9" est de lancer un code (code que je ne sais pas faire d'où ma demande) FormatConditions.Delete (je ne veux pas supprime toutes MFC) que pour la formule =mod(b8;14)=9 qui permettra de supprimer la ligne qui correspond à la formule et au format dans la MFC.

Voilà encore merci de vos réponses
Si vous désirez il m'est possible de mettre en ligne le fichier .zip mais je pense que cela n'aura pas beaucoup d'utilité.
Cdlt

Bonjour,

Vous vous dites débutant et vous pensez qu'il vous faut du VBA pour l'utilisation de MFC, pourquoi pas! Mais comme je n'arrive pas à me représenter ce que vous voulez faire et que vous voulez absolument du VBA, alors voici en exemple un bout de code que je vous laisse le soin d'adapter à votre fichier.

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
Sub AjouterUnFormatConditionnel()
    Application.ScreenUpdating = False
    'on veut créer des MFC avec 3 conditions par formules
    Formule1 = "=MOD(B8;14)=9"
    Formule2 = "=MOD(B8;14)=10"
    Formule3 = "=MOD(B8;14)=11"
 
    'Plage = votre tableau ou doit s'appliquer les MFC
    Range(plage).FormatConditions.Delete ' effacement de toutes les MFC
    'on recrée les MFC
    Range(plage).FormatConditions.Add(xlExpression, xlLess, Formule1).Interior.Color = RGB(255, 214, 83)
    Range(plage).FormatConditions.Add(xlExpression, xlLess, Formule2).Interior.Color = RGB(255, 110, 241)
    Range(plage).FormatConditions.Add(xlExpression, xlLess, Formule3).Interior.Color = RGB(0, 110, 241)
End Sub

Cdlt

02/02/2019, 21h56
furtif13780

Merci ARTURO83 de vous obstinez à me répondre, et pourtant vous en est pas obligé, c'est très aimable de votre part,

Pour faire court, le code que vous avez fait efface toutes les MFC et c'est là le problème :

Ligne 9: Range(plage).FormatConditions.Delete ' effacement de toutes les MFC

Je ne veux pas effacer toutes les MFC, je voudrais, si sais possible, effacé seulement la MFC celle qui aura été créé et dont je ferais le choix.

Par exemple:
Ligne 4: Formule1 = "=MOD(B8;14)=9" 'effacement de la MFC
Ligne 4: Formule1 = "=MOD(B8;14)=10" 'ne sera pas effacée
Ligne 4: Formule1 = "=MOD(B8;14)=11" 'ne sera pas effacée

Et encore toutes mes excuses pour le dérangement.

Cdlt

Bonjour,

Voici quelque chose qui devrait correspondre à vos attentes.

Ci-dessous, 3 petits programmes: "Creer_MFC", "Effacer_Toutes_Les_MFC", "Supprimer_MFC_Choisies"
Le code "Supprimer_MFC_Choisies", affiche une boîte de dialogue vous demandant si vous voulez supprimer la MFC qui s'affiche,
-si vous répondez "OUI", la MFC est supprimée et le programme s'arrête.
-si vous répondez "NON", le programme boucle sur la MFC suivante et vous repose la question.
-et ainsi de suite jusqu'à la dernière MFC trouvée.

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
Sub Creer_MFC()
    'Initialisation des variables
    Dim Formule1 As String, Formule2 As String, Formule3 As String
    Dim Plage As String
 
    Application.ScreenUpdating = False
    'on veut créer des MFC avec 3 conditions par formules
    Formule1 = "=MOD(B8;14)=9"
    Formule2 = "=MOD(B8;14)=10"
    Formule3 = "=MOD(B8;14)=11"
 
    'Plage = votre tableau ou doit s'appliquer les MFC
    Plage = "B2:J10"
    Range(Plage).FormatConditions.Delete ' effacement de toutes les MFC
    [B2].Select 'Sélectionner une cellule des cellules de la plage
    'on recrée les MFC
    Range(Plage).FormatConditions.Add(xlExpression, xlLess, Formule1).Interior.Color = RGB(255, 214, 83)
    Range(Plage).FormatConditions.Add(xlExpression, xlLess, Formule2).Interior.Color = RGB(255, 110, 241)
    Range(Plage).FormatConditions.Add(xlExpression, xlLess, Formule3).Interior.Color = RGB(0, 110, 241)
End Sub
 
Sub Effacer_Toutes_Les_MFC()
    Plage_A_Effacer = "B2:J10"
    Range(Plage_A_Effacer).FormatConditions.Delete
End Sub
 
Sub Supprimer_MFC_Choisies()
    'Initialisation des variables
    Dim Fc As FormatCondition
    Dim Plage As String
    Dim CptFc As Byte
 
    Application.ScreenUpdating = False
    Plage = "B2:J10" 'Plage à contrôler
    [B2].Select 'sélectionner une des cellule de cette plage à contrôler
    CptFc = 1 'Numéro d'ordre des MFC, on commence par la première
 
    'Controle
    If ActiveCell.FormatConditions.Count > 0 Then   'Vérifie si la cellule à tester contient une MFC
        'Si MFC détectée, alors on boucle sur toutes les MFC de la cellule
        For Each Fc In ActiveCell.FormatConditions 'pour chaque formule de MFC trouvée, on demande si on doit la supprimer
            If MsgBox("La formule est " & Fc.Formula1, vbYesNo + vbCritical + vbDefaultButton2, "Voulez-vous supprimer cette MFC?") = vbYes Then
                Range(Plage).FormatConditions(CptFc).Delete 'Supprime la MFC affichée
                End 'on sort du programme après suppression de la MFC
            End If
            CptFc = CptFc + 1 'Numéro de la MFC
        Next Fc 'on passe à la MFC suivante
    End If
End Sub

Avec un fichier en exemple:
Pièce jointe 447014

Cdlt

03/02/2019, 10h00
furtif13780

Bonjour ARTURO83

J'ai eu du mal à m'expliquer, j'en suis désolé, mais je vous félicite du résultat, c'est parfaitement ce que je recherchais.
Continuer dans cette voie de partage !

Merci et bonne journée

Cdlt