selection de zone

Version imprimable

selection de zone

Bonjour,

Pouvez-vous m'aider sur cette problématique:

Je désire que ma macro me renvoie l'adresse complete d'une zone selectionné en Range("AV15"), c'est à dire :
ex: CONFIG!$I$15:$J$24! si je selectionne l'onglet config & zone I15:J24

2. qu'une boite de dialogue me demande si je veux nommer la plage
3. si oui, qu'il me crée une plage nommée dans excel.

ci-dessous mon debut de code:

Merci d'avance
Code:

1 2 3 4 5 6 7 8 Sub SelectionPlages() Dim plage As Range Dim a As String Set plage = Application.InputBox("Sélectionnez une plage !", "Sélection de cellules", Type:=8) a = plage.Address & "!" & plage.Address Range("AV15") = a End Sub

10/01/2019, 11h34
unparia

Bonjour
Commence au moins par cette "boîte de dialogue", qui n'est qu'une msgbox "yes/no".
La lecture de la rubrique MsgBox, fonction de ton aide VBA est claire et assortie d'exemple. Sa lecture devrait suffire à résoudre cette étape.
Nous passerons à ta seconde question après.

merci de votre retour
voici le code:

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
Sub SelectionPlages()
Dim plage As Range
Dim a As String
Set plage = Application.InputBox("Sélectionnez une plage !", "Sélection de cellules", Type:=8)
a = plage.Address & "!" & plage.Address
Range("AV15") = a
 
réponse = MsgBox("Voullez vous créer le nom de la plagé ? ", vbQuestion + vbYesNo, "???")
 
    If réponse = vbYes Then
        nomplage = InputBox("Veuillez indiquer le nom de la plage ? ")
    Else
       nomplage = a
    End If
End Sub

10/01/2019, 12h05
Menhir

Citation:

Envoyé par damijoo

Je désire que ma macro me renvoie l'adresse complete d'une zone selectionné en Range("AV15"), c'est à dire :
ex: CONFIG!$I$15:$J$24! si je selectionne l'onglet config & zone I15:J24

2. qu'une boite de dialogue me demande si je veux nommer la plage
3. si oui, qu'il me crée une plage nommée dans excel.

Inutile d'avoir l'adresse d'une plage pour la nommer, surtout si on a déjà sa référence.
Surtout que tu es très bien parti en utilisant un InputBox avec le paramètre 8.

Pas besoin de la variable "a".
Il suffit d'ajouter un second InputBox pour demander le nom souhaité et d'appliquer ce nom (après avoir vérifié qu'il n'est pas vide) avec la propriété Name.
https://msdn.microsoft.com/fr-fr/lib...7(v=office.15)

Dans ton dernier message, la MsgBox est inutile : si l'utilisateur ne veux pas nommer la plage, il lui suffit de ne pas mettre de nom dans la seconde InputBox ou même simplement d'appuyer sur le bouton "Annuler".
D'ailleurs, dans ton code, il serait bien de vérifier que l'utilisateur n'a pas fait "Annuler" à la première InputBox en plaçant un test If Not Plage Is Nothing Then.
10/01/2019, 12h17
damijoo

c'est justement la que je bloque.

Je n'arrive pas à faire comprendre au système de me resortir le nom complet (zone + sheet)

merci d'avance

Bonjour,

Une piste :

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
 
Sub SelectionPlages()
 
    Dim Plage As Range
    Dim Nom As String
 
    Set Plage = Application.InputBox("Sélectionnez une plage !", "Sélection de cellules", Type:=8)
 
    If MsgBox("Voullez vous créer le nom de la plage ? ", vbQuestion + vbYesNo, "???") = vbNo Then Exit Sub
 
    Nom = InputBox("Veuillez indiquer le nom de la plage ? ")
 
    If Nom = "" Then Exit Sub
 
    On Error Resume Next
    ThisWorkbook.Names.Add Nom, Plage, True
 
    If Err.Number <> 0 Then MsgBox "Le nom '" & Nom & "' n'est pas valide !"
 
End Sub

10/01/2019, 13h15
damijoo

Bonjour,

C'est super ca règle une de mes problématiques, maintenant je peux au moin afficher dans une cellule le nom de la zone selectionnée en placant Range("AV25") = Nom apres ThisWorkbook.Names.Add Nom, Plage, True

Cependant, je pense avoir mal défini mon problème, désolé.

la Macro doit systematiquement indiquer dans la case Range("AV15") soit:
1. le nom de la plage nommée si l'utilisateur a dit oui je veux en nommer une.

2. s'il ne désire pas la nommer, la plage selectionnée : nom complet qui dans ma terminologie veux dire veux dire son chemin : nom de l'onglet + zone selectionnée. ex : si je lance la macro depuis un onglet nommé 1 et que je réalise la selection depuis un onglet CONFIG : CONFIG!$I$15:$J$24!

Mon souci porte en fait sur les export des informations dans la cellule excel. Soit ca me renvoit du vide ou une erreur et le nom de l'onglet je ne sais pas le faire.

Merci pour la future aide

Cordialement

Comme ceci alors :

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
 
Sub SelectionPlages()
 
    Dim Plage As Range
    Dim Nom As String
 
    On Error Resume Next
    Set Plage = Application.InputBox("Sélectionnez une plage !", "Sélection de cellules", Type:=8)
 
    If Err.Number <> 0 Then Exit Sub 'si pas de sélection
 
    If MsgBox("Voulez-vous créer le nom de la plage ? ", vbQuestion + vbYesNo, "???") = vbNo Then
 
        Range("AV25").Value = Plage.Parent.Name & "!" & Plage.Address 'Plage.Address(0, 0)<-- si on la veux relative
        Exit Sub
 
    End If
 
    Nom = InputBox("Veuillez indiquer le nom de la plage ? ")
 
    If Nom = "" Then Exit Sub
 
    ThisWorkbook.Names.Add Nom, Plage, True
 
    If Err.Number <> 0 Then MsgBox "Le nom '" & Nom & "' n'est pas valide !" Else Range("AV25").Value = Nom
 
End Sub

10/01/2019, 14h18
damijoo

super merci beaucoup
10/01/2019, 14h37
Menhir

Citation:

Envoyé par damijoo

c'est justement la que je bloque.
Je n'arrive pas à faire comprendre au système de me resortir le nom complet (zone + sheet)

Moi, ce qui me "bloque", c'est ceux qui me font perdre mon temps.
Je viens de t'expliquer en détail pourquoi il était complètement inutile d'extraire le nom complet de la zone mais visiblement, ça n'a servit à rien.

Donc, je passe.
Bonne chance pour la suite.