Sélection et copie

Version imprimable

30/12/2018, 02h35
Aakash Qureshi

Sélection et copie

Bonsoir,bonjour,

Je souhaiterais savoir si quelqu'un pourrait m'aider sur une extraction que j'ai faite et pour lequel je souhaiterais faire une selection. Et qu'il me copie cette selection dans un onglet.
Est ce que c'est possible? Et si oui, pourriez vous m'aider svp?

Je vous explique ma problematique en detail.
Je suis de profession comptablr. Je n'ai pris connaissance que tres recemment des macros sur Excel. Etant assez curieux, je veux connaitre ce nouvelle outil qui pourrait me faciliter pas mal de saisie et donc un gain de travail.

Pour cela, je suis en train de creer des macros sur un fichier Excel pour mon suivi bancairr.

J'ai grace a des tutos et livres sur le sujets des macros et langage vba pu creer un sommaire pour mon fichier. Ainsi que creer une macros pour que la liste de mes comptes soient divisé en plusieur feuilles. Le sommaire me permet normalement de mettre en liaison les feuilles. Je dis normalement parceque je rencontre un petit probleme de reference (message d'erreur de Excel)

J'ai pu extraire notamment les lignes comptable de mon ERP que j'ai inserer dans une feuille sur ce fichier Excel.

Maintenant:

- serait il possible de me dire si l'on peut faire une selection d'une partie du tableau pour le mettre dans l'onglet creeer a son effet? Le tout en langage VBA. Et comment faire, si c'est possible?
-pour mon probleme de reference sur le sommaire, est ce qu'il y aurait une solution de recours?

Merci d'avance pour vos retours,
30/12/2018, 10h33
Patrice740

Bonjour,

Citation:

Envoyé par Aakash Qureshi

- serait il possible de me dire si l'on peut faire une selection d'une partie du tableau pour le mettre dans l'onglet creeer a son effet? Le tout en langage VBA. Et comment faire, si c'est possible?
-pour mon probleme de reference sur le sommaire, est ce qu'il y aurait une solution de recours?

1 - Oui, le plus simple est d'utiliser un filtre élaboré : https://philippetulliez.developpez.c...dvancedfilter/
2 - Certainement, encore faudrait-il connaitre le problème : Contexte, Code de la Macro, Message d'erreur, ...
30/12/2018, 11h35
Aakash Qureshi

Bonjour Patrice740'

Merci pour votre retour, je vais consulter votre lien pour ma reponse.
Concernant l'autre point, le message d'erreur me parle d'un probleme de reference non repertorié lorsque je clique sur le lien du sommaire censé m'envoyer vers la page concernée.
Je dis censé parceque, il me creer bien les pages et les liens mais dans le vba, les pages sont rangé par ordre numerique (feuil1, feuil10, feuil100, feuil2, feuil20, feuil200...).
Donc je pense que c'est de la que viens le probleme de reference...

J'utilise une tablette, comment vous montrer ma problematique...
30/12/2018, 13h29
John Mc Evee

Bonjour Aakash Qureshi et bienvenu sur le forum,

Il y a quelque temps, on a travaillé avec un comptable sur une ventilation de compte en partant du grand livre.

Voilà le lien de la discussion et tu devrais pouvoir trouver ton bonheur (Filtre des données, copies des données visibles, etc..). En fin de discussion, il y a un lien vers une thématique sur le lettrage de compte sur Excel.

lien

Si tu as des questions sur un traitement comptable particulier n'hésite pas.

A+
30/12/2018, 13h42
Patrice740

Citation:

Envoyé par Aakash Qureshi

J'utilise une tablette, comment vous montrer ma problematique...

Citation:

Envoyé par Patrice740

2 - Certainement, encore faudrait-il connaitre le problème : Contexte, Code de la Macro, Message d'erreur, ...

Patrice,

Le code est le suivant:

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
Sub Navigation()
Dim Ma_feuille as object
Dim num_ligne as long
 
       Num_ligne = 2
       For each ma_feuille in worksheets
              If ma_feuille.name <> "sommaire" then
              ' index dans le sommaire
                 Sheets ("sommaire").cells(num_ligne, 1) = ma_feuille.name
                 Sheets ("sommaire").hyperlinks.add anchor:=shhets("sommaire").cells(num_ligne,1),      
                 address:="", SubAddress:= ma_feuille.name & "!a1", texttodisplay:= ma_feuille.name
              'Creation du lien de retour   
                 Sheets (ma_feuille.name).hyperlinks.add anchor:=Sheets (ma_feuille.name).cells(1,3), 
                 address:="", address:="sommaire!a1", texttodisplay:="retour"
 
                 Num_ligne = num_ligne +1
              End if
        Next
 
End sub

Le message d'erreur est:

Citation:

La reference n'est pas valide

Merci pour votre retour,

30/12/2018, 14h10
Aakash Qureshi

John mc evee,

Je suis en train de regarder votre lien, votre macro a l'air de correspondre a ma demande,

Pensez vous qu'il est possible d'associer cette macro a une macro de sommaire?
Je souhaiterais aussi faire un systeme de rafraichissement avec un clearcontent pour eviter que mon extraction precedente soit encore presente dans mon extraction suivante, pensez vous que c'est faisable?

Merci pour votre retour,

Bonjour,

Ton code corrigé :

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
Option Explicit
Sub Navigation()
Dim Ma_feuille As Worksheet
Dim num_ligne As Long
  num_ligne = 2
  For Each Ma_feuille In Worksheets
    If Ma_feuille.Name <> "sommaire" Then
      ' index dans le sommaire
      With Worksheets("sommaire")
        .Hyperlinks.Add anchor:=.Cells(num_ligne, 1), Address:="", SubAddress:=Ma_feuille.Name & "!a1", TextToDisplay:=Ma_feuille.Name
      End With
      'Creation du lien de retour
      With Worksheets(Ma_feuille.Name)
        .Hyperlinks.Add anchor:=.Cells(1, 3), Address:="", SubAddress:="sommaire!a1", TextToDisplay:="retour"
      End With
      num_ligne = num_ligne + 1
    End If
  Next
End Sub

30/12/2018, 15h00
Aakash Qureshi

J'ai toujours le meme message .... 😕😕😕
30/12/2018, 15h07
Aakash Qureshi

1 pièce(s) jointe(s)

je viens d'avoir la possibilité de vous presenter mon fichier qui risquerait d'etre retraiter par plusieurs fichier Excel, au vue du nombre de banque et du nombre de page que sa me créer...

Quel serait le plus pratique?

Patrice pour votre code, il marche mais lorsque je clique sur le lien hypertexte du sommaire. il me met le message de bug, mais pas sur le lien retour de toute les feuilles. Comment cela peut etre possible?

Merci pour vos retours,
30/12/2018, 15h59
John Mc Evee

Salut,

Pour le code de patrick, il manque les ' (guillemets) pour le nom de la feuille et plus de problème. La ligne de code a modifier ci-dessous :

Code:

.Hyperlinks.Add Anchor:=Sheets("Sommaire").Cells(Num_Ligne, 1), Address:="", SubAddress:="'" & Ma_Feuille.Name & "'!A1", TextToDisplay:=Ma_Feuille.Name

De ce que j'ai compris, tu veux répartir tes données par compte bancaire. Mais qu'elles sont tes données d'entrée et comment souhaites-tu les affichés.

Sinon aucun soucis pour adapter le code de la ventilation mais sans des précisions sur les données d'entrée et les objectifs de sortie difficile de te répondre et de te proposer quelque chose.

A+
30/12/2018, 16h19
Aakash Qureshi

1 pièce(s) jointe(s)

En effet, je l'avais supprimer du fichier pour la confidentialité de mon entreprise
mais je met en PJ une veille extraction qui peut servir de base.

merci pour votre retour,

ps: john la formule fonctionne met elle me créer des liens à l'infini... 8O8O8O
30/12/2018, 16h29
John Mc Evee

Dans le code de patrick il faut juste que tu remplaces cette ligne. Pour la boucle infinie je n'ai pas le problème. Dès fois avec Excel, on y comprend plus rien :mouarf::mouarf::mouarf:.

Code:

.Hyperlinks.Add anchor:=.Cells(num_ligne, 1), Address:="", SubAddress:=Ma_feuille.Name & "!a1", TextToDisplay:=Ma_feuille.Name

par

Code:

.Hyperlinks.Add Anchor:=.Cells(Num_Ligne, 1), Address:="", SubAddress:="'" & Ma_Feuille.Name & "'!A1", TextToDisplay:=Ma_Feuille.Name

Si tu ne veux pas mettre à disposition des données confidentielles, les entêtes de colonnes avec deux trois lignes bidons suffisent à concevoir la macro.

Je regarde ton fichier dans la soirée.

A+

Salut,

J'ai regardé ton fichier et voici le code pour extraire les lignes compte par compte dans chaque feuille. J'ai utilisé une syntaxe explicite volontairement afin que tu t'appropries le code.

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
'************************************************************************************************************
' NAME : Copie_Extract_Banque (PROCESS)
' DESCRIPTION : A partir du grand livre extrait, le processus va répartir les différentes données par feuille
' Pour rappel, chaque feuille concerne un numéro de compte
'************************************************************************************************************
Public Sub Copie_Extract_Banque()
 
    Dim Feuille_Compte      As Excel.Worksheet
    Dim Feuille_Sommaire    As Excel.Worksheet
    Dim Feuille_Grand_Livre As Excel.Worksheet
    Dim Critere             As Long
    Dim Derniere_Ligne      As Long
 
    Application.ScreenUpdating = False
 
    Set Feuille_Grand_Livre = ThisWorkbook.Worksheets("Feuil1")
    Set Feuille_Sommaire = ThisWorkbook.Worksheets("Sommaire")
 
    'Pour toutes les feuilles du classeur
    For Each Feuille_Compte In ThisWorkbook.Worksheets
 
        'Sauf celle du sommaire du grand livre et nommé CCB
        If Not Feuille_Compte.Name = Feuille_Sommaire.Name And _
        Not Feuille_Compte.Name = Feuille_Grand_Livre.Name And _
        Not Feuille_Compte.Name = "C.C.B" Then
 
            ' On efface le travail précédent si il y a des données
            If Feuille_Compte.Range("A2") <> "" Then
 
                Derniere_Ligne = Feuille_Compte.Range("A1").End(xlDown).Row
                Feuille_Compte.Range("2:" & Derniere_Ligne).ClearContents
 
            End If
 
            With Feuille_Grand_Livre
 
                'On désactive les filtres
                If .FilterMode Then .ShowAllData
 
                Derniere_Ligne = .Range("A1").End(xlDown).Row
 
                'On récupère le critère en fonction du nom de la feuille
                ' 51278119 BRED PERPIGNAN C
                'Critere = 51278119
                Critere = CLng(Left$(Feuille_Compte.Name, InStr(Feuille_Compte.Name, " ") - 1))
 
                'On applique le filtre
                .Range("1:1").AutoFilter 7, Critere
 
                'On copie les données encore visible
                .Range("A1:T" & Derniere_Ligne).SpecialCells(xlCellTypeVisible).Copy Feuille_Compte.Range("A2")
 
 
            End With
 
        End If
 
    Next Feuille_Compte
 
    If Feuille_Grand_Livre.FilterMode Then Feuille_Grand_Livre.ShowAllData
 
    Feuille_Sommaire.Select
 
    Set Feuille_Sommaire = Nothing
    Set Feuille_Grand_Livre = Nothing
 
    Application.ScreenUpdating = True
End Sub

Si tu veux appeler le processus depuis un autre processus il faut utiliser l'instruction Call suivit du nom du processus à exécuter.

En espérant avoir répondu à ta question.

A+

31/12/2018, 12h02
Aakash Qureshi

Merci John,

Derniere petite question, est ce que tu peux me dire si c'est un ajout aux autres macros ou est ce qu'elle remplace les 2 macros faite precedemment sur le fichier?
31/12/2018, 13h05
John Mc Evee

Salut,
A rajouter en plus des 2 autres.

A+