évenement click sur checkbox dynamiquement

Version imprimable

11/12/2018, 12h53
jbrichez

évenement click sur checkbox dynamiquement
Bonjour à tous,

J'ai un Userform avec une série de 9 checkbox. J'aimerais eviter la répétition de code tel que :
Code:

1 2 3 4 5 6 7 8 9 10 Public Sub checkbox1_click() 'meme action End Sub Public Sub checkbox2_click() 'meme action End Sub etc...
Je passerais par une fonction a l'intérieur. Mais j'aimerais avoir si il est possible de coder un programme qui fonctionne sur le click de n'importe quelle checkbox du Userform.

Merci beaucoup.

Bonjour,

Toutes les checkBox appellent un sous-programme unique tel que l'exemple ci-dessous:

Code:

1
2
3
4
5
6
7
8
9
10
11
12
Public Sub checkbox1_click()
    Sous_Programme
End Sub
 
Public Sub checkbox2_click()
    Sous_Programme
End Sub
 
Sub Sous_Programme()
    'programme commun à toutes les checkBox
 
End Sub

Cdlt

Bonjour,

Avec un module de classe !
A mettre dans le module du formulaire :

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
 
Dim Chk() As New Classe1
 
Private Sub UserForm_Initialize()
 
    Dim Ctrl As Control
    Dim I As Integer
 
    For Each Ctrl In Me.Controls
 
        If TypeName(Ctrl) = "CheckBox" Then
 
            I = I + 1: ReDim Preserve Chk(1 To I)
            Set Chk(I).GrpChk = Ctrl
 
        End If
 
    Next Ctrl
 
End Sub

A mettre dans le module de classe nommé Classe1 et à adapter selon les besoins :

Code:

1
2
3
4
5
6
7
8
9
10
11
12
 
Public WithEvents GrpChk As MSForms.CheckBox
 
Private Sub GrpChk_Click()
 
    MsgBox "Titre de la case à cocher : " & GrpChk.Caption _
           & vbCrLf & _
           "Nom de la case à cocher : " & GrpChk.Name _
           & vbCrLf & _
           "Valeur de la case à cocher : " & GrpChk.Value
 
End Sub