Script pour renommage de fichier

Version imprimable

Bonjour,

J'écris en ce moment mon premier script batch et je m'arrache les cheveux... :(

Le but: automatiser le renommage de fichiers docx de la forme AA_BB_CC en CC_AA.

J'ai testé 2 méthodes, et j'ai un problème dans les deux. Pouvez-vous m'aider à trouver ce qui cloche svp?

1er essai: appel d'une subroutine

Problème: la boucle tourne une fois de trop ! Tous les fichiers sont renommés puis, le 1er fichier a avoir été renommé est renommé à nouveau avant que le programme ne quitte.

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
@echo off
SETLOCAL enableExtensions enableDelayedExpansion
title Renommage de fichiers PDF automatique
mode con cols=80 lines=16
color B
 
rem MAIN BATCH FILE PROGRAM----------------------------------
 
rem Selection du repertoire contenant les fichiers à renommer
set /p repertoire=Saissez le chemin absolu du repertoire:
 
rem Parcours de tous les fichiers du répertoire
for %%f in (%repertoire%\*.docx) do call :process %%~nf
goto :EOF
 
:process
set old_file_name=%1
rem Extraction des elements du nom de fichier
for /f "tokens=1,2,3 delims=_" %%a in ("%old_file_name%") do (
	set new_name_part_2=%%a
	set new_name_part_3=%%b
	set new_name_part_1=PO%%c
	)
rem Construction du nouveau nom de fichier
set new_file_name=%new_name_part_1%_%new_name_part_2%
rem renommage du fichier
ren %repertoire%\%old_file_name%.docx %new_file_name%.docx
echo Fichier %1 renomme en %new_file_name%!
pause > nul
goto :EOF

2eme essai: sans subroutine

Résultat: "Fichier AA_BB_CC renomme en _"

Problème: les variables de la deuxième boucle for sont perdues à la sortie de cette même boucle...

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
@echo off
SETLOCAL enableExtensions enableDelayedExpansion
title Renommage de fichiers PDF automatique
mode con cols=80 lines=16
color B
 
rem MAIN BATCH FILE PROGRAM----------------------------------
 
rem Selection du repertoire contenant les fichiers à renommer
set /p repertoire=Saissez le chemin absolu du repertoire:
 
rem Parcours de tous les fichiers du répertoire
for %%f in (%repertoire%\*.docx) do (
	set old_file_name=%%~nf
	rem Extraction des elements du nom de fichier
	for /f "tokens=1,2,3 delims=_" %%a in ("%old_file_name%") do (
		set new_name_part_2=%%a
		set new_name_part_3=%%b
		set new_name_part_1=PO%%c
		)
	rem Construction du nouveau nom de fichier
	set new_file_name=!new_name_part_1!_!new_name_part_2!
	rem renommage du fichier
	ren %repertoire%\%old_file_name%.docx !new_file_name!.docx
	echo Fichier %%~nf renomme en !new_file_name!!
	pause > nul 
	)
 
echo Attention je vais quitter
pause > nul
goto :EOF

Je suis à cours d'idée... Merci d'avance pour votre aide!

Bonjour,

Voilà la solution :

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
@echo off
SETLOCAL enableExtensions enableDelayedExpansion
title Renommage de fichiers PDF automatique
mode con cols=150 lines=32
color B
chcp 1252 >nul
 
rem MAIN BATCH FILE PROGRAM----------------------------------
 
rem Selection du repertoire contenant les fichiers à renommer
set /p repertoire="Saisissez le chemin absolu du répertoire: " 
 
rem on teste si le répertoire existe et on se positionne dedans
cd /d %repertoire% || exit /b 1
 
if not exist "temp" (mkdir "temp")
 
rem Parcours de tous les fichiers du répertoire
for %%A in (*.docx) do (call:process "%%~fA")
 
move "temp\*.*" "%repertoire%\" >nul
rmdir "temp"
 
echo. & pause
exit /b 0
 
:process
echo.
for /f "tokens=1,2,* delims=_" %%a in ("%~n1") do (
	move "%~1" "temp\%%c_%%a%~x1" >nul
	echo Fichier [%~nx1] renommé en [%%c_%%a%~x1]
)
goto :EOF

Je suis obligé de déplacer les fichiers dans un dossier temporaire sinon la boucle traite certains fichiers plusieurs fois, ce qui est tout à fait normal.

04/12/2018, 19h29
Marco88

Wahou!!!! Super, merci beaucoup barnabe0057!

C'est vraiment un code très propre et très concis (ça m'a fait apprendre un tas d'autres commandes :P) et ca marche du tonnerre! :mrgreen:

Le test d'existence du répertoire pour éviter le plantage est un must :oops:... et j'admire la puissance de passer le nom complet du fichier en paramètres de la subroutine!

Petite question cependant pour bien comprendre: pourquoi est-ce que la boucle ne s’arrête pas après avoir traiter tous les fichiers du répertoire (ce qui est pourtant ce qu'on lui dit de faire)?

Code:

for %%A in (*.docx) do (call:process "%%~fA")

On dirait que la création d'un répertoire temporaire est une solution de contournement pour empêcher la boucle de tourner une fois de trop...

Merci encore pour votre aide, j’apprécie vraiment! :)
04/12/2018, 22h23
barnabe0057

Je suis content que tu apprécies mes petites astuces, surtout si ça te permet d'apprendre.

Concernant le problème avec la boucle, je ne suis pas encore assez pointu sur le fonctionnement de l'interpréteur de commandes pour te donner une explication correcte.
Apparemment la boucle re-liste les fichiers à un moment ou à un autre, du coup les fichiers renommés sont considérés comme non-traités, et donc traités une deuxième fois. Enfin c'est ma théorie (un peu bancal je l'admets !).