Filtrer les valeurs d'une ListBox (issues d'une feuiles excel) dans un UserForm

Version imprimable

3 pièce(s) jointe(s)

Bonjour à tous et merci à tous pour votre aide !

J'ai un tableau Excel inséré dans un UserForm à l'aide d'un ListBox.
Je cherche à ajouter un filtre dans la ListBox afin de n'afficher que les valeurs qui contiennent par exemple "325" choisie dans un TextBox.
A terme je souhaite sélectionner une des lignes dans ce ListBox et mettre en gras la ligne correspondante dans la feuille "Essai". Cela ressemble à ça :

Pièce jointe 428344

Pièce jointe 428346

Je me suis basé sur le code que j'ai trouvé sur cette discussion sur le forum qui m'a beaucoup aidé : Insérer un tableau excel dans un UserForm
(Merci à eux).

Avez vous des pistes pour pouvoir filtrer ma ListBox ?

J'ai ajouté le fichier Excel en PJ.

Merci d'avance pour votre aide.

Axel

PS :
Voila le code source :
Code:

1 2 3 4 5 6 7 8 9 10 11 12 13 14 15 16 17 18 19 20 21 22 23 24 25 26 27 Private Sub CommandButton1_Click() With ListBox1 For i = 0 To .ListCount - 1 If .Selected(i) = True Then mess = mess & i + 1 + 1 & vbCrLf ' tu peut mettre 2 bien entendu Next End With MsgBox mess End Sub Private Sub ListBox1_Click() MsgBox ListBox1.ListIndex End Sub Private Sub UserForm_Activate() Dim plage As Range, i As Long, large With Sheets("Essai") Set plage = .Range("A1").CurrentRegion.Offset(1, 0) For i = 1 To plage.Columns.Count: large = large & ";" & Round(plage.Columns(i).Width): Next ' on capture la largeur des colonnes large = Mid(large, 2, 200) With Me.ListBox1 .RowSource = plage.Address .ColumnHeads = True .ColumnWidths = large .ColumnCount = plage.Columns.Count .ListStyle = 1 .MultiSelect = 1 End With End With End Sub

Bonjour,

Une piste, remplaces les procédures correspondantes :

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
 
Private Sub CommandButton2_Click()
 
    Dim Cel As Range
    Dim I As Long
 
    ListBox1.Clear
 
    For Each Cel In Plage.Columns(4).Cells 'recherche seulement sur la dernière colonne de la plage
 
        If Cel.Value = TextBox1.Text Then
 
            ListBox1.AddItem Cel.Offset(, -3).Value
            ListBox1.Column(1, I) = Cel.Offset(, -2).Value
            ListBox1.Column(2, I) = Cel.Offset(, -1).Value
            ListBox1.Column(3, I) = Cel.Value
            ListBox1.Column(4, I) = Cel.Row
 
            I = I + 1
 
        End If
 
    Next Cel
 
End Sub
 
Private Sub ListBox1_MouseUp(ByVal Button As Integer, ByVal Shift As Integer, ByVal X As Single, ByVal Y As Single)
 
    Dim I As Long
 
    Plage.Font.Bold = False
 
    For I = 0 To ListBox1.ListCount - 1
 
        Plage.Rows(ListBox1.Column(4, I) - 1).Font.Bold = ListBox1.Selected(I)
 
    Next I
 
End Sub
 
Private Sub UserForm_Activate()
 
    Dim I As Long, Large
 
    With Worksheets("Essai"): Set Plage = .Range(.Cells(2, 1), .Cells(.Rows.Count, 4).End(xlUp)): End With
 
    For I = 1 To Plage.Columns.Count: Large = Large & Round(Plage.Columns(I).Width) & "pt;": Next
 
    Large = Large & "0pt" 'rajoute une dimension égale à 0 pour la cacher, cette colonne contient les numéros de ligne
 
    With ListBox1
 
        .ColumnCount = Plage.Columns.Count + 1
        .ColumnWidths = Large
        .ListStyle = 1
        .MultiSelect = 1 'ne permet pas la gestion de l'événement Click() sur la ListBox !
 
    End With
 
End Sub

1 pièce(s) jointe(s)

Bonjour,

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
Dim f, TblBD(), NBCol
Option Compare Text
Private Sub UserForm_Initialize()
  Set f = Sheets("Essai")
  Set d = CreateObject("Scripting.Dictionary")
  Set Rng = f.Range("A2:E" & f.[A65000].End(xlUp).Row)
  TblBD = Rng.Value
  NBCol = UBound(TblBD, 2) - 1
  For i = 1 To UBound(TblBD): TblBD(i, NBCol + 1) = i + Rng.Row - 1: Next i
  Me.ListBox1.List = TblBD
  Me.ListBox1.ColumnCount = 5
  Me.ListBox1.ColumnWidths = "50;30;50;50;50"
End Sub
 
Private Sub TextBox1_Change()
  ColRecherche = 4
  clé = "*" & Me.TextBox1 & "*"
  Dim Tbl()
  For i = 1 To UBound(TblBD)
    If TblBD(i, ColRecherche) Like clé Then
        n = n + 1: ReDim Preserve Tbl(1 To UBound(TblBD, 2), 1 To n)
        For k = 1 To UBound(TblBD, 2): Tbl(k, n) = TblBD(i, k): Next k
     End If
  Next i
  If n > 0 Then Me.ListBox1.Column = Tbl Else Me.ListBox1.List = TblBD
End Sub
 
Private Sub b_affiche_Click()
 f.[A1].CurrentRegion.Interior.ColorIndex = xlNone
 For i = 0 To Me.ListBox1.ListCount - 1
   If Me.ListBox1.Selected(i) Then
     ligne = Me.ListBox1.List(i, NBCol)
     f.Cells(ligne, 1).Resize(, NBCol).Interior.ColorIndex = 3
   End If
 Next i
End Sub

Boisgontier

21/11/2018, 12h19
axelair2

Merci à vous 2 pour votre aide c'est incroyable !

Boisgontier le code marche parfaitement c'est génial !
Merci encore pour votre aide j'ai appris plein de choses :P

Bonne journée à vous 2 !