Édition et modification d'un document RTF

Version imprimable

Bonjour a tous ! :)
Alors après recherche je me tourne vers vous pour un petit problème je souhaiterais a partir d'un document.rtf modelé dupliquer le Document.rtf et modifier le duplicata avant de l'imprimer puis de le supprimer.
Dans mon .rtf j'ai plusieurs "variable" (enfin ce que je souhaite modifier:weird: ) je les est ecrite sous la forme [Variable].
Peut etre avec
Code:

1 2 3 4 Const ForWriting = 2 '***Permet d'ecrire les données Set fso = CreateObject("Scripting.FileSystemObject") Set NewFichier = fso.OpenTextFile("D:\Vitogaz\Log\Bon.rtf",ForWriting,True)
Avez vous des suggestions ? Car je suis un peut perdu :aie:

Merci infiniment d’avance !! :ave: :ave: :ave: :ave: :ave:

16/11/2018, 09h01
l_autodidacte

Tu as déjà ces deux liens qui en parlent : ICI et ICI .

[Re]

Merci pour ta réponse et désoler de rouvrir ce post.
malgré les deux post que tu ma conseiller je n'arrive pas a trouver comment modifier un partie de mon document.rtf. J'ai beau me triturer la tête je ne comprend pas comment ce bout de code fonctionne:
Code:

1 2 3 4 5 6 7 8 9 10 11 rtfContents = "{\rtf1\ansi\ansicpg1252\deff0\nouicompat\deflang1036{\fonttbl{\f0\fnil\fcharset0 Calibri;}{\f1\fnil\fcharset0 MS Sans Serif;}{\f2\fnil\fcharset0 Arial;}}" _ & "{\colortbl ;\red0\green77\blue187;\red0\green176\blue80;\red255\green0\blue0;}" _ & "{\*\generator Riched20 10.0.17134}\viewkind4\uc1" _ & "\pard\sa200\sl276\slmult1\f0\fs22\lang12 " & Txt_prenom.value & " \b "& Txt_nom.value &"\b0\par" _ & "\cf1\b\fs24 "& Txt_titre.value &"\par" _ & "\cf0\b0 "& Txt_poste.Value &"\par" _ & "\cf2\b "& Txt_mail.value &"\par" _ & "\pard\sa200\sl276\slmult1\tx1278\cf3\b0\i "& Txt_Add.Value &"\par" _ & "\cf0\b\i0\f1 "& Txt_Code.Value &" "& Txt_Ville.Value &"\f0 \par" _ & "\b0\f2 "& Txt_Tel.value &"\fs22\par" _ & "}"
Je pense que c'est la partie qui permet de modifier des bout de texte mais je suis pas douer avec le vbs.
Je me permet donc implorer une fois de plus votre aide :merci:

Salut

UN exemple dans un HTA

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
<HEAD>
        <TITLE> Générer un .RTF </TITLE>
        <HTA:APPLICATION
                Id = "DemoRtf"
                >
                <SCRIPT language="VBScript" type="text/vbscript">ResizeTo 320,380</SCRIPT>
        </HEAD>
        <script language="VBScript">
                Dim DossierRacineDuProg
                Sub Window_Onload()
                        Dim ChemNomComplet
                        ChemNomComplet = DemoRtf.CommandLine ' ChemNomComplet = Id du programme.CommandLine
                        DossierRacineDuProg = Left(ChemNomComplet, (InStrRev(ChemNomComplet, "\", -1, vbTextCompare)))
                        DossierRacineDuProg = Replace(DossierRacineDuProg,Chr(34),"")
                End Sub
                '----------------------------------------------------------------------------------------------------------------------
                Sub FormatRTF()
                        Dim rtfContents
                        rtfContents = "{\rtf1\ansi\ansicpg1252\deff0\nouicompat\deflang1036{\fonttbl{\f0\fnil\fcharset0 Calibri;}{\f1\fnil\fcharset0 MS Sans Serif;}{\f2\fnil\fcharset0 Arial;}}" _
                                                & "{\colortbl ;\red0\green77\blue187;\red0\green176\blue80;\red255\green0\blue0;}" _
                                                & "{\*\generator Riched20 10.0.17134}\viewkind4\uc1" _
                                                & "\pard\sa200\sl276\slmult1\f0\fs22\lang12 " & Txt_prenom.value & " \b "& Txt_nom.value &"\b0\par" _
                                                & "\cf1\b\fs24 "& Txt_titre.value &"\par" _
                                                & "\cf0\b0 "& Txt_poste.Value &"\par" _
                                                & "\cf2\b "& Txt_mail.value &"\par" _
                                                & "\pard\sa200\sl276\slmult1\tx1278\cf3\b0\i "& Txt_Add.Value &"\par" _
                                                & "\cf0\b\i0\f1 "& Txt_Code.Value &" "& Txt_Ville.Value &"\f0 \par" _
                                                & "\b0\f2 "& Txt_Tel.value &"\fs22\par" _
                                                & "}"
                        'enregistrer dans le dossier du programme
                        Dim FSO, F
                        Set FSO = CreateObject("Scripting.FileSystemObject")
                        Set F = FSO.OpenTextFile(DossierRacineDuProg & "test1.RTF", 2,true) 
                        F.Write rtfContents
                        F.Close
                        Set F = Nothing: Set FSO = Nothing
                        msgbox "Fichier test1.RTF sauvegardé dans le dossier: " & DossierRacineDuProg
                End Sub
                '----------------------------------------------------------------------------------------------------------------------
                </SCRIPT>
        <body>
                Prénom:         <input type="text" name="Txt_prenom" style="position: absolute; left:100px; width:150px"> <br>
                Nom:            <input type="text" name="Txt_nom" style="position: absolute; left:100px; width:150px"> <br>
                Titre:          <input type="text" name="Txt_titre" style="position: absolute; left:100px; width:150px"> <br>
                Poste:          <input type="text" name="Txt_poste" style="position: absolute; left:100px; width:150px"> <br>
                Mail:           <input type="text" name="Txt_mail" style="position: absolute; left:100px; width:150px"> <br>
                Code postal:    <input type="text" name="Txt_Code" style="position: absolute; left:100px; width:150px"> <br>
                Ville:          <input type="text" name="Txt_Ville" style="position: absolute; left:100px; width:150px"> <br>
                Telephone:      <input type="text" name="Txt_Tel" style="position: absolute; left:100px; width:150px"> <br>
                Infos:  <br>
                               <TEXTAREA name="Txt_Add" style="position:relative; left:53px; height:100px; width:208px"></TEXTAREA>
                <br> <br>
                <INPUT Type="button" name="BtT1" value=" Go " onClick="FormatRTF">
        </body>

A savoir que pour obtenir le formatage de la variable rtfContents, il faut proceder comme indiqué dans le post N°7 de cette discussion.

Re

Ayant relu le premier message d'ouverture de la discussion.
Une version en VBScript avec variables en lieu et place d'input HTML.

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
'Nom du fichier: DemoRtf.vbs
Dim Reponse1, Reponse2, Reponse3, Reponse4, Reponse5, Reponse6
Reponse1 = inputbox("Votre prénom")
Reponse2 = inputbox("Votre nom")
Reponse3 = inputbox("Votre message")
Reponse4 = inputbox("Votre code postal")
Reponse5 = inputbox("Votre ville")
Reponse6 = inputbox("Votre telephon")
 
Dim rtfContents
	rtfContents = "{\rtf1\ansi\ansicpg1252\deff0\nouicompat\deflang1036{\fonttbl{\f0\fnil\fcharset0 Calibri;}{\f1\fnil\fcharset0 MS Sans Serif;}{\f2\fnil\fcharset0 Arial;}}" _
				& "{\colortbl ;\red0\green77\blue187;\red0\green176\blue80;\red255\green0\blue0;}" _
				& "{\*\generator Riched20 10.0.17134}\viewkind4\uc1" _
				& "\pard\sa200\sl276\slmult1\f0\fs22\lang12 " & Reponse1 & " \b "& Reponse2 &"\b0\par" _
				& "\cf1\b\fs24 "& Reponse3 &"\par" _
				& "\cf0\b\i0\f1 "& Reponse4 &" "& Reponse5 &"\f0 \par" _
				& "\b0\f2 "& Reponse6 &"\fs22\par" _
				& "}"
			'enregistrer dans le dossier du programme
			Dim DossierRacineDuProg, NomDuFichierVBS
			NomDuFichierVBS = "DemoRtf.vbs"
			DossierRacineDuProg = replace(WScript.ScriptFullName,NomDuFichierVBS,"")
			Dim FSO, F
			Set FSO = CreateObject("Scripting.FileSystemObject")
			Set F = FSO.OpenTextFile(DossierRacineDuProg & "test2.RTF", 2,true) 
			F.Write rtfContents
			F.Close
			Set F = Nothing: Set FSO = Nothing
			msgbox "Fichier test2.RTF sauvegardé dans le dossier: " & DossierRacineDuProg

04/12/2018, 11h19
Superzest 76

[Re]

@ProgElecT Merci infiniment pour ton aide j'ai compris comment ça marche maintenant ! :merci: