2 boucles FOR imbriquées et GOTO

Version imprimable

Bonjour,
Je coince dans l'élaboration d'un petit script batch.
La première boucle lit les données dans un fichier structuré "liste.txt" qui possède cette structure "Client;Chemin;ExtensionFichier;Date;Heure" et qui dispose de plusieurs lignes de données.
Code:

1 2 3 4 5 6 7 8 9 10 11 12 13 14 15 16 17 18 19 20 21 22 23 24 25 26 27 28 29 30 31 @ECHO OFF SETLOCAL ENABLEDELAYEDEXPANSION FOR /F "skip=1 delims=; tokens=1,2,3,4,5" %%a IN (liste.txt) DO ( SET Client=%%a SET CheminDossier=%%b SET ExtensionFichiers=%%c SET DateTrigger=%%d SET HeureTrigger=%%e SET DateCompleteTrigger=!DateTrigger!_!HeureTrigger! FOR /F "tokens=1,2" %%i IN ('dir !CheminDossier!\*.!ExtensionFichiers! /O-D ^| FIND "/"') DO ( SET DateDernierFichier=%%i SET HeureDernierFichier=%%j ECHO !DateDernierFichier!_!HeureDernierFichier! GOTO :Next ) :Next ECHO Client=!Client! ECHO !DateDernierFichier! ) ENDLOCAL PAUSE
Mon problème se situe au niveau du GOTO :Next qui me fait en fait sortir des 2 boucles !!! et pas juste de la deuxième comme souhaité.
Du coup il ne parcourt que la première ligne de données du fichier "liste.txt"
Si je supprime la partie avec GOTO :Next... il me parcourt bien tout le fichier liste.txt mais alors je n'obtiens plus le résultat souhaité.

Le GOTO :Next a pour objectif de ne lister que le fichier le plus récent de la fonction DIR

Voilà j'espère avoir était assez clair pour que quelqu'un puisse m'aider.
Merci
A+
Dams'

Salut,

ton label :next est contenu dans la première boucle !!!!:aie:

essaye ça:

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
@ECHO OFF

SETLOCAL ENABLEDELAYEDEXPANSION


FOR /F "skip=1 delims=; tokens=1,2,3,4,5" %%a IN (liste.txt) DO (

	SET Client=%%a
	SET CheminDossier=%%b
	SET ExtensionFichiers=%%c
	SET DateTrigger=%%d
	SET HeureTrigger=%%e
	SET DateCompleteTrigger=!DateTrigger!_!HeureTrigger!


  FOR /F "tokens=1,2" %%i IN ('dir !CheminDossier!\*.!ExtensionFichiers! /O-D ^| FIND "/"') DO (
	SET DateDernierFichier=%%i
	SET HeureDernierFichier=%%j
	ECHO !DateDernierFichier!_!HeureDernierFichier!
	GOTO :Next
  )
)

endlocal
echo done!!!
exit/b


:Next
  ECHO Client=!Client!
  ECHO !DateDernierFichier!
  pause

16/11/2018, 11h15
damsmut

ben non, ça ne marche pas... seule la 1ère ligne du fichier "liste.txt" est lue.

La 1ère boucle se ferme à la 1ère parenthèse fermante ")"
La 2ème boucle se ferme à la 2ème parenthèse fermante.

Or tout ce que tu as rajouté se trouve après la 2ème parenthèse fermante... donc ça ne marche pas

Bonjour damsmut, salut sachadee,

En fait tu n'as pas besoin de sortir de la deuxième boucle, il suffit d'inverser l'ordre de tri et de récupérer le dernier résultat :

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
@ECHO OFF

SETLOCAL ENABLEDELAYEDEXPANSION

FOR /F "skip=1 delims=; tokens=1,2,3,4,5" %%a IN (liste.txt) DO (

	SET Client=%%a
	SET CheminDossier=%%b
	SET ExtensionFichiers=%%c
	SET DateTrigger=%%d
	SET HeureTrigger=%%e
	SET DateCompleteTrigger=!DateTrigger!_!HeureTrigger!


  FOR /F "tokens=1,2" %%i IN ('dir "!CheminDossier!\*.!ExtensionFichiers!" /OD ^| FIND "/"') DO (
	SET DateDernierFichier=%%i
	SET HeureDernierFichier=%%j
  )

  ECHO Client=!Client!
  ECHO !DateDernierFichier!_!HeureDernierFichier!

)

ENDLOCAL
PAUSE

17/11/2018, 10h18
damsmut

salut barnabe0057,

c'est en fait la solution provisoire que j'avais mis en place en attendant de recevoir une solution à mon problème :-)
17/11/2018, 19h46
sachadee

met un compteur dans ta deuxime boucle qui se reinitialise dans la première et ça marchera tranquille !
18/11/2018, 19h27
damsmut

tu peux être plus précis avec ton idée de compteur sachadee ?
un ptit bout de code ?

qqe chose comme ça :

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
@ECHO OFF

SETLOCAL ENABLEDELAYEDEXPANSION


FOR /F "skip=1 delims=; tokens=1,2,3,4,5" %%a IN (liste.txt) DO (

	SET Client=%%a
	SET CheminDossier=%%b
	SET ExtensionFichiers=%%c
	SET DateTrigger=%%d
	SET HeureTrigger=%%e
	SET DateCompleteTrigger=!DateTrigger!_!HeureTrigger!
	set /a $c=1

  FOR /F "tokens=1,2" %%i IN ('dir !CheminDossier!\*.!ExtensionFichiers! /O-D ^| FIND "/"') DO (
	SET DateDernierFichier=%%i
	SET HeureDernierFichier=%%j
	ECHO !DateDernierFichier!_!HeureDernierFichier!
	if !$c!==1 (
		ECHO Client=!Client!
		ECHO !DateDernierFichier!
		set /a $c+=1
		pause
		)
  )
)

echo done!!!

29/11/2018, 09h58
damsmut

bon, finalement je suis resté sur l'idée de contournement...

Citation:

En fait tu n'as pas besoin de sortir de la deuxième boucle, il suffit d'inverser l'ordre de tri et de récupérer le dernier résultat :