Menu contextuel lié à un tableau excel

Version imprimable

Bonjour,

J'ai une macro qui fonctionne parfaitement. Je l'ai ajouté au menu contextuel du clic droit dans une feuille classique. Cela fonctionne parfaitement (modification et RAZ du menu contextuel, appelle de la macro etc).

Mon problème est que je n'arrive pas à connaitre le nom du menu contextuel lié à un tableau excel (excel 2016; insérer/tableaux/tableaux ou Ctrl+l) pour appeler ma macro depuis un clic droit dans le tableau. Actuellement j'ai du le déplacer en dehors mais ce n'est pas satisfaisant.

J'ai cherché sur le forum et sur le net et n'ai rien trouvé sauf la quasi certitude que c'est bien un commandbar comme pour toutes les autres applications se servant du clic droit dans excel.
J'ai utilisé la macro ci-dessous pour obtenir le nom du menu contextuel en faisant plusieurs clics droit dans un tableaux. J'obtiens "worksheet menu bar".
Code:

1 2 3 4 5 Private Sub Worksheet_BeforeRightClick(ByVal Target As Range, Cancel As Boolean) MsgBox Application.CommandBars.ActiveMenuBar.Name End Sub
J'ai créé une autre macro pour obtenir toutes les commadbars et en ai essayé une bonne dizaine mais sans résultat. (J'ai obtenu une liste de 155 noms que je ne colle pas ici pour la clarté.)
Code:

1 2 3 4 5 6 7 8 9 10 11 12 13 Sub ggg() Dim cb As CommandBar Dim i As Integer i = 1 For Each cb In Application.CommandBars Range("A" & i) = cb.Name i = i + 1 Next cb End Sub
Je m'en remets donc à votre aide pour obtenir ce nom de commandbar mystérieux. Merci d'avance pour votre soutien.

06/11/2018, 16h01
Theze
Bonjour,

je n'ai pas Excel 2016 mais par exemple en Excel 2007, si je veux afficher le menu contextuel clic droit c'est :
Code:

1 2 3 4 5 Dim B As CommandBar Set B = CommandBars("Cell") B.ShowPopup
Si je veux exécuter le menu "Insérer..." de cette barre, je fais :
Code:

1 2 3 4 5 Dim B As CommandBar Set B = CommandBars("Cell") B.Controls("&Insérer...").Execute
L'esperluette avant le mot "Insérer" représente le trait de raccourci clavier et il doit être mis sinon, le nom du menu ne sera pas reconnu.
Code pour voir les Captions des contrôles :
Code:

1 2 3 4 5 6 7 Dim B As CommandBar Dim C As CommandBarControl Set B = CommandBars("Cell") For Each C In B.Controls: Debug.Print C.Caption: Next C
Là, on voit bien les esperluettes qui sont dans les noms.
07/11/2018, 09h49
valkia

2 pièce(s) jointe(s)

Bonjour Theze et merci pour ton temps,

Je maîtrise les ajouts que l'on peut faire au menu contextuel en général et en particulier à celui des cellules standards car je connais le nom de la commandbar sur laquelle agir. Pièce jointe 425103
Mon soucis est de connaître le nom de la commandbar affectée au tableaux que l'on insère via insérer/tableaux/tableaux ou Ctrl+l.
Mon problème sera alors résolu car dans mon code je remplacerai commandbars("Cell") par commandbars("INCONNU_POUR_L'INSTANT") et tout sera fini.
Pièce jointe 425112

Bonjour,

Peut être en listant les objets de chaque barre de commande dans la feuille active et en cherchant le nom du bouton :

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
 
Sub Test()
 
    Dim B As CommandBar
    Dim Ctrl As CommandBarControl
    Dim I As Integer
 
    For Each B In CommandBars
 
        I = I + 1: Cells(I, 1).Value = B.Name
 
        For Each Ctrl In B.Controls
 
            I = I + 1: Cells(I, 2).Value = Ctrl.Caption
            Cells(I, 3).Value = TypeName(Ctrl)
            'Ctrl.CopyFace: ActiveSheet.Paste Cells(I, 4) 'ceci prend pas mal de temps d'où le DoEvents
            'DoEvents
 
        Next Ctrl
 
    Next B
 
End Sub

MERCI !

La solution était en effet de ne pas juste afficher les commandbars comme je l'avais évoqué mais bien d'afficher le niveau inférieur et de rechercher ("ta&ble" et non "table").

Pour ceux qui voudront la réponse directement c'est "List Range Popup". Pour ceux qui voudront agir sur un autre, utilisez la petite macro de Theze pour trouver la commandbar qui vous intéresse.
Et pour les détails de codage je joins le code qui ajoute et retire les options perso au clic droit.
dans un module :

Code:

1
2
3
4
5
6
7
8
9
10
11
'**********************************************************************************************************************************
'                                                RESTAURATION CLIC DROIT
'**********************************************************************************************************************************
 
Sub DeleteFromCellMenu()
 
    Application.CommandBars("cell").Reset
    Application.CommandBars("List Range Popup").Reset
 
 
End Sub

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
'**********************************************************************************************************************************
'                                                AJOUT AU CLIC DROIT pour MOTOR TABLE
'**********************************************************************************************************************************
 
 
Sub AddToCellMenu_MOTORTABLE()
    Dim ContextMenu As CommandBar
    Dim MySubMenu As CommandBarControl
 
    ' Supprime les ajouts pour éviter les doublons
    Call DeleteFromCellMenu
 
    ' définit ContextMenu comme un menu concernant les cellules
    Set ContextMenu = Application.CommandBars("List Range Popup")
 
    ' Ajoute  un bouton
    Set MySubMenu = ContextMenu.Controls.Add(Type:=msoControlButton, before:=1)
 
    With MySubMenu
        .FaceId = 25
        .Caption = "SEARCH MOTOR"
        .Tag = "My_Cell_Control_Tag"
        .OnAction = "'" & ThisWorkbook.Name & "'!" & "Manual_search"
    End With
 
    ' ajoute un séparateur avec le menu suivant
    ContextMenu.Controls(2).BeginGroup = True
 
End Sub

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
'**********************************************************************************************************************************
'                                                RECHERCHE MANUELLE DE MOTEUR DEPUIS TABLEAU MOTEUR
'**********************************************************************************************************************************
 
Sub Manual_search()
 
    Application.ScreenUpdating = False
 
    TRAITEMENT DE LA MACRO
 
    Application.ScreenUpdating = True
 
End Sub

dans workbook :

Code:

1
2
3
4
5
Private Sub Workbook_Deactivate()
 
    Call DeleteFromCellMenu
 
End Sub

Merci encore à Theze et bonne journée.

08/11/2018, 16h54
Theze

Bonjour,

Content de t'avoir aidé mais je ne pouvais pas te donner le nom du bouton car je n'ai pas Excel 2016 et il n'existe pas en 2007 !
09/11/2018, 14h15
valkia

Citation:

Envoyé par Theze

je ne pouvais pas te donner le nom du bouton

J'avais faim, tu m'as appris à pêcher. Ne t'excuse pas de ne pas m'avoir donner un poisson.
11/07/2025, 13h39
johnsdoeuf

M'a bien aidé

Merci