ADO - MS SQL Server, empecher un time out sans changer les parametres ?

Version imprimable

Bonjour a vous et merci de votre temps et de votre aide.

J'ai une application Access qui utilise in BD MS SQL Server pour ses donnees et une partie de ses traitements.
Mon probleme est que j'ai un time out d'une minute sur ma connexion, donc si je depasse ce temps de traitement du cote de SQL, j'ai une erreur dans Access.
Je ne peux pas (c'est interdit par ma compagnie) changer la duree du time out. C'est 1 mn pas une seconde de plus.

Pour lancer mes traitements j'utilise :

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
Public Sub ExecuteExec(prmStoredProcName As String, ParamArray prmStoredProcParam() As Variant)
    'Call a store procedure executing something
    Dim storedProcConnection As New ADODB.Connection
    Call storedProcConnection.Open("MonDSN")
 
    Dim execCmd As String
    Dim execParam As String
 
    Dim p As Variant: For Each p In prmStoredProcParam
        If execParam <> "" Then
            execParam = execParam & ", "
        End If
 
        execParam = execParam & p
    Next p
 
    Dim db As DAO.Database: Set db = CurrentDb
    execCmd = db.QueryDefs(prmStoredProcName).SQL & " " & execParam
    db.Close: Set db = Nothing
 
    Dim cmd As New ADODB.Command
 
    With cmd
        .ActiveConnection = storedProcConnection
        .CommandText = execCmd
        .CommandType = adCmdText
        .Execute
    End With
 
    Set cmd = Nothing
 
    Call storedProcConnection.Close:  Set storedProcConnection = Nothing
End Sub

Et pour les requetes de selection :

Code:

1
2
3
4
5
6
7
8
Public Sub OpenSelectConnection()
 
    If m_SelectConnection Is Nothing Then
        Set m_SelectConnection = New ADODB.Connection
        Call m_SelectConnection.Open("MonDSN")
    End If
 
End Sub

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
Private Function ExecuteSelect(prmStoredProcName As String, ParamArray prmStoredProcParam() As Variant) As ADODB.Recordset
    'Call a stroed procedure returning a recordset
    Call OpenSelectConnection
 
    Dim execCmd As String
    Dim execParam As String
 
    Dim p As Variant: For Each p In prmStoredProcParam
        If execParam <> "" Then
            execParam = execParam & ", "
        End If
 
        execParam = execParam & p
    Next p
 
    Dim db As DAO.Database: Set db = CurrentDb
    execCmd = db.QueryDefs(prmStoredProcName).SQL & " " & execParam
    db.Close: Set db = Nothing
 
    Dim result As New ADODB.Recordset
 
    With result
        .ActiveConnection = m_SelectConnection
        .Source = execCmd
        .LockType = adLockOptimistic
        .CursorType = adOpenKeyset
        .CursorLocation = adUseClient
        .Open
    End With
 
    Set ExecuteSelect = result: Set result = Nothing
End Function

Code:

1
2
3
4
5
6
7
8
Public Sub CloseSelectConnection()
 
    If Not m_SelectConnection Is Nothing Then
        Call m_SelectConnection.Close
        Set m_SelectConnection = Nothing
    End If
 
End Sub

Je peux changer ce code au besoin.

Ma BD a des tables liees dans SQL server.

Ma question est : connaissez vous un moyen pour empecher le time out sans toucher au parametrage de la connexion.

A+

24/10/2018, 22h52
Invité

Bonsoir,
Regardes si tu trouves ce que tu cherches dans cette source.

Mais je modifie le time out !

https://www.developpez.net/forums/d1...a/#post9283354
25/10/2018, 13h00
marot_r

Merci dysorthographie.

Cela ressemble a ce que je fais actuellement, mais je note qu'on peut modifier localement le time out.
A priori je n'aurai pas le droit de le faire mais c'est bon a savoir.

A+
25/10/2018, 15h17
Invité

Bonjour,
Ceci dit vérifies le time out local de ta connexion rien ne dit quelle soit a une second????

De toutes les façons ça ne modifiera pas les limites imposées par le serveur.

Après tout 1000/1000 ça fait 1 seconde!
25/10/2018, 16h33
marot_r

Bonjour.

J'ai quand meme toute une minute, pas seulement 1s de time out. C'est deja assez contraignant comme cela.

il semblerai que le time out ne se manifeste que sur les stored proc de type "select".
Si j'execute un calcul qui ne retourne rien, j'ai pu le depasser sans probleme.
Je suis en train de valider avec un GROS paquet de mes donnees pour voir si cela tient la charge mais il semblerai que j'ai trouve une piste de contournement de mon probleme.

A+
26/10/2018, 00h08
Invité

Par défaut je pense que le time out d'adodb est entre 10 et 60 millisecondes, donc tu pourrais accessoirement le fixer à 60 000.
26/10/2018, 13h17
marot_r

Bonjour.

Comme je l'ai dit, je ne peux pas toucher (directement) au time out. Cela m'est explicitement interdit.

A par cela c'est vraiment etrange.

J'avais un message d'erreur fictif, juste pour faire du debugage, dans ma procedure stockee.
Je l'ai enleve => Time out a environ 5mn.
Je l'ai remis => Erreur d'execution au bout de 20mn environ mais pas de time out.
On dirait que l'affichage de l'erreur maintient la conversation entre SQL et Access et que cela empeche le time out.

Je continue mon exploration.

A+

Bonjour.

Il semblerai que l'execution asynchrone resolve mon probleme :

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
Public Sub ExecuteExecAsynchronic(prmStoredProcName As String, ParamArray prmStoredProcParam() As Variant)
    'Call a store procedure executing something
    ' Do not wait SQL, but wait in Access
    Dim storedProcConnection As New ADODB.Connection
    Call storedProcConnection.Open("MaBD")
    
    Dim execCmd As String
    Dim execParam As String
    
    Dim p As Variant: For Each p In prmStoredProcParam
        If execParam <> "" Then
            execParam = execParam & ", "
        End If
    
        execParam = execParam & p
    Next p
    
    Dim db As DAO.Database: Set db = CurrentDb
    execCmd = db.QueryDefs(prmStoredProcName).SQL & " " & execParam
    db.Close: Set db = Nothing
    
    Dim cmd As New ADODB.Command
    
    With cmd
        .ActiveConnection = storedProcConnection
        .CommandText = execCmd
        .CommandType = adCmdText
        .Execute , , adAsyncExecute 'Do not wait MS SQL
    End With
    
    Do While cmd.State = adStateExecuting 'Wait until MS SQL says it has finished
        DoEvents
    Loop    
    Set cmd = Nothing
        
    Call storedProcConnection.Close:  Set storedProcConnection = Nothing
End Sub

J'ai pu calculer 5000 resultats en environ 1h sans que mon appli Access plante.

A+

29/10/2018, 13h15
marot_r

Bonjour a tous.

Le traitement asynchrone est ce que je cherchais.

A+
29/10/2018, 14h03
Invité

bonjour,

bon à savoir je n'y aurais pas pensé!
30/10/2018, 15h33
marot_r

Bonjour a tous.

Surprise (désagréable) ma super solution ne fonctionnait plus ce matin.

Apres plusieurs essais, j'ai découvert qu'il fallait que j'ajoute 0 ma procédure stockée MS SQL Server:

Code:

SET @msg = 'Ici in message'; RAISERROR(@msg, 0, 1) WITH NOWAIT; -- Has to be there to prevent time-out on Access.

Sinon Access time out pareil.

J'avais mis ces messages en commentaire car ils servaient uniquement au debuggage, du moins je le croyais.

A+