Problème comparaison de nombre

Version imprimable

22/09/2018, 22h21
sk8r's

Problème comparaison de nombre

Bonsoir,
Je vous expose mon problème. Je n'arrive pas à comparer deux nombre dans le cadre d'une boucle if.
Le but de mon programme est de créer plusieurs dossier ainsi que sous dossier en fonction de la demande de l'utilisateur.
En vous remerciant pour votre futur aide.

_____Programme______
mkdir dossier\3A
mkdir dossier\4A
mkdir dossier\5A
set /p variable_3a=Nombre eleve en 3A ?
set /p variable_4a=Nombre eleve en 4A ?
set /p variable_5a=Nombre eleve en 5A ?
set /a compteur=0
echo la valeur de notre variable est %variable_3a%
echo %compteur%
pause
if /i %compteur% LSS %variable_3a%
(
echo je suis dans la boule for
mkdir dossier\3A\eleve%compteur%
set /a compteur+=1
pause
)
set /a compteur=0

if /i %compteur% LSS %variable_4a%
(
echo je suis dans la boule for
mkdir dossier\3A\eleve%compteur%
set /a compteur+=1
pause
)
set /a compteur=0

if /i %compteur% LSS %variable_5a%
(
echo je suis dans la boule for
mkdir dossier\3A\eleve%compteur%
set /a compteur+=1
pause
)
set /a compteur=0

Bonjour,

On peut simplifier tout cela avec l'utilisation de 2 boucles FOR :

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
@echo off
setlocal enableextensions enabledelayedexpansion
chcp 1252 >nul

:: _____Programme______

for %%E in (3A 4A 5A) do (
	if not exist "dossier\%%E" (mkdir dossier\%%E)
	
	cls & set /p variable_%%E="Nombre d'élèves en %%E ? "
	echo Le nombre d'élèves en %%E est !variable_%%E!
	echo.

	for /L %%F in (1,1,!variable_%%E!) do (	
		if not exist "dossier\%%E\eleve_%%F" (
		mkdir "dossier\%%E\eleve_%%F"
		echo ### élève_%%F ==^>^> dossier créé
		)
	)
	echo. & pause
)

De cette façon il n'y a plus besoin de comparer 2 nombres.

23/09/2018, 11h45
sk8r's

merci beaucoup de votre aide mon problème est résolue