Modifier quelques valeurs dans fichier ini

Version imprimable

05/07/2018, 15h02
Minus63

Modifier quelques valeurs dans fichier ini

Bonjour à tous

J'ai plus l'habitude des scripts linux, j'ai fait quelques scripts simples en batch mais la je me retrouve face à un mur notamment avec l'utilisation de FOR que je n'arrive pas à utiliser.

Voila mon besoin:

J'ai un fichier ini qui en finalité doit contenir ces 4 lignes comme cela (en plus de celles déjà présentes, le fichier ne contient pas que ces lignes la):

broadcastsearch = 0
aggressive = 0
serversearchinterval = 30
serveraddr = server.licenses.domain.lan

Hors

broadcastsearch et aggressive peuvent être en valeur = 1
(1 étant activé et 0 étant désactivé)
serversearchinterval peut être en valeur différente de 30
et serveraddr peut être renseigné ou non

Le script a donc pour but de renseigner les 4 lignes comme il faut.

Je crée bien un fichier de travail temporaire, je renseigne bien toutes les variables utilisables, mais quand il s'agit de trouver le texte dans le fichier et modifier les paramètres, la je coule.

Si une âme charitable pouvait m'aider, j'apprécierai et apprendrai par la même occasion

Par avance merci

Une première approche pour commencer

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
@echo off
 
set broadcastsearch=a
set aggressive=b
set serversearchinterval=c
set serveraddr=d
 
(FOR /F "tokens=* delims=" %%a in (toto.ini) do echo %%a|find /i "broadcastsearch =">nul&&echo broadcastsearch = %broadcastsearch%||(
echo %%a|find /i "aggressive = ">nul&&echo aggressive = %aggressive%||(
echo %%a|find /i "serversearchinterval =">nul&&echo serversearchinterval = %serversearchinterval%||(
echo %%a|find /i "serveraddr =">nul&&echo serveraddr = %serveraddr%
))) || echo %%a)>toto.tmp
del toto.ini
ren toto.tmp toto.ini
 
pause

06/07/2018, 09h53
Minus63

Bonjour et merci beaucoup ça fonctionne

Il ne me reste plus maintenant qu'à ajuster le script pour qu'il aille chercher le fichier ini en écrivant l'arborescence complète
06/07/2018, 10h26
Minus63

Bon ben le script part en vrille dés que je rentre le chemin complet d'accès au fichier ini

J'ai essayé en l'écrivant en dur comme via des variables, et le fichier ini obtenu ne contient que le résultat des differentes actions de recherche du script.
07/07/2018, 10h50
ericlm128

Montre ton script complet avec le chemin

Bonjour

Voilà ce que j'utilise

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
@echo off

set ini_file="C:\Program Files (x86)\Common Files\Aladdin Shared\HASP\hasplm.ini"
 
set broadcastsearch=0
set aggressive=0
set serversearchinterval=30
set serveraddr=server.licenses.domain.lan
 
(FOR /F "tokens=* delims=" %%a in (%ini_file%) do echo %%a|find /i "broadcastsearch =">nul&&echo broadcastsearch = %broadcastsearch%||(
echo %%a|find /i "aggressive = ">nul&&echo aggressive = %aggressive%||(
echo %%a|find /i "serversearchinterval =">nul&&echo serversearchinterval = %serversearchinterval%||(
echo %%a|find /i "serveraddr =">nul&&echo serveraddr = %serveraddr%
))) || echo %%a)>"C:\Program Files (x86)\Common Files\Aladdin Shared\HASP\initmp.txt"
del %ini_file%
ren "C:\Program Files (x86)\Common Files\Aladdin Shared\HASP\initmp.txt" hasplm.ini
 
pause

Je suis sur qu'il y a quelque chose qui m'échappe...

Merci pour ton aide

Voici quelques modifications

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
@echo off
 
set ini_file=C:\Program Files (x86)\Common Files\Aladdin Shared\HASP\hasplm.ini
 
set broadcastsearch=0
set aggressive=0
set serversearchinterval=30
set serveraddr=server.licenses.domain.lan
 
(FOR /F "tokens=* usebackq delims=" %%a in ("%ini_file%") do echo %%a|find /i "broadcastsearch =">nul&&echo broadcastsearch = %broadcastsearch%||(
echo %%a|find /i "aggressive = ">nul&&echo aggressive = %aggressive%||(
echo %%a|find /i "serversearchinterval =">nul&&echo serversearchinterval = %serversearchinterval%||(
echo %%a|find /i "serveraddr =">nul&&echo serveraddr = %serveraddr%
))) || echo %%a)>"%ini_file%.tmp"
del "%ini_file%"
for /F "tokens=* delims=" %%a in ("%ini_file%") do set ini_file_name=%%~nxa
ren "%ini_file%.tmp" "%ini_file_name%"
 
pause

09/07/2018, 10h31
Minus63

merci

ca ne fonctionne pas car la il me fait une erreur

Code:

/Common était inattendu
09/07/2018, 10h39
ericlm128

A oui excuse moi, j'ai oublié d'enlever les "

J'ai modifié le code précédent
09/07/2018, 10h48
Minus63

re

C'est nickel ça fonctionne. :hola:

sur une déclaration variable il faut enlever les " ?

Par contre une petite explication de texte sur le script me ferai du bien

notamment sur

ligne 10: FOR /F "tokens=* usebackq delims=" %%a in ("%ini_file%") do echo %%a
et
ligne 16: for /F "tokens=* delims=" %%a in ("%ini_file%") do set ini_file_name=%%~nxa
09/07/2018, 11h15
ericlm128

Citation:

sur une déclaration variable il faut enlever les " ?

Non pas forcément, cela dépend de si tu veux que les " soit dans la variable ou pas

Citation:

ligne 10: FOR /F "tokens=* usebackq delims=" %%a in ("%ini_file%") do echo %%a

Les espaces sont souvent un/le problème comme dans ton cas.
usebackq permet de lire un fichier "%ini_file%" en utilisant les " et permet de résoudre les problèmes d'espaces potentiels.
for /? pour plus d'informations

Citation:

ligne 16: for /F "tokens=* delims=" %%a in ("%ini_file%") do set ini_file_name=%%~nxa

La commande ren accepte uniquement un nom de fichier en deuxième paramètre et non pas un chemin complet.
Cette ligne permet de le récupérer/extraire
09/07/2018, 13h58
Minus63

merci beaucoup pour tes explications

Problème résolu