interface réseau Ethernet en assembleur

j'ai rien pour piloter l'Ethernet directement mais je ma suis fait une biblio pour UDP et TCP sous Windows:
Code:
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
;******************************************************************
 
net_init:
pushad
push dword WSADATA
push dword 101h       ;version de winsock a initialiser (1.1 ici)
call	[WSAStartup]  ;initialisation de winsock
 
ss
mov [esp+28],eax   ;préserve eax
popad
ret
 
;********************
net_ecoute_tcp:    ;ouvre un port TCP en écoute
;entrée        bx=numéros de port
;              edx=adresse de l'inteface sur laquel ouvrir le port ou adresse ip null (edx=0), pour ouvrir le port sur toutes les interface réseau
;sortie        eax=code d'erreur ebx=handle du nouveau port
 
pushad
mov word[addr_ip],2
mov [addr_ip+2],bh
mov [addr_ip+3],bl
 
mov [addr_ip+4],edx  ;adresse ip
xor ebx,ebx
mov [addr_ip+8],ebx  ;zone toujour nul
mov [addr_ip+12],ebx  ;zone toujour nul
 
;ouverture et configuration du port
push dword 6       ;protocol 1=icmp(pour ipv4) 6=tcp 17=udp 58=icmp(pour ipv6)
push dword 1   ;type de transmission (1 pour tcp et 2 pour udp)
push dword 2   ;adresse family 2=IPV4 23=IPV6
call [socket]  ;crée un socket
cmp eax,-1
je net_erreur 
 
mov ebx,eax
 
push dword 16
push dword addr_ip 
push ebx
call [bind]      ;definit l'adresse du socket
cmp eax,0
jne net_erreur
 
push dword 100     ;nombre de connexion maximum
push ebx
call [listen]      ;met le socket en mode écoute
cmp eax,0
jne net_erreur
 
mov dword[dword_temporaire],1 
push dword dword_temporaire  ;point sur un dword a 1
push dword 8004667Eh         ;commande "FIONBIO"
push ebx
call [ioctlsocket]  ;passe le socket en "non blocking mode"
cmp eax,0
jne net_erreur
 
ss
mov [esp+16],ebx  ;préserve ebx
popad
xor eax,eax
ret
 
 
 
 
net_erreur:
call [WSAGetLastError]
ss
mov [esp+16],eax  ;modifie ebx dans la pile
popad
mov eax,1
ret
 
 
;********************
net_connexion_tcp:    ;ouvre une connexion vers un port TCP
;entrée        bx=numéros de port source
;              cx=port de destination
;              edx=adresse de desitnation
;sortie        eax=code d'erreur ebx=handle du nouveau port
 
pushad
 
mov word[addr_ip],2
mov [addr_ip+2],bh
mov [addr_ip+3],bl
xor ebx,ebx
mov [addr_ip+4],ebx  ;adresse ip null, pour ouvrir le port sur toutes les interface réseau sinon spécifier l'adresse de la seule carte qui doit ouvrir le port
mov [addr_ip+8],ebx   ;zone toujours nul
mov [addr_ip+12],ebx  ;zone toujours nul
 
mov word[addr_ip2],2
mov [addr_ip2+2],ch
mov [addr_ip2+3],cl
mov [addr_ip2+4],edx  
xor ebx,ebx
mov [addr_ip2+8],ebx   ;zone toujours nul
mov [addr_ip2+12],ebx  ;zone toujours nul
 
 
 
;ouverture et configuration du port
push dword 6   ;protocol 1=icmp(pour ipv4) 6=tcp 17=udp 58=icmp(pour ipv6)
push dword 1  ;type de transmission (1 pour tcp et 2 pour udp)
push dword 2   ;adresse family 2=IPV4 23=IPV6
call [socket]  ;crée un socket
cmp eax,-1
je net_erreur 
 
mov ebx,eax
 
push dword 16
push dword addr_ip 
push ebx
call [bind]      ;definit l'adresse du socket
cmp eax,0
jne net_erreur
 
 
mov dword[dword_temporaire],16
push dword dword_temporaire  ;zone de 16
push dword addr_ip2           ;adresse de la connexion
push ebx
call [connect]
cmp eax,0
jne net_erreur
popad
xor eax,eax
ret
 
 
 
 
 
;********************
net_test_nvc:   ;test si une nouvelle connexion est disponible
 
pushad
mov dword[dword_temporaire],16
push dword dword_temporaire  ;zone de 16
push dword addr_ip          ;adresse de la connexion
push ebx
call [accept]
cmp eax,-1
je erreur_nouv_connexion
 
ss
mov [esp+16],eax  ;modifie ebx dans la pile
popad
mov eax,1
ret
 
erreur_nouv_connexion:
call [WSAGetLastError]
cmp eax,10035   ;code d'erreur "WSAEWOULDBLOCK"
je aucune_nouv_connexion
 
ss
mov [esp+16],eax  ;modifie ebx dans la pile
popad
mov eax,2
ret 
 
aucune_nouv_connexion:
popad
xor eax,eax
xor ebx,ebx
ret 
 
 
 
;********************
net_lire_port_tcp:           ;recevoir données sur port tcp
;entrée
;ecx=quantité a reçevoire
;edi=zone ou ecrire les données
;ebx= handle du port a lire
;sortie
;ecx=nombre de données données lut
 
pushad
 
push ebx
push ecx
push edi
mov dword[dword_temporaire],1 
push dword dword_temporaire  ;point sur un dword a 1
push dword 8004667Eh         ;commande "FIONBIO"
push ebx
call [ioctlsocket]  ;passe le socket en "non blocking mode"
pop edi
pop ecx
pop ebx
cmp eax,0
jne erreur_lire_port
 
push dword 0
push ecx
push edi
push ebx
call [recv]
cmp eax,-1
je erreur_lire_port
 
ss
mov [esp+24],eax  ;modifie ecx dans la pile
popad
xor eax,eax
xor ebx,ebx
ret
 
 
erreur_lire_port:
call [WSAGetLastError]
cmp eax,10035   ;code d'erreur "WSAEWOULDBLOCK"
je aucune_donnee_lut
 
ss
mov [esp+16],eax  ;préserve ebx
popad
mov eax,2
ret 
 
aucune_donnee_lut:
popad
xor eax,eax
xor ecx,ecx
ret 
 
 
 
 
 
 
;********************
net_ecrire_port_tcp:
;envoyer données
;ecx=quantité a envoyer
;esi=zone ou se trouve les données a envoyer
;ebx=handle du port a lire
 
pushad
 
push ebx
push ecx
push esi
mov dword[dword_temporaire],0 
push dword dword_temporaire  ;point sur un dword a 0
push dword 8004667Eh         ;commande "FIONBIO"
push ebx
call [ioctlsocket]  ;passe le socket en "blocking mode"
pop esi
pop ecx
pop ebx
cmp eax,0
jne erreur_lire_port
 
push dword 0
push ecx
push esi
push ebx
call [send]
cmp eax,-1
je erreur_lire_port
 
ss
mov [esp+24],eax  ;modifie ecx dans la pile
popad
xor eax,eax
ret
 
 
;*********************************************************************************
net_ouvre_port_udp:
;entrée        bx=numéros de port
;              ebp=adresse de l'inteface sur laquel utiliser le port ou adresse ip null (ebp=0), pour ouvrir le port sur toutes les interface réseau
;sortie        eax=code d'erreur ebx=handle du nouveau port
 
pushad
mov word[addr_ip],2
mov [addr_ip+2],bh
mov [addr_ip+3],bl
 
mov [addr_ip+4],ebp  ;adresse ip
xor eax,eax
mov [addr_ip+8],eax  ;zone toujour nul
mov [addr_ip+12],eax  ;zone toujour nul
 
;ouverture et configuration du port
push dword 17       ;protocol 1=icmp(pour ipv4) 6=tcp 17=udp 58=icmp(pour ipv6)
push dword 2   ;type de transmission (1 pour tcp et 2 pour udp)
push dword 2   ;adresse family 2=IPV4 23=IPV6
call [socket]  ;crée un socket
cmp eax,-1
je net_erreur 
 
push eax
push dword 16
push dword addr_ip 
push eax
call [bind]      ;definit l'adresse du socket
pop ebx
cmp eax,0
jne net_erreur
 
push ebx
mov dword[dword_temporaire],1 
push dword 1
push dword dword_temporaire  ;point sur un dword a 1
push dword 32  ;nom de l'option 32=SO_BROADCAST
push dword 0FFFFh ;niveau SOL_SOCKET
push ebx
call [setsockopt]
pop ebx
cmp eax,0
jne net_erreur
 
ss
mov [esp+16],ebx  ;modifie ebx dans la pile
popad
xor eax,eax
ret
 
 
;****************************************************
net_lire_port_udp:           ;recevoir données sur port udp
;entrée
;ecx=quantité a reçevoire
;edi=zone ou ecrire les données
;ebx= handle du port a lire
;sortie
;ecx=nombre de données données lut
;edx=port ip d'origine de la trame
;ebp=adresse ip d'origine de la trame
 
pushad
 
push ebx
push ecx
push edi
mov dword[dword_temporaire],1 
push dword dword_temporaire  ;point sur un dword a 1
push dword 8004667Eh         ;commande "FIONBIO"
push ebx
call [ioctlsocket]  ;passe le socket en "non blocking mode"
pop edi
pop ecx
pop ebx
cmp eax,0
jne erreur_lire_port
 
mov dword[dword_temporaire],16
push dword dword_temporaire  ;zone de 16
push dword addr_ip          ;adresse de la connexion
push dword 0
push ecx
push edi
push ebx
call [recvfrom]
cmp eax,-1
je erreur_lire_port
 
 
ss
mov [esp+24],eax  ;modifie ecx dans la pile
xor eax,eax
mov ah,[addr_ip+2]
mov al,[addr_ip+3]
ss
mov [esp+20],eax  ;modifie edx dans la pile
mov eax,[addr_ip+4]
ss
mov [esp+8],eax  ;modifie ebp dans la pile
 
popad
xor eax,eax
ret
 
 
;********************************
net_ecrire_port_udp:
;dx= numéros de port
;ebp=adresse
;ecx=quantité a envoyer
;esi=zone ou se trouve les données a envoyer
;ebx=handle du port a lire
 
pushad
 
mov word[addr_ip],2
mov [addr_ip+2],dh
mov [addr_ip+3],dl
 
mov [addr_ip+4],ebp  ;adresse ip
xor eax,eax
mov [addr_ip+8],eax  ;zone toujour nul
mov [addr_ip+12],eax  ;zone toujour nul
 
push ebx
push ecx
push esi
mov dword[dword_temporaire],0 
push dword dword_temporaire  ;point sur un dword a 0
push dword 8004667Eh         ;commande "FIONBIO"
push ebx
call [ioctlsocket]  ;passe le socket en "blocking mode"
pop esi
pop ecx
pop ebx
cmp eax,0
jne net_erreur
 
 
mov dword[dword_temporaire],16
push dword dword_temporaire  ;zone de 16
push dword addr_ip          ;adresse de la connexion
push dword 0
push ecx
push esi
push ebx
call [sendto]
cmp eax,-1
je net_erreur
 
popad
xor eax,eax
xor ebx,ebx
ret