Plusieurs conditions avec ElseIf - problème

Version imprimable

Bonjour,

Je cherche à attribuer une valeur « oui » ou « non » dans la colonne U par rapport à la valeur de la cellule de la colonne B.
Par contre, je voudrais appliquer 2 conditions dans « ElseIf ActiveCell.Value = "Gestion" And ActiveCell.Offset(0, 3).Value = "" » mais j’ai un message d’erreur incompatibilité de type.

Pouvez-vous m’expliquer pourquoi ?

Le code complet ci-dessous :
Code:

1 2 3 4 5 6 7 8 9 10 11 12 13 Range("B1").Select Range(Selection, Selection.End(xlDown)(0)).Select For Each cell In Selection X = X + 1 ActiveCell.Offset(1, 0).Select If ActiveCell.Value = "Inv" Then ActiveCell.Offset(0, 19).Value = "non" ElseIf ActiveCell.Value = "Gestion" And ActiveCell.Offset(0, 3).Value = "" Then ActiveCell.Offset(0, 19).Value = "non" Else ActiveCell.Offset(0, 19).Value = "oui" End If Next
Merci par avance

Bonjour Roulax (et bienvenu sur le Forum)

Ouh là!

- Balises code pour reporter le code dans la discussion
- Déclaration des variables
- A quoi sert X?
- Ces p... de Select qui ne servent à rien

Essaie cela.
Pour ce faire, regarde toutes les méthodes et propriétés utilisées
Comprends par tous les moyens et reviens si nécessaire

(J'ai volontairement passé outre la méthode If)

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
Option Explicit
 
Public Sub montest_Marcel()
 
Dim c As Range
Dim derlign As Long ' à adapter
 
With Worksheets(1)
      derlign = .Cells(.Rows.Count, 2).End(xlUp).Row
      For Each c In .Range("B1:B" & derlign)
            With c
                  Select Case .Value
                        Case "Inv"
                              .Offset(0, 19).Value = "non"
                        Case "Gestion"
                              .Offset(0, 19).Value = IIf(.Offset(0, 3).Value = "", "non", "oui")
                  End Select
            End With
      Next c
End With
 
End Sub

bonjour

Code:

1
2
3
4
5
6
Select Case .Value
                        Case "Inv",""
                              .Offset(0, 19).Value = "non"
                        Case "Gestion"
                              .Offset(0, 19).Value = "oui" 
End Select

22/06/2018, 15h56
MarcelG

Bonjour,

Sauf erreur, il y une condition sur la cellule

Code:

.Offset(0,3)

Non?

Salut

Je dirais même

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
            With c
                'Soit initialiser à "oui"
                '.Offset(0, 19).Value = "oui"
                Select Case .Value
                    Case "Inv"
                        .Offset(0, 19).Value = "non"
                    Case "Gestion"
                        .Offset(0, 19).Value = IIf(.Offset(0, 3).Value = "", "non", "oui")
                    'Soit ajouter un Else
                    Case Else
                        .Offset(0, 19).Value = "oui"
                End Select
            End With

Le Select Case à l'avantage (je trouve) de pouvoir être modifié rapidement mais si tu veux garder ta structure If...else...

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
Public Sub montest_Marcel()
 
Dim CellInB As Range
 
    'On pointe la 1ère feuille du classeur
    With Worksheets(1)
        'On boucle sur les cellules de la colonne B, de B1 à la dernière cellule non vide en partant du bas de la feuille
        For Each CellInB In .Range("B1", .Cells(.Rows.Count, "B").End(xlUp))
            'On pointe la cellule
            With CellInB
                'On regarde les conditions du "non"
                If (.Value = "Inv") Or ((.Value = "Gestion") And (.Offset(0, 3).Value = "")) Then
                    .Offset(0, 19).Value = "non"
                Else
                    .Offset(0, 19).Value = "oui"
                End If
            End With
        Next
    End With
 
End Sub

Par contre j'attire ton attention sur les comparaison de chaine, la comparaison que tu fais en écrivant Cellule.value= "Inv" est sensible à la case et donc si la cellule contient "inv", la comparaison retournera un False.
Tu as plusieurs choix possibles pour éviter ce type de problème, en voici deux

tu passes la chaine contenu dans la cellule en minuscule (ou en majuscule) au moment du teste

Code:

LCase(Cellule.value) = "inv"
tu utilises la fonction StrComp

Code:

strcomp(cellule.value,"Inv",vbTextCompare) = 0

++
Qwaz

25/06/2018, 13h24
roulax

Merci pour vos réponses.
Problème résolu