Bug sur For each avec une Range()

Version imprimable

Salut à tous,

J'ai une plage de donnée plage1 qui regroupe toutes les cellules de M2 à M65536. Sur celle ci j'effectue un test sur le contenue de la cellule pour voir si il est égale a "true" ou "false".
Ensuite en fonction du résultat j'effectue une opération quelconque.

Sans que le formulaire d'affichage soit fermé, les donnés de ma plage sont modifié, une valeur passe de "true" a "false".
Toujours sans fermer mon formulaire, je réitère sur ma plage de donné une For Each mais je remarque que les données séléctionnées par celle-ci sont mainteant de M1 à M2 or je ne l'ai jamais modifier !

Une idée ?

Merci !

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
Set plage1 = Sheets("journal").Range("M2:M" & [A65536].End(xlUp).Row)
 
        Number_risky = 0
        top_risky = 5
        For Each Cell In plage1
 
            MsgBox Cell.Value
 
            If Cell.Value = "false" Then
 
                'On créé les éléments
                Set action_name_frame = risked_position_frame.Controls.Add("Forms.Label.1", "ok" & Number_risky, True)
                Set action_ticker_isin_frame = risked_position_frame.Controls.Add("Forms.Label.1", "ok" & Number_risky, True)
                Set action_numbers_frame = risked_position_frame.Controls.Add("Forms.Label.1", "ok" & Number_risky, True)
                Set action_entry_date_frame = risked_position_frame.Controls.Add("Forms.Label.1", "ok" & Number_risky, True)
                Set action_buying_price_frame = risked_position_frame.Controls.Add("Forms.Label.1", "ok" & Number_risky, True)
                Set action_total_investing_frame = risked_position_frame.Controls.Add("Forms.Label.1", "ok" & Number_risky, True)
 
                'on positionne les éléments créés
                action_name_frame.Caption = Cell.Offset(0, -12).Value
                action_name_frame.top = top_risky
                action_name_frame.Left = 20
                action_name_frame.Width = 100
 
                action_ticker_isin_frame.Caption = Cell.Offset(0, -11).Value
                action_ticker_isin_frame.top = top_risky
                action_ticker_isin_frame.Left = 162
 
                action_numbers_frame.Caption = Cell.Offset(0, -9).Value
                action_numbers_frame.top = top_risky
                action_numbers_frame.Left = 256
 
                action_entry_date_frame.Caption = Cell.Offset(0, -7).Value
                action_entry_date_frame.top = top_risky
                action_entry_date_frame.Left = 354
 
                action_buying_price_frame.Caption = Cell.Offset(0, -8).Value & "€"
                action_buying_price_frame.top = top_risky
                action_buying_price_frame.Left = 456
 
                action_total_investing_frame.Caption = Cell.Offset(0, -9).Value * Cell.Offset(0, -8).Value & "€"
                action_total_investing_frame.top = top_risky
                action_total_investing_frame.Left = 558
 
                top_risky = top_risky + 19
                Number_risky = Number_risky + 1
 
            End If
        Next Cell
 
        number_of_risked_position_frame.Caption = "Trade(s) à risque: " & Number_risky & "/7"

19/06/2018, 17h32
jbrichez

Citation:

Envoyé par pijaku

Salut

[A65536].End(xlUp).Row te retourne la dernière ligne saisie en colonne A. Si cette ligne est 1, ton Range devient M2:M1.

Merci beaucoup pour votre réponse, cependant mes cellules sont remplis jusqu’à la ligne 10 ...
19/06/2018, 17h33
pijaku

Salut

[A65536].End(xlUp).Row te retourne la dernière ligne saisie en colonne A. Si cette ligne est 1, ton Range devient M2:M1.

En colonne A???
19/06/2018, 17h41
jbrichez

1 pièce(s) jointe(s)

Voila ma feuille:
Pièce jointe 389779
19/06/2018, 17h53
pijaku

Essaye :

Code:

Set plage1 = Sheets("journal").Range("M2:M" & Sheets("journal").Range("A65536").End(xlUp).Row)
19/06/2018, 17h59
jbrichez

Cela fonctionne parfaitement ! Est-ce que je peu avoir des explications quant a son fonctionnement ?
19/06/2018, 20h56
pijaku

Je te ferai un topo demain à ce sujet.
En attendant, ferme cette discussion en cliquant sur "résolu".
Bonne soirée

Bonjour,

Lorsque tu utilises [A65536].End(xlUp).Row sans préfixer la feuille, tu cherches la dernière cellule remplie de la colonne A de la feuille active.
Si tu préfixe une feuille, grâce à la syntaxe : Sheets("journal").Range("A65536").End(xlUp).Row, tu es sur d'agir sur la feuille concernée.

L'écriture Range("A65536").End(xlUp) correspond à la combinaison de touches CTRL+Flèche du haut.
En fait, tu commences à la cellule A65536 et remonte (xlUp) ainsi jusqu'à la dernière (End) cellule saisie.

Remarques :
Depuis Excel 2007, il vaut mieux utiliser la syntaxe : Sheets("journal").Cells(Rows.Count, 1).End(xlUp).Row ou le 1 représente la colonne (ici A).
La syntaxe avec les crochets [], est une simplification d'écriture utilisant la méthode Evaluate. Ainsi [A1] est identique à Range("A1").
A titre personnel, je n'utilise pas la syntaxe End(xlUp), mais y préfère la méthode Find.
Celle-ci est , en effet, plus généraliste et permet, entres autres, de ne pas se méfier d'éventuelles lignes masquées.
A ce titre, j'utilise la fonction suivante :
Code:

1 2 3 4 5 6 Private Function derlig_reelle(plage As Range) As Long 'cas d'absence de données dans la plage à traiter : If WorksheetFunction.CountA(plage) = 0 Then derlig_reelle = plage.Cells(1, 1).Row: Exit Function 'dans tous les autres cas : derlig_reelle = plage.Find("*", , , , , xlPrevious).Row End Function
Que tu peux appeler comme ceci :
Code:

1 2 3 4 5 6 7 8 'Dernière ligne réelle d'une colonne : MsgBox derlig_reelle(Worksheets("Feuil1").Columns(1)) MsgBox derlig_reelle(Worksheets("Feuil1").Columns("A")) MsgBox derlig_reelle(Worksheets("Feuil2").Range("B:B")) 'Dernière ligne réelle d'une plage de cellules : MsgBox derlig_reelle(Worksheets("Feuil1").Range("A10:G153")) 'Dernière ligne réelle d'une feuille : MsgBox derlig_reelle(Sheets("Feuil3").Cells)
Voilà voilà
Bonne journée