Recherche dans un textBox et afficher le resultat dans une listBox

Version imprimable

Voir 40 message(s) de cette discussion en une page

07/06/2018, 15h39
El tigre

1 pièce(s) jointe(s)

Recherche dans un textBox et afficher le resultat dans une listBox

Bonjour tout le monde,

Je viens tous juste d'intégrer le forum et je vous remercie d'avance pour votre aide. Je vous sollicite car j’ai un projet à rendre d’ici lundi et je n’arrive toujours pas à avancer.
-Lorsque que je sélectionne une feuille , j’aimerai effectuer une recherche dans le textBox, et que les résultats apparaissent dans la listbox, pour que je puisse par la suite supprimer ou modifier la ligne.
Mais je n’arrive pas à trouver le code qui me permettrai d’afficher le résultat dans la listBox, si vous pourriez m’aider à avancer s’il vous plait:( :( .
Je vous met en pièce jointe le fichier pour comprendre , si ce n’est pas clair n’hésitez pas à me demander.
Biens à vous
07/06/2018, 17h03
Transitoire

Bonjour, j'ai jeté un oeil rapide sur votre dossier, mais il n'y a pas plus de clarté dans le dossier que dans vos explications. il serait bon que vous expliquiez mieux, si vous souhaitez être aidé!
Cordialement 8-)
08/06/2018, 13h42
El tigre

Actuellement, mon textboxChercher n’est pas active car je n’arrive pas à effectuer de recherche. Mon but est que lorsque je tape dans textboxChercher Benois, par exemple , j’ai son nom son prénom son sexe et son mail qui apparait dans la listBoxResultat et ainsi de suite....

Bonjour,

Alors 2 méthodes :

Soit on demande à la listbox de créer un nombre de colonne et d'y ajouter les données en fonction du tableau.
Soit on ajoute le texte correspondant avec des "&"

Pour plus de souplesse sur l'extraction des données par exemple, j'ai choisi la première.
Met ce code :

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
Private Sub TextBoxChercher_Change()
 
    Dim ligne As Integer
    Dim nbLigne As Integer
    Dim dercol As Integer
    Dim i As Byte
 
    Application.ScreenUpdating = False
    ListBoxResultat.Clear
    nbLigne = WorksheetFunction.CountA(Range("A:A"))
 
    If TextBoxChercher <> "" Then
        For ligne = 2 To nbLigne
            If Cells(ligne, 1) Like "*" & TextBoxChercher & "*" Then
 
                dercol = Cells(1, Cells.Columns.Count).End(xlToLeft).Column 'on détecte la dernière colonne
                ListBoxResultat.ColumnCount = dercol 'on adapte le nombre de colonne
 
                ListBoxResultat.AddItem Cells(ligne, 1)
                For i = 1 To dercol 'On boucle sur les données
                ListBoxResultat.List(ListBoxResultat.ListCount - 1, i) = Cells(ligne, i)
                Next i
 
            End If
        Next
    End If
End Sub

A lire sur le fonctionnement d'une listbox (très bon chapitre) : https://silkyroad.developpez.com/VBA...serForm/#LII-G

08/06/2018, 15h27
El tigre

Ah super, c'est exactement ce que je recherchais:lol::lol: Merci beaucoup
08/06/2018, 15h54
El tigre

Le soucis est que le code ne s'adapte pas pour toutes les feuilles, et la premere colonne apparait deux fois, je ne sais pas pourquoi

Citation:

Envoyé par El tigre

Le soucis est que le code ne s'adapte pas pour toutes les feuilles, et la premere colonne apparait deux fois, je ne sais pas pourquoi

Il ne s'adapte pas car aucune feuille n'est indiqué. La recherche de plage se fait donc sur la feuille active.
Pour le soucis de donnée ListBox, il suffit juste de modifier l'ajout comme ceci : ListBoxResultat.List(ListBoxResultat.ListCount - 1, i) = Sheets(NomFeuille).Cells(ligne, i + 1) --> On lui indique de prendre la colonne d'après

J'ai modifier le code. Pense à réactiver ton Application.ScreenUpdating à la fin

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
Private Sub TextBoxChercher_Change()
 
    Dim ligne As Integer
    Dim nbLigne As Integer
    Dim dercol As Integer
    Dim i As Byte
    Dim NomFeuille As String
 
    Application.ScreenUpdating = False
    ListBoxResultat.Clear
    NomFeuille = ComboBoxChoix2
    nbLigne = Sheets(NomFeuille).Range("A65536").End(xlUp).Row
 
    If NomFeuille = "" Then Exit Sub
 
    If TextBoxChercher <> "" Then
        For ligne = 2 To nbLigne
            If Sheets(NomFeuille).Cells(ligne, 1) Like "*" & TextBoxChercher & "*" Then
 
                dercol = Sheets(NomFeuille).Cells(1, Cells.Columns.Count).End(xlToLeft).Column 'on détecte la dernière colonne
                ListBoxResultat.ColumnCount = dercol 'on adapte le nombre de colonne
 
                ListBoxResultat.AddItem Sheets(NomFeuille).Cells(ligne, 1)
                For i = 1 To dercol 'On boucle sur les données
                ListBoxResultat.List(ListBoxResultat.ListCount - 1, i) = Sheets(NomFeuille).Cells(ligne, i + 1)
                Next i
 
            End If
        Next
    End If
 
    Application.ScreenUpdating = True
 
End Sub

Change aussi le code des combobox car si on efface une erreur apparaît

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
'''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''
'Procedure qui permet d'afficher la bonne feuille quand l utilisateur selectionne un item dans la liste de la page ajouter
'''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''
Private Sub ComboBoxChoix_Change()
    Dim sWs As String
 
    sWs = Me.ComboBoxChoix.Value
    Call ChargerListBox
    If sWs <> "" Then Worksheets(sWs).Select
 
End Sub
''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''
'Procedure qui permet d'afficher la bonne feuille quand l utilisateur selectionne un item dans la liste modifier
''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''
Private Sub ComboBoxChoix2_Change()
    Dim sWs As String
 
    sWs = Me.ComboBoxChoix2.Value
    Call ChargerListBox
 
End Sub

Et met cette procédure à la fin. C'est presque le même code que le précédent. L'avantage c'est que cela permet de charger ta ListBox dès que tu choisis ta feuille.

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
Sub ChargerListBox()
 
Dim ligne As Integer
Dim nbLigne As Integer
Dim dercol As Integer
Dim i As Byte
Dim NomFeuille As String
 
Application.ScreenUpdating = False
 
NomFeuille = ComboBoxChoix2
dercol = Sheets(NomFeuille).Cells(1, Cells.Columns.Count).End(xlToLeft).Column 'on détecte la dernière colonne
ListBoxResultat.ColumnCount = dercol 'on adapte le nombre de colonne
nbLigne = Sheets(NomFeuille).Range("A65536").End(xlUp).Row
 
'''Sheets(NomFeuille).Select 'active la feuille choisi
ListBoxResultat.Clear
For ligne = 2 To nbLigne
    ListBoxResultat.AddItem Sheets(NomFeuille).Cells(ligne, 1)
    For i = 1 To dercol 'On boucle sur les données
    ListBoxResultat.List(ListBoxResultat.ListCount - 1, i) = Sheets(NomFeuille).Cells(ligne, i + 1)
    Next i
Next ligne
 
Application.ScreenUpdating = True
 
End Sub

11/06/2018, 12h14
El tigre

salut McLister213,

C'est parfait, juste je ne comprend pas, on m'affcihe une erreur quand je l'execute :

" Could not set the list property. Invalid property value. Run time error 380"

Sais tu à quoi est ce du ?

Salut

Peux-tu préciser sur quelle ligne apparait l'erreur stp

Sinon, une proposition pour n'avoir qu'une seul procédure pour le remplissage de la liste. Il suffit de passer en paramètre le texte recherché.

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
Option Explicit
 
Private Sub Workbook_PeutImporteOu()
    'On charge le listbox avec toutes les ligne dont la cellule de la colonne A n'est pas vide
    ChargerListBox
End Sub
 
Private Sub TextBoxChercher_Change()
    'On appel la fonction de chargement de la liste
    ChargerListBox TextBoxChercher_Change.Text
 
End Sub
 
 
 
Sub ChargerListBox(Optional Match As String = "*")
'Si Match n'est pas renseigné lors de l'appel, on recherche toutes les cellules ayant un contenu "*"
Dim nbLigne As Integer
Dim DerCol As Integer
Dim iCol As Integer
Dim CellFind As Range
Dim strFirstCell As String
 
'On désactive le rafraichissement de l'écran
Application.ScreenUpdating = False
 
'On pointe la feuille sur lauqelle on va travailler
With Sheets(ComboBoxChoix2.Text)
    nbLigne = .Cells(.Rows.Count, "A").End(xlUp).Row
    DerCol = .Cells(1, .Cells.Columns.Count).End(xlToLeft).Column 'on détecte la dernière colonne
    ListBoxResultat.ColumnCount = DerCol 'on adapte le nombre de colonne
    'On vide le contenu du listbox
    ListBoxResultat.Clear
 
    'On recherche la valeur Match sur la colonne A
    Set CellFind = .Columns("A").Find(Match, , xlValues, xlPart, MatchCase:=False)
    If Not CellFind Is Nothing Then
        'Une cellule au moins correspond à la recherche
        'On conserve l'adresse de ce 1er résultat
        strFirstCell = CellFind.Address
        'On boucle pour trouver les résultats suivants
        Do
            'On inscrit la ligne dans le listbox, en bouclant sur chaque colonne
            ListBoxResultat.AddItem CellFind.Value
            For iCol = 1 To DerCol
                ListBoxResultat.List(ListBoxResultat.ListCount - 1, i) = CellFind.Offset(, i).Value
            Next
            'On pointe le resultat suivant éventuel
            Set CellFind = .Columns("A").FindNext(CellFind)
        'On ne retourne en haut de la boucle que si le nouveau résultat trouvé n'est pas le 1er, où s'il n'existe plus de résultat sur la feuile
        Loop Until (CellFind Is Nothing) Or (CellFind.Address = strFirstCell)
    End If
 
'On réactive l'affichage de l'écran
Application.ScreenUpdating = True
 
End Sub

++
Qwaz

Salut,

Chez moi cela marchait mais remarque une erreur est possible sur la première combobox. Dans le doute tiens remplace tout le code par celui-la :

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
Option Explicit
'''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''
'Procedure qui permet d'afficher la bonne feuille quand l utilisateur selectionne un item dans la liste de la page ajouter
'''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''
Private Sub ComboBoxChoix_Change()
    Dim sWs As String
    sWs = Me.ComboBoxChoix.Value
    Worksheets(sWs).Select
 
End Sub
''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''
'Procedure qui permet d'afficher la bonne feuille quand l utilisateur selectionne un item dans la liste modifier
''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''
Private Sub ComboBoxChoix2_Change()
    Dim sWs As String
 
    sWs = Me.ComboBoxChoix.Value
    Call ChargerListBox
    If sWs <> "" Then Worksheets(sWs).Select
 
End Sub
'''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''
'procedure permettant de fermer le formulaire de la page modifier
''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''
Private Sub CommandButtonFermer_Click()
    Unload Me
End Sub
'''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''
'procedure permettant de fermer le formulaire de la page ajouter
''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''
Private Sub CommandButtonFermer2_Click()
    Unload Me
End Sub
 
Private Sub TextBoxChercher_Change()
 
    Dim ligne As Integer
    Dim nbLigne As Integer
    Dim dercol As Integer
    Dim i As Byte
    Dim NomFeuille As String
 
    Application.ScreenUpdating = False
    ListBoxResultat.Clear
    NomFeuille = ComboBoxChoix2
    nbLigne = Sheets(NomFeuille).Range("A65536").End(xlUp).Row
 
    If NomFeuille = "" Then Exit Sub
 
    If TextBoxChercher <> "" Then
        For ligne = 2 To nbLigne
            If Sheets(NomFeuille).Cells(ligne, 1) Like "*" & TextBoxChercher & "*" Then
 
                dercol = Sheets(NomFeuille).Cells(1, Cells.Columns.Count).End(xlToLeft).Column 'on détecte la dernière colonne
                ListBoxResultat.ColumnCount = dercol 'on adapte le nombre de colonne
 
                ListBoxResultat.AddItem Sheets(NomFeuille).Cells(ligne, 1)
                For i = 1 To dercol 'On boucle sur les données
                ListBoxResultat.List(ListBoxResultat.ListCount - 1, i) = Sheets(NomFeuille).Cells(ligne, i + 1)
                Next i
 
            End If
        Next
    End If
 
    Application.ScreenUpdating = True
 
End Sub
 
 
'''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''
'procedure permettant d'alimenter les combobox
''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''
Private Sub UserForm_Initialize()
'si la dernière ligne est supérieure à 256 déclarer i et x en Integer
Dim i As Byte, x As Byte
i = Sheets("identifiant").Range("A65536").End(xlUp).Row
For x = 1 To i
    With ComboBoxChoix2
        .AddItem Sheets("identifiant").Range("A" & x)
    End With
    With ComboBoxChoix
        .AddItem Sheets("identifiant").Range("A" & x)
    End With
Next x
End Sub
 
Sub ChargerListBox()
 
Dim ligne As Integer
Dim nbLigne As Integer
Dim dercol As Integer
Dim i As Byte
Dim NomFeuille As String
 
Application.ScreenUpdating = False
 
NomFeuille = ComboBoxChoix2
dercol = Sheets(NomFeuille).Cells(1, Cells.Columns.Count).End(xlToLeft).Column 'on détecte la dernière colonne
ListBoxResultat.ColumnCount = dercol 'on adapte le nombre de colonne
nbLigne = Sheets(NomFeuille).Range("A65536").End(xlUp).Row
 
Sheets(NomFeuille).Select 'active la feuille choisi
ListBoxResultat.Clear
For ligne = 2 To nbLigne
    ListBoxResultat.AddItem Sheets(NomFeuille).Cells(ligne, 1)
    For i = 1 To dercol 'On boucle sur les données
    ListBoxResultat.List(ListBoxResultat.ListCount - 1, i) = Sheets(NomFeuille).Cells(ligne, i + 1)
    Next i
Next ligne
 
Application.ScreenUpdating = True
 
End Sub

Ou alors tu as le code de Qwazerty qui est aussi intéressant ;)

A+

Edit : j'ai corrigé deux petit oubli dans le code de "Qwazerty". La boucle "iCol" et le "End With. Sinon tout fonctionne nickel :

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
 
Private Sub Workbook_PeutImporteOu()
    'On charge le listbox avec toutes les ligne dont la cellule de la colonne A n'est pas vide
    ChargerListBox
End Sub
 
Private Sub TextBoxChercher_Change()
    'On appel la fonction de chargement de la liste
    ChargerListBox TextBoxChercher_Change.Text
 
End Sub
 
Sub ChargerListBox(Optional Match As String = "*")
'Si Match n'est pas renseigné lors de l'appel, on recherche toutes les cellules ayant un contenu "*"
Dim nbLigne As Integer
Dim DerCol As Integer
Dim iCol As Integer
Dim CellFind As Range
Dim strFirstCell As String
 
'On désactive le rafraichissement de l'écran
Application.ScreenUpdating = False
 
'On pointe la feuille sur lauqelle on va travailler
With Sheets(ComboBoxChoix2.Text)
    nbLigne = .Cells(.Rows.Count, "A").End(xlUp).Row
    DerCol = .Cells(1, .Cells.Columns.Count).End(xlToLeft).Column 'on détecte la dernière colonne
    ListBoxResultat.ColumnCount = DerCol 'on adapte le nombre de colonne
    'On vide le contenu du listbox
    ListBoxResultat.Clear
 
    'On recherche la valeur Match sur la colonne A
    Set CellFind = .Columns("A").Find(Match, , xlValues, xlPart, MatchCase:=False)
    If Not CellFind Is Nothing Then
        'Une cellule au moins correspond à la recherche
        'On conserve l'adresse de ce 1er résultat
        strFirstCell = CellFind.Address
        'On boucle pour trouver les résultats suivants
        Do
            'On inscrit la ligne dans le listbox, en bouclant sur chaque colonne
            ListBoxResultat.AddItem CellFind.Value
            For iCol = 1 To DerCol
                ListBoxResultat.List(ListBoxResultat.ListCount - 1, iCol) = CellFind.Offset(, iCol).Value
            Next iCol
            'On pointe le resultat suivant éventuel
            Set CellFind = .Columns("A").FindNext(CellFind)
        'On ne retourne en haut de la boucle que si le nouveau résultat trouvé n'est pas le 1er, où s'il n'existe plus de résultat sur la feuile
        Loop Until (CellFind Is Nothing) Or (CellFind.Address = strFirstCell)
    End If
 
End With
'On réactive l'affichage de l'écran
Application.ScreenUpdating = True
 
End Sub

11/06/2018, 14h06
El tigre

Hello, alors déjà merci beaucoup pour vos réponses :)

Sinon je ne comprend pas d'ou vient le "TextBoxChercher_Change.Text"
11/06/2018, 14h16
McLister213

Citation:

Envoyé par El tigre

Hello, alors déjà merci beaucoup pour vos réponses :)

Sinon je ne comprend pas d'ou vient le "TextBoxChercher_Change.Text"

Cela indique le renvoie de la valeur texte contenue dans le TextBox.
L'avantage c'est qu'il détecte automatiquement, sans passer par une condition, si le texte est vide.
11/06/2018, 15h07
El tigre

1 pièce(s) jointe(s)

je n'ai toujours pas compris, excusez moi, je vous ai mis en pièce jointe, l'erreur que j'obtient
11/06/2018, 15h22
Qwazerty

Citation:

Envoyé par El tigre

Hello, alors déjà merci beaucoup pour vos réponses :)

Sinon je ne comprend pas d'ou vient le "TextBoxChercher_Change.Text"

Il faut juste retirer le "_change" TextBoxChercher.Text, ça doit être un copié collé malheureux :)

Citation:

Edit : j'ai corrigé deux petit oubli dans le code de "Qwazerty". La boucle "iCol" et le "End With. Sinon tout fonctionne nickel :

Il en restait :d, merci.
C'est ça de ne pas tester le code avant de le poster!

++
Qwaz
11/06/2018, 15h31
El tigre

1 pièce(s) jointe(s)

ah oui c'est bon c'est nickel, j'ai juste une derniere question, on est bien d'accord que normalement lorsque l'utilisateur tape "g" par exemple tous les mots contenant la lettre g s'affichent ? parce que si c'est le cas je n'obtient pas tous les mots disponble? et savez vous comment faire pour enlever l'en tête ? je sais pas si je suis clair, désolé j'en demande un peu trop :oops:
11/06/2018, 15h56
Qwazerty
Citation:
Envoyé par El tigre

on est bien d'accord que normalement lorsque l'utilisateur tape "g" par exemple tous les mots contenant la lettre g s'affichent ? parce que si c'est le cas je n'obtient pas tous les mots disponibles?
et savez vous comment faire pour enlever l'en tête ?
1. Ah il faut que la correspondance du texte se fasse sur toutes les cellules? Pas uniquement sur la 1ère?
2. Tu veux dire qu'il n'en tienne pas compte? Si tu tapes par exemple "Nom", la ligne des entêtes ne doit pas être prise en compte et apparaitre dans le listbox (il me semblait y avoir fait attention pourtant)
11/06/2018, 16h02
El tigre

1. Oui, c'est exactement sa
2. oui voila j'aimerais avoir l'en tête fixer je ne sais pas si c'est possible car la lorsque je tape i par exemple, l'entete apparait dans listbox comme si on pouait la modifier hors que non;

je sais pas si je suis clair

Essaie avec ça

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
Sub ChargerListBox(Optional Match As String = "*")
'Si Match n'est pas renseigné lors de l'appel, on recherche toutes les cellules ayant un contenu "*"
Dim nbLigne As Integer
Dim DerCol As Integer
Dim iCol As Integer
Dim CellFind As Range
Dim strFirstCell As String
Dim LastRow As Long
 
'On désactive le rafraichissement de l'écran
Application.ScreenUpdating = False
 
'On pointe la feuille sur lauqelle on va travailler
With Sheets(ComboBoxChoix2.Text)
    nbLigne = .Cells(.Rows.Count, "A").End(xlUp).Row
    DerCol = .Cells(1, .Cells.Columns.Count).End(xlToLeft).Column 'on détecte la dernière colonne
    ListBoxResultat.ColumnCount = DerCol 'on adapte le nombre de colonne
    'On vide le contenu du listbox
    ListBoxResultat.Clear
 
    'On recherche la valeur Match sur la colonne A
    Set CellFind = .UsedRange.Find(Match, , xlValues, xlPart, xlByRows, MatchCase:=False)
    If Not CellFind Is Nothing Then
        'Une cellule au moins correspond à la recherche
        'On conserve l'adresse de ce 1er résultat
        strFirstCell = CellFind.Address
        'On boucle pour trouver les résultats suivants
        Do
            'On vérifie que la ligne n'est pas déjà inscrite dnas le tableau
            'On vérifie aussi que la cellule ne fait pas partie de l'entête
            If (LastRow <> CellFind.Row) And (CellFind.Row <> 1) Then
                'On inscrit la ligne dans le listbox, en bouclant sur chaque colonne
                ListBoxResultat.AddItem CellFind.Value
                For iCol = 1 To DerCol
                    ListBoxResultat.List(ListBoxResultat.ListCount - 1, iCol) = CellFind.Offset(, iCol).Value
                Next
            End If
            LastRow = CellFind.Row
            'On pointe le resultat suivant éventuel
            Set CellFind = .UsedRange.FindNext(CellFind)
        'On ne retourne en haut de la boucle que si le nouveau résultat trouvé n'est pas le 1er, où s'il n'existe plus de résultat sur la feuile
        Loop Until (CellFind Is Nothing) Or (CellFind.Address = strFirstCell)
    End If
End With
 
'On réactive l'affichage de l'écran
Application.ScreenUpdating = True
 
End Sub

++Qwaz

11/06/2018, 16h16
El tigre

Ok nickel merci , pour etablir la taille de colonnes en fonction des mots je sais que c'est cColumnWidth mais je le place où dans le code stp
11/06/2018, 16h44
Qwazerty

Tu peux directement le renseigner dans VBA, tu cliques sur le listbox, tu vas dans les propriétés (Touche F4 si pas affichés). Pour définir les largeurs de chaque colonne, tu places les largeurs les unes à la suite des autres en séparant par un point virgule (VBA ajoutera tout seul les unité "pt", tu as juste à mettre 40;5;0;12. le 0 masque la colonne.

Sinon si tu veux le modifier dans le code, je ne sais pas quand tu veux modifier la largeur ni par rapport à quel critère. Je sais que le calcule par rapport à la font utilisé est plutôt pénible à faire (je dis ça de mémoire, fait quelques recherches sur le sujet).

++
Qwaz

Voir 40 message(s) de cette discussion en une page