Vérifier qu'un chiffre se répète un certain nombre de fois sans interruption

Bonjour à tous,

Sur la base de la matrice VBA qu'a proposé Eric (et que j'utilise maintenant), j'aimerais faire la même chose pour détecter si dans un nombre des chiffres se répètent à la suite et un certains nombre de fois.

Par exemple, si j'ai dans une colonne le nombre 1 222 222,34, j'aimerais que dans la colonne a coté cela me dise "Yes" ou "No" (si par exemple on dit que la condition est : que le chiffre se répète 6 fois de suite). Si par exemple nombre était 12 122 222,34, bien qu'ayant le "2" 6 fois il faudrait que ca me dise "No".

Cela peut se faire soit par une selection de critère (comme dans la VBA précédente pour les mots), dans ce cas là dans un autre onlget j'irai renseigner toutes les suites possibles, ou alors s'il y a un autre moyen qui detecte automatiquement les répétitions de chiffres je suis preneur.

Merci par avance pour votre aide...

Un jour je maitriserais VBA promis :)

Salut.

Sur l'idée d'Eric d'utiliser une fonction perso, voici une fonction perso qui utilise les expressions régulières, à utiliser dans ta feuille de calcul comme une fonction native d'Excel, à laquelle tu passes la valeur à tester, le chiffre qui doit être répété et le nombre de répétitions voulues

Code:

---

1 2 3 4 5 6 7 8 9 10

Function SuiteChiffreOk(Valeur As String, Chiffre As String, Repetition As Long) As Boolean Dim RegExp As Object Dim Pattern As String   Set RegExp = CreateObject("VBScript.RegExp") Pattern = Chiffre & "{" & Repetition & "}" RegExp.Pattern = Pattern SuiteChiffreOk = RegExp.test(Valeur) Set RegExp = Nothing End Function

---

Le résultat en Excel:

Pièce jointe 362904

Citation:

---

Envoyé par arnaudgalinier

---

Bonjour,

Pour faire cela, j'utiliserais les instructions Instr pour connaître le position du premier caractère et Mid avec une boucle sur les caractères à partir du premier trouvé sans tenir compte des séparateurs de milliers (blanc, point,etc....) ou décimal.

Bonjour et merci,

Pierre pour votre code VBA cela m'indique "Sub or Function non définie", une idée de ce qui coince ?

Eric, merci pour votre aide, mais je vous avoue, qu'avec mon niveau VBA je n'y comprends rien :calim2:

Sur quelle ligne de code?

Version d'Excel?

Excel sur Mac ou PC?

VBScript désactivé sur le pc?

La solution de Pierre fonctionne nickel chez moi.

Bonjour

Avant de prendre la route et pour me changer les idées --->> une méthode rigolote et "décalée" (pas de VBS sur ma machine -->> et donc ...) --->>

Code:

---

1 2 3 4 5 6 7 8 9 10 11

toto = "221222222f33333331111" nb = 6 ' la cndition.nombre minimum de répétitions Dim titi() As Byte titi = StrConv(toto, vbFromUnicode) For I = 0 To UBound(titi) - 1 If titi(I + 1) <> titi(I) Then titi(I) = 0 Next tata = Split(StrConv(titi, vbUnicode), Chr(0)) For I = 0 To UBound(tata) If Len(tata(I)) >= nb - 1 Then MsgBox "le chiffre " & Left(tata(I), 1) & " est répété " & Len(tata(I)) + 1 & " fois de suite" Next

---

Citation:

---

Envoyé par Pierre Fauconnier

Sur quelle ligne de code?

Version d'Excel?

Excel sur Mac ou PC?

VBScript désactivé sur le pc?

---

Alors j'utilise une version 2016 d'Excel sur un PC et VBscript est actif.

Et il me semble que c'est sur la premiere ligne du code (voir capture d'écran).

Merci Pièce jointe 362972

Et la ligne de code qui pose problème?

A quel moment as-tu ce message?

Citation:

---

Envoyé par Pierre Fauconnier

Et la ligne de code qui pose problème?

A quel moment as-tu ce message?

---

J'ai rajouté la capture d'écran dans ma réponse précédente.

Le message apparaît, une fois que j'appuie sur entrée après avoir fais appel à la formule et l'avoir renseigné.

Il y a une crasse après les lignes Dim... (Le site a ajouté cette crasse lors de mon copier-coller car je n'ai pas ce problème chez moi et lorsque je reprends le code du site et que je le teste, j'ai le même problème que toi. Je suppose que c'est un problème d'encodage et je ne suis pas sur ma machine habituelle)

Supprime simplement ce qui est en bleu entre les lignes Dim et Set RegExp

ou

Supprime la ligne vide entre les Dim et le Set RegExp. Et si tu souhaites refaire une ligne vide, fais simplement Enter après t'être placé à la fin de la ligne du dernier Dim

Yes!!

Merci a vous!

C'est promis cet été je me plonge a fond dans le VBA :)

Existe-t-il une méthode rapide (et qui ne vous prenne pas trop de temps a m'expliquer) pour que ce code, prenne en compte plusieurs critères ?

Je m'explique, là je ne peux mettre qu'un critère par exemple le 2;répété x fois...

J'aimerais le faire pour tous les chiffres de 0 à 9.

La solution que j'envisage (vous allez avoir peur) et de recopier ce code dans plusieurs colonne en modifiant chaque fois le chiffre que je veux voir s'il est dupliqué. 8O8O

Pour modifier la recherche, on peut modifier le pattern. C'est là, notamment, que réside la puissance de cet outil.

Peux-tu définir précisément ce que tu souhaites faire? Vérifier qu'il y a au moins un chiffre (n'importe lequel?) répété x fois? Le x peut aller de x à y?

Citation:

---

Envoyé par Pierre Fauconnier

Note bien que la fonction que je te donnes ne vérifie pas que le 2. Elle vérifie que ton deuxième paramètre se répète le nombre de fois précisé par le troisième paramètre. Tu peux donc vérifier que 9 se répète 3 fois ou que 1 se répète 10 fois.

Pour modifier la recherche, il suffit de modifier le pattern de la RegExp, normalement. C'est là, notamment, que réside la puissance de cet outil.

Peux-tu définir précisément ce que tu souhaites faire? Vérifier qu'il y a au moins un chiffre (n'importe lequel?) répété x fois?

---

Oui j'ai bien noté ca, mais effectivement ce que je souhaite faire, c'est vérifier qu'il y a au moins un chiffre (de 0 à 9) qui se répète x fois.

Bonjour à tous,

Jacques, sympa ton code :plusser:
Comme tu l'as déjà dit ce fameux StrConv(toto, vbFromUnicode) est bien utile,
on peut faire souvent appel à lui je vois ;)

Citation:

---

Envoyé par Pierre Fauconnier

---

Je rebondis sur ton message, Pierre, car depuis quelques jours, lorsque je copie-colle mon code entre balises #, j'ai une ribambelle de caractères parasites qui viennent se déverser dans mon code. Je ne sais pas si le problème vient de mon poste ou s'il vient du site.

re

Code:

---

1 2 3

Public Function comptechiffre(cel, valeur, repetition) comptechiffre = IIf(UBound(Split(cel.Value, valeur)) >= repetition, "yes", "no") End Function

---

formule :

Citation:

---

=comptechiffre(A1;22;6)

---

traduction

Citation:

---

=comptechiffre(adresse cellule;chiffre a tester;occurence)

---

si 6 occurence ou plus tu aura "yes" sinon "no"
si tu veux nom pas 6 ou plus mais exactement 6 suprime le ">" dans le code
appercu
Pièce jointe 362992
auserais-je dire que cela doit etre compatible PC windows/mac

Arnaud,

Voici une solution qui teste qu'au moins un chiffre (n'importe lequel) est répété x fois. (attention aux crasses à la recopie)

Code:

---

1 2 3 4 5 6 7 8 9 10 11 12 13 14 15 16

Function SuiteChiffreOk(Valeur As String, Repetition As Long) As Boolean Dim RegExp As Object Dim Pattern As String Dim Rep As String Dim Counter As Long   Rep = "{" & Repetition & "}" Pattern = "0" For Counter = 1 To 9 Pattern = Pattern & Rep & "|" & Counter Next Set RegExp = CreateObject("VBScript.RegExp") RegExp.Pattern = Pattern SuiteChiffreOk = RegExp.test(Valeur) Set RegExp = Nothing End Function

---

Pièce jointe 362995

Citation:

---

Envoyé par Eric KERGRESSE

Je rebondis sur ton message, Pierre, car depuis quelques jours, lorsque je copie-colle mon code entre balises #, j'ai une ribambelle de caractères parasites qui viennent se déverser dans mon code. Je ne sais pas si le problème vient de mon poste ou s'il vient du site.

---

Je vais remonter le problème. Merci Eric ;)

Joli, Patrick, pour la demande initiale :plusser:

Merci.

Patrick,

Je retire ce que j'ai dit (mais je te laisse le +1 ;), car ça m'a donné l'idée)... Ca me renvoie YES même si les chiffres ne se suivent pas (je n'avais pas testé avant d'applaudir, mais en relisant ton code, je ne voyais pas comment cela pouvait fonctionner)...

Pièce jointe 362997

Mais ton idée est bonne... Voici ton code modifié pour que cela fonctionne (selon la demande initiale qui était de spécifier un chiffre bien défini). Comme quoi il y a souvent plusieurs chemins... ;)

Code:

---

1 2 3 4 5 6

Function CompteChiffre1(Valeur As String, Chiffre As Long, Repetition As Long) Dim Chaine As String   Chaine = String(Repetition, Chiffre & "") CompteChiffre1 = UBound(Split(Valeur, Chaine)) > 0 End Function

---

Un grand merci Pierre, c'est parfait!

Merci à tous pour vos solutions, vous êtes géniaux!!!

autre solution basique mais simple si l'on veut viser plus spécialement un chiffre avec sa répétition au minimum

Code:

---

1 2 3

Function repet(Cel As Range, chiffre) repet = IIf(InStr(Cel.Value, chiffre) >= 1, "Yes", "No") End Function

---

Ex. valeur de Cel : 456555567
=repet(B2;555)

Ce que j'apprécie particulièrement dans cette discussion (mais dans d'autres aussi), c'est que les différentes approches permettent à des utilisateurs de tous niveaux de s'y retrouver et d'avoir une solution à leur portée. L'important est qu'il y a d'abord une obligation de résultat, et c'est ce qu'illustre Arnaud

Citation:

---

Envoyé par arnaudgalinier

[...]La solution que j'envisage (vous allez avoir peur) et de recopier ce code dans plusieurs colonne en modifiant chaque fois le chiffre que je veux voir s'il est dupliqué. 8O8O

---

C'était aussi une solution, comme celle de Ryu qui, pour être basique mais simple, comme il dit, n'en est pas moins fonctionnelle (pour la question initiale).

L'approche de Ryu, qui plus est, permettrait, pour la question initiale, basiquement mais simplement, de se passer de VBA...

Pièce jointe 363009

Citation:

---

Envoyé par Pierre Fauconnier

Arnaud,

Voici une solution qui teste qu'au moins un chiffre (n'importe lequel) est répété x fois. (attention aux crasses à la recopie)

Code:

---

1 2 3 4 5 6 7 8 9 10 11 12 13 14 15 16

Function SuiteChiffreOk(Valeur As String, Repetition As Long) As Boolean Dim RegExp As Object Dim Pattern As String Dim Rep As String Dim Counter As Long   Rep = "{" & Repetition & "}" Pattern = "0" For Counter = 1 To 9 Pattern = Pattern & Rep & "|" & Counter Next Set RegExp = CreateObject("VBScript.RegExp") RegExp.Pattern = Pattern SuiteChiffreOk = RegExp.test(Valeur) Set RegExp = Nothing End Function

---

---

En fait j'ai un petit soucis, le code fonctionne pour la première ligne, mais quand j'étire la formule je ne comprends pas les résultats qui ressortent (voir ci-dessous) :
Pièce jointe 363013

Pièce jointe 362995

Pour info dans ma colonne N, le nombre sont en format nombre.

Sorry, j'avais oublié de placer la répétition sur le 9.

Voici un code qui fonctionne (j'ai ajouté Pattern = Pattern & Rep après la boucle).

Code:

---

1 2 3 4 5 6 7 8 9 10 11 12 13 14 15 16 17

Function SuiteChiffreOk(Valeur As String, Repetition As Long) As Boolean Dim RegExp As Object Dim Pattern As String Dim Rep As String Dim Counter As Long   Rep = "{" & Repetition & "}" Pattern = "0" For Counter = 1 To 9 Pattern = Pattern & Rep & "|" & Counter Next Pattern = Pattern & Rep Set RegExp = CreateObject("VBScript.RegExp") RegExp.Pattern = Pattern SuiteChiffreOk = RegExp.test(Valeur) Set RegExp = Nothing End Function

---

Question subsidiaire: Ca doit compter sur les valeurs avec décimales ou tu considères que ta suite de chiffres est une chaine de caractères?

Parfait, encore un grand merci!

Je considère la suite de chiffres comme un chaine de caractère, autrement dit je m'en fiche des décimales, et encore autrement dit votre code correspond parfaitement à ma demande.

Avec le code que je te donne, si tu souhaites tester 122,222245 et voir si un chiffre se répète 6 fois de suite, la fonction renverra FAUX.

Si tu veux que le comptage considère qu'il n'y a pas de décimales, tu devras utiliser la version suivante, dans laquelle je remplace , et . par rien. Par contre, il n'est pas nécessaire de se préoccuper du séparateur de milliers qui n'est pas passé à la fonction. A toi de voir ;)

Code:

---

1 2 3 4 5 6 7 8 9 10 11 12 13 14 15 16 17 18

Function SuiteChiffreOk(Valeur As String, Repetition As Long) As Boolean Dim RegExp As Object Dim Pattern As String Dim Rep As String Dim Counter As Long   Valeur = Replace(Replace(Valeur, ".", ""), ",", "") Rep = "{" & Repetition & "}" Pattern = "0" For Counter = 1 To 9 Pattern = Pattern & Rep & "|" & Counter Next Pattern = Pattern & Rep Set RegExp = CreateObject("VBScript.RegExp") RegExp.Pattern = Pattern SuiteChiffreOk = RegExp.test(Valeur) Set RegExp = Nothing End Function

---

un dérivé de la fonction simple :

Code:

---

1 2 3 4 5 6 7 8 9 10 11

Function repetition(Cel As Range, repet As Byte) Dim i As Byte For i = 1 To Len(Cel.Value) If InStr(Cel.Value, String(repet, Mid(Cel.Value, i, 1))) >= 1 Then repetition = "Yes" Exit For Else repetition = "No" End If Next End Function

---

Edit : pour ressembler à la 1ère (post ) :

Code:

---

1 2 3 4 5 6 7

Function repetition(Cel As Range, repet As Byte) Dim i As Byte For i = 1 To Len(Cel.Value) repetition = IIf(InStr(Cel.Value, String(repet, Mid(Cel.Value, i, 1))) >= 1, "Yes", "No") If repetition = "Yes" Then Exit For Next End Function

---

Bonjour Pierre

Citation:

---

Ce que j'apprécie particulièrement dans cette discussion (mais dans d'autres aussi), c'est que les différentes approches permettent à des utilisateurs de tous niveaux de s'y retrouver et d'avoir une solution à leur portée

---

les approches sont innombrables.
En voilà une autre :

Code:

---

1 2 3 4 5 6 7 8 9 10 11

toto = "22122222213333333111177777777777744" nb = 6 ' la cndition.nombre minimum de répétitions titi = Split(StrConv(" " & toto, vbUnicode), Chr(0)) meszozos = "": deja = "" For I = 0 To UBound(titi) - 1 If InStr(deja, titi(I)) = 0 And toto Like "*" & String(nb, titi(I)) & "*" Then meszozos = meszozos & vbCrLf & titi(I) deja = deja & titi(I) End If Next MsgBox "liste des chiffres répétés au moins " & nb & " fois de suite" & IIf(meszozos <> "", meszozos, vbCrLf & "aucun")

---

et si strconv peut en rebuter certains, voilà la même chose (un peu moins rapide) avec Mid :

Code:

---

1 2 3 4 5 6 7 8 9 10

toto = "22122222213333333111177777777777744" nb = 6 ' la cndition.nombre minimum de répétitions For I = 1 To Len(toto) c = Mid(toto, I, 1) If InStr(deja, c) = 0 And toto Like "*" & String(nb, c) & "*" Then meszozos = meszozos & vbCrLf & Mid(toto, I, 1) deja = deja & c End If Next MsgBox "liste des chiffres répétés au moins " & nb & " fois de suite" & IIf(meszozos <> "", meszozos, vbCrLf & "aucun")

---

(je préfère la plus grande agilité de la première des deux. Le nombre de lignes de code n'est pas ce qui importe).

Citation:

---

Envoyé par Pierre Fauconnier

Patrick,

Je retire ce que j'ai dit (mais je te laisse le +1 ;), car ça m'a donné l'idée)... Ca me renvoie YES même si les chiffres ne se suivent pas (je n'avais pas testé avant d'applaudir, mais en relisant ton code, je ne voyais pas comment cela pouvait fonctionner)...

Pièce jointe 362997

Mais ton idée est bonne... Voici ton code modifié pour que cela fonctionne (selon la demande initiale qui était de spécifier un chiffre bien défini). Comme quoi il y a souvent plusieurs chemins... ;)

Code:

---

1 2 3 4 5 6

Function CompteChiffre1(Valeur As String, Chiffre As Long, Repetition As Long) Dim Chaine As String   Chaine = String(Repetition, Chiffre & "") CompteChiffre1 = UBound(Split(Valeur, Chaine)) > 0 End Function

---

---

oui pierre j'avais pas compris qu'il fallait absolument que la valeur recherchée avec repetition devait se suivre
en relisant l'enoncé en post 1 effectivement j'ai busé le "fois de suite" autant pour moi

il y avait aussi

Code:

---

application.rept(valeur,repetition)

---

EDIT PETITE ADAPTATION D'UNE METHODE OU L'AUTRE
et cela pour du texte ou des nombres

Code:

---

1 2 3

Public Function comptechar(cel As Range, valeur, repetition As Long) comptechar = IIf(UBound(Split(cel.Value, Application.Rept(valeur, repetition))) > 0, "yes", "no") End Function

---

Code:

---

1 2 3

Public Function comptechar(cel As Range, valeur, repetition As Long) comptechar = IIf(UBound(Split(cel.Value, String(repetition, valeur & ""))) > 0, "yes", "no") End Function

---

formule texte

Citation:

---

=comptechar(A2;"a";5) ' teste si "a" est répété 5 fois

---

Citation:

---

=comptechar(A1;2;6)'teste si "2" est répété 6 fois

---

mille excuse pour la meprise :oops:

Bonjour,

Les possibilités étant innombrables, je me permet trois petits détours (Like, Replace et Instr)...
Toutes sur le même schéma, un Do Loop sur le Split d'une constante afin d'en tirer tous les "pattern" possibles grâce à la fonction String.

Code:

---

1 2 3 4 5 6 7 8 9 10 11 12 13 14 15 16 17 18 19 20 21 22 23 24 25 26 27 28 29 30 31 32 33 34 35 36 37 38 39 40 41 42 43 44 45

Option Explicit   Private Const STRP As String = "0 1 2 3 4 5 6 7 8 9"   Sub MainTest() Dim m As String m = Inl("22234444", 0) & " " & Inl("22234444", 2) & " " & Inl("22234444", 4) & " " & Inl("22234444", 5) & vbCrLf m = m & Inr("22234444", 0) & " " & Inr("22234444", 2) & " " & Inr("22234444", 4) & " " & Inr("22234444", 5) & vbCrLf m = m & Ini("22234444", 0) & " " & Ini("22234444", 2) & " " & Ini("22234444", 4) & " " & Ini("22234444", 5) MsgBox m End Sub   Function Inl(strC As String, lngRept As Integer) As Boolean Dim cpt As Integer, t If lngRept > 0 Then t = Split(STRP, " ") Do Inl = strC Like "*" & String(lngRept, t(cpt)) & "*" cpt = cpt + 1 Loop While Not Inl And cpt <= 9 End If End Function   Function Inr(strC As String, lngRept As Integer) As Boolean Dim cpt As Integer, L As Integer, t If lngRept > 0 Then t = Split(STRP, " ") Do L = Len(Replace(strC, String(lngRept, t(cpt)), "")) Inr = ((Len(strC) - L) Mod lngRept = 0) And Len(strC) > L cpt = cpt + 1 Loop While Not Inr And cpt <= 9 End If End Function   Function Ini(strC As String, lngRept As Integer) As Boolean Dim cpt As Integer, t If lngRept > 0 Then t = Split(STRP, " ") Do Ini = InStr(1, strC, String(lngRept, t(cpt))) > 0 cpt = cpt + 1 Loop While Not Ini And cpt <= 9 End If End Function

---

re
bonjour a tous

je ne voudrais pas prolonger une discussion plus qu'il ne faut mais il me parraissait important d'attirer votre attention sur ce point

POURQUOI LIMITER LA FONCTION A VRAI/FAUX OU YES/NO COMME VOUS VOULEZ

je me suis dit
1°et si je voudrais non pas savoir si oui ou non mais mais avoir le retour du nombre d'occurences chaine identiques qui se suivent
2°et si je voudrais non pas savoir si oui ou non mais mais avoir le retour du nombre d'occurences chaine identiques qui ne se suivent pas forcement

j'ai donc limité paradoxalement:mouarf: la fonction a retourner le nombre d'occurence et dans la formule je gere le vrai/faux par la condition si()

Code:

---

1 2 3

Public Function comptechar(cel As Range, valeur, repetition As Long) comptechar = UBound(Split(cel.Value, Application.Rept(valeur, repetition))) End Function

---

comme vous le voyez ci dessous tout se gere avec le 2d et 3eme argument de la fonction et le test ">" dans la condition "si()" selon mes besoins

1. y a-t-il "2" 5 fois de suite dans la cellules la formule : =SI(comptechar(A3;2;3)>0;"yes";"no")
2. combien de fois il y a "aaa" dans la cellule la formule =comptechar(A2;"a";3)
3. y a-t-il "22" 3 fois de suite dans la cellules la formule : =SI(comptechar(A3;22;3)>0;"yes";"no")
4. y a-t-il plusieurs fois "22" pas forcement qu'il se suivent dans la cellule la formule =SI(comptechar(A5;22;1)>1;"yes";"no")
5. combien de fois il y a "22" pas forcement qu'il se suivent dans la cellule la formule =comptechar(A2;22;1)
6. y a-t-il plusieurs fois "toto" pas forcement qu'il se suivent dans la cellule la formule =SI(comptechar(A5;"toto";1)>1;"yes";"no")

demo
Pièce jointe 363310

a noter que j'aurais pu faire exactement la meme chose en utilisant un argument supplementaire dans un select case dans la fonction pour choisir le type/mode de retour de la fonction et ainsi se passer de la condition "si()" dans la formule
j'ai voulu la garder la plus simple possible c'est pour cela que j'ai choisi cette methode

a noter aussi par exemple en ligne 2 dans la capture j'aurais pu utiliser =comptechar(A2;"aaa";1)

@Patrick,

Le nombre d’occurrences est également sujet à interprétation.
Ainsi, dans 22222234 on peut y voir :
> 3 fois 22 :
22222234
> 5 fois 22 :
22222234
22222234
22222234
22222234
22222234

re
bonjour franck
comme on teste une chaine et que en plus il est précisé "fois de suite" ton interprétation est erronée

2222 n'est pas 3 fois 22 de suite comme tu le sous entends

cela dit ta remarque est pertinante mais on parle de combinasion voir d'un nombre puissance len(....)

2222
le1 avec le 2d
le 1 avec le 3eme
le 1 avec le 4eme
le 2d avec le 3eme
etc...etc.....
d'ailleurs il me semble avoir fait un exercice comme ca avec le regex celui ci me semble t il ,donnait bien le nombre sans les combinaison croisée
a verifier