L'ajout d'un namespace fait perdre un attribut

Version imprimable

Bonjour,

J'ai un fichier XML de départ que je désire transformer en un autre fichier XML.
Au départ, je n'ai pas de namespace et je désire ajouter un namespace.
Voici mon fichier XML de départ

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
<?xml version="1.0" encoding="UTF-8"?>
<Document>
		<PmtInf>
			<ReqdColltnDt>2018-03-18</ReqdColltnDt>
			<DrctDbtTxInf>
				<PmtId>
					<EndToEndId>voice0116</EndToEndId>
				</PmtId>
				<!-- Attention cet element a un Attribut ! ! -->
				<InstdAmt Ccy="EUR">1242.19</InstdAmt>
			</DrctDbtTxInf>
		</PmtInf>
		<PmtInf>
			<ReqdColltnDt>2018-03-19</ReqdColltnDt>
			<DrctDbtTxInf>
				<PmtId>
					<EndToEndId>voice0349</EndToEndId>
				</PmtId>
				<InstdAmt Ccy="EUR">1055.12</InstdAmt>
			</DrctDbtTxInf>
			<DrctDbtTxInf>
				<PmtId>
					<EndToEndId>voice0143</EndToEndId>
				</PmtId>
				<InstdAmt Ccy="EUR">750.32</InstdAmt>
			</DrctDbtTxInf>
		</PmtInf>
</Document>

Comme vous le voyez, la racine est simplement <Document>
Je désire obtenir une racine comme ceci <Document xmlns="urn:iso:std:iso:202:tech">
Pour y parvenir, j'applique la transformation xslt suivante

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
	<!-- <xsl:strip-space elements="*"/> -->
	<xsl:output method="xml" indent="yes" encoding="utf-8"/>
 
	<xsl:template match="*[ancestor::Document]">
		<xsl:element name="{local-name()}" namespace="urn:iso:std:iso:202:tech">
			<xsl:apply-templates select="*|text()"/>
		</xsl:element>
	</xsl:template>
 
	<xsl:template match="Document|@*">
		<Document xmlns="urn:iso:std:iso:202:tech">
			<xsl:apply-templates select="*|text()"/>
		</Document>
	</xsl:template>
 
</xsl:stylesheet>

Cela fonctionne plutôt bien si ce n'est que je perds l'attribut Ccy
Voici le résultat que j'obtiens :

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
<?xml version="1.0" encoding="utf-8"?>
<Document xmlns="urn:iso:std:iso:202:tech">
	<PmtInf>
		<ReqdColltnDt>2018-03-18</ReqdColltnDt>
		<DrctDbtTxInf>
			<PmtId>
				<EndToEndId>voice0116</EndToEndId>
			</PmtId>
			<InstdAmt>1242.19</InstdAmt>
		</DrctDbtTxInf>
	</PmtInf>
	<PmtInf>
		<ReqdColltnDt>2018-03-19</ReqdColltnDt>
		<DrctDbtTxInf>
			<PmtId>
				<EndToEndId>voice0349</EndToEndId>
			</PmtId>
			<InstdAmt>1055.12</InstdAmt>
		</DrctDbtTxInf>
		<DrctDbtTxInf>
			<PmtId>
				<EndToEndId>voice0143</EndToEndId>
			</PmtId>
			<InstdAmt>750.32</InstdAmt>
		</DrctDbtTxInf>
	</PmtInf>
</Document>

Mes noeuds InstdAmt ont perdu leur attribut !!
Là où j'ai <InstdAmt>1242.19</InstdAmt> ,
j'aurais dû garder<InstdAmt Ccy="EUR">1242.19</InstdAmt>

Comment puis-je faire pour garder l'attribut Ccy ?

Merci pour vos explications

15/03/2018, 15h51
thelvin

Hello,

ben quand tu crées un nouvel élément, 'faudrait pas oublier de copier les attributs dedans !

Un simple <xsl:copy-of select="@*"/> devrait faire l'affaire...

OK, Merci.

Voici donc la solution complète :

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
	<xsl:output method="xml" indent="yes" encoding="utf-8"/>
	<xsl:template match="*[ancestor::Document]">
		<xsl:element name="{local-name()}" namespace="urn:iso:std:iso:202:tech">
			<xsl:apply-templates select="*|text()"/>
		</xsl:element>
	</xsl:template>
	<xsl:template match="Document">
		<Document xmlns="urn:iso:std:iso:202:tech">
			<xsl:copy-of  select="*|text()"/>
		</Document>
	</xsl:template>
</xsl:stylesheet>

15/03/2018, 16h38
thelvin

Chez moi cela ne fait pas du tout ce que tu as demandé... Seule la racine a un namespace avec ce code. J'imagine, et ton exemple confirmait, que tu voulais que tous les éléments héritent du namespace de la racine.

Oui, j'ai repondu un peu trop vite...
Ce que je viens de publier ne fait pas le job voulu.

Code:

1
2
3
4
5
6
7
8
<Document xmlns="urn:iso:std:iso:202:tech">  <!-- parfait ! -->
	<PmtInf xmlns="">        <!--   je ne veux pas de ce xmlns ici -->
		<ReqdColltnDt>2018-03-18</ReqdColltnDt>
		<DrctDbtTxInf>
			<PmtId>
				<EndToEndId>voice0116</EndToEndId>
			</PmtId>
			<InstdAmt Ccy="EUR">1242.19</InstdAmt>   <!-- Parfait : l attribut Ccy est présent -->

15/03/2018, 17h43
thelvin

Voilà. Donc plutôt le copy-of que j'ai dit, à l'endroit où j'ai dit (quand tu crées tes éléments !)

:ptdr: Je ne comprends pas...
Le Copy-of ne fait pas l'affaire mais on se rapproche du résultat.
Cette fois-ci on a :

Code:

1
2
3
4
5
6
7
8
9
10
11
<?xml version="1.0" encoding="utf-8"?>
<Document xmlns="urn:iso:std:iso:202:tech">
	<PmtInf>
		<ReqdColltnDt>2018-03-18</ReqdColltnDt>
		<DrctDbtTxInf>
			<PmtId>
				<EndToEndId>voice0116</EndToEndId>
			</PmtId>
			<InstdAmt>EUR1242.19</InstdAmt>  <!-- c est mieux : il y a EUR mais toujours l attribut Ccy -->
		</DrctDbtTxInf>
	</PmtInf>

J'utilise ce XSLT :

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
	<xsl:output method="xml" indent="yes" encoding="utf-8"/>
 
	<xsl:template match="*[ancestor::Document]">
		<xsl:element name="{local-name()}" namespace="urn:iso:std:iso:202:tech">
			<xsl:apply-templates select="@*|*|text()"/>
		</xsl:element>
	</xsl:template>
 
	<xsl:template match="Document">
		<Document xmlns="urn:iso:std:iso:20022:tech:xsd:pain.008.001.02">
			<xsl:apply-templates select="@*|*|text()"/>
		</Document>
	</xsl:template>
 
</xsl:stylesheet>

Si j'utilise

Code:

<xsl:copy-of select="@*"/>

alors il me met

Code:

xmlns=""

et ça ce n'est pas bon non plus.

15/03/2018, 18h12
thelvin

Si tu l'utilises... Où ?

Bonjour,

Voici le XSLT avec copy-of :

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
	<xsl:output method="xml" indent="yes" encoding="utf-8"/>
	<xsl:template match="*[ancestor::Document]">
		<xsl:element name="{local-name()}" namespace="urn:iso:std:1.02">
			<xsl:copy-of select="*"/>
		</xsl:element>
	</xsl:template>
	<xsl:template match="Document">
		<Document xmlns="urn:iso:std:1.02">
			<xsl:apply-templates select="*|text()" />
		</Document>
	</xsl:template>
</xsl:stylesheet>

Par rapport aux versions avec apply-templates, cette version avec copy-of a l'avantage de copier l'attribut Ccy="EUR".
Il crée bien la racine avec le nouveau namespace mais pour les éléments enfants de Document, il les copie avec l'ancien namespace c'est-à-dire pas de namespace. D'où le xmlns = "".

Voici ce que ce XSLT me donne :

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
<?xml version="1.0" encoding="utf-8"?>
<Document xmlns="urn:iso:std:1.02">           <!-- Parfait !  -->
	<PmtInf>
		<ReqdColltnDt xmlns="">2018-03-18</ReqdColltnDt>    <!-- Mauvais namespace -->
		<DrctDbtTxInf xmlns="">                                  <!-- Mauvais namespace -->
			<PmtId>
				<EndToEndId>voice0116</EndToEndId>
			</PmtId>
			<InstdAmt Ccy="EUR">1242.19</InstdAmt>             <!-- Parfait !  -->
		</DrctDbtTxInf>
	</PmtInf>
	<PmtInf>
		<ReqdColltnDt xmlns="">2018-03-19</ReqdColltnDt>
		<DrctDbtTxInf xmlns="">
			<PmtId>
				<EndToEndId>voice0349</EndToEndId>
			</PmtId>
			<InstdAmt Ccy="EUR">1055.12</InstdAmt>
		</DrctDbtTxInf>
		<DrctDbtTxInf xmlns="">
			<PmtId>
				<EndToEndId>voice0143</EndToEndId>
			</PmtId>
			<InstdAmt Ccy="EUR">750.32</InstdAmt>
		</DrctDbtTxInf>
	</PmtInf>
</Document>

Je ne parviens pas à éliminer ce xmlns=""

Soit j'ai le bon namespace mas sans l'attribut Ccy="EUR".
Soit j'ai lattribut Ccy="EUR" correct mais alors j'ai des problèmes de namespace.

Comment avoir l'un et l'autre corrects ?

Merci.

Bon, comme je ne parviens pas avoir l'un et l'autre, j'ai essayé d'avoir l'un puis l'autre.

En créant un template supplémentaire et surtout en spécifiant explicitement dans le 3ième § que je veux pour tous les éléments le namespace "urn:iso.." je parviens à mes fins.
Voici ce que j'ai :

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
	<xsl:output method="xml" version="1.0" encoding="UTF-8" indent="yes"/>
 
	 <xsl:template match="@*|text()">
        <xsl:copy>
            <xsl:apply-templates select="@*|node()"/>
        </xsl:copy>
    </xsl:template>
 
    <xsl:template match="Document">
		<Document xmlns="urn:iso:std:1.02">
			<xsl:apply-templates select="@*|node()" />
		</Document>
	</xsl:template>
 
 
		<xsl:template match="*">
		<xsl:element name="{local-name()}" namespace="urn:iso:std:1.02">
			<xsl:apply-templates select="@*|node()"/>
		</xsl:element>
	</xsl:template>
 
</xsl:stylesheet>

Merci encore pour votre aide. ....ensemble, on est plus fort.

Bon, si tu y arrives...

Enfin, la solution était de faire exactement ce que j'ai dit et absolument pas autre chose que ça. Dans une feuille XSLT complète ça donne :

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
	<!-- <xsl:strip-space elements="*"/> -->
	<xsl:output method="xml" indent="yes" encoding="utf-8"/>
 
	<xsl:template match="*[ancestor::Document]">
		<xsl:element name="{local-name()}" namespace="urn:iso:std:iso:202:tech">
			<xsl:copy-of select="@*"/>
			<xsl:apply-templates select="*|text()"/>
		</xsl:element>
	</xsl:template>
 
	<xsl:template match="Document|@*">
		<Document xmlns="urn:iso:std:iso:202:tech">
			<xsl:apply-templates select="*|text()"/>
		</Document>
	</xsl:template>
 
</xsl:stylesheet>

Ce qui au passage, se simplifie en :

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
	<!-- <xsl:strip-space elements="*"/> -->
	<xsl:output method="xml" indent="yes" encoding="utf-8"/>
 
	<xsl:template match="*">
		<xsl:element name="{local-name()}" namespace="urn:iso:std:iso:202:tech">
			<xsl:copy-of select="@*"/>
			<xsl:apply-templates select="node()"/>
		</xsl:element>
	</xsl:template>
 
</xsl:stylesheet>

16/03/2018, 15h51
PipoWIL

Bonjour,

Oui, en effet votre solution est bonne et est nettement plus élégante que la mienne. Félicitations.
Désolé si je n'avais pas compris la première fois.
Encore merci pour votre précieuse aide.