Afficher des UserForm multilingue

Version imprimable

07/03/2018, 18h06
cschauss

1 pièce(s) jointe(s)

Afficher des UserForm multilingue

Bonjour,
J'aimerais rendre les userforms de mon classeur multilingue.
J'ai créé une feuille UserFormCaptions qui contient les informations nécessaires pour gérer les textes en différentes langues

Colonne A: Nom du UserForm
Colonne B: Nom du contrôle
Colonne C: Type du contrôle
Colonne D: Valeur "Caption" en FR
Colonne E: Valeur "Caption" en DE
Colonne F: Valeur "Caption" en EN
Pièce jointe 357962

J'avais imaginé utiliser la procédure SUB UserForm_Initialize()
1. Je récupère la langue sélectionnée par l'utilisateur
2. Je recherche le nom du formulaire sur la feuille UserFormCaptions (colonne A)
3. Je crée une boucle Do Loop

Mais voilà... Je ne sais pas comment faire pour modifier la valeur Caption des contrôles de ma liste!

Je vous remercie pour votre aide
Amicalement
Charles
07/03/2018, 18h36
Philippe Tulliez

Bonjour,
Pour travailler en mode multi-langue, j'utilise la fonction EQUIV (MATCH pour version anglaise et VBA), tu cherches la langue et EQUIV te renvoie le numéro de la colonne de la langue cherchée
07/03/2018, 21h46
unparia

Bonjour
Tu devrais en profiter pour remettre en cause tes traductions;
Non résident ne se traduit par exemple en anglais pas par "not resident" (qui n'aurait aucun sens en anglais) mais par "non resident"
08/03/2018, 00h08
clementmarcotte

Dire que cela se fait les yeux fermés en VB.net.

Puis dire que toute édition supérieure à Express de Visual Studio, permet de faire des applications compilées pour travailler avec Excel.

Heureusement que je suis habitué de prêcher dans le désert.

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
Private Sub UserForm_Initialize()
ColLangue = 4
ColName = 3
ColUserform = 1
Set f = Worksheets("UserFormCaptions")
dern = f.Cells(Rows.Count, ColUserform).End(xlUp).Row
 For i = 2 To dern
  If f.Cells(i, ColUserform).Value <> Me.Name Then
  Else
   Me.Controls(f.Cells(i, ColName).Value).Caption = f.Cells(i, ColLangue).Value
  End If
 Next
End Sub

08/03/2018, 17h24
cschauss

Citation:

Envoyé par Philippe Tulliez

Bonjour,
Pour travailler en mode multi-langue, j'utilise la fonction EQUIV (MATCH pour version anglaise et VBA), tu cherches la langue et EQUIV te renvoie le numéro de la colonne de la langue cherchée

Bonjour et merci ta réponse, mais mon problème n'est de trouver la colonne correspondant à la langue, mais plutôt de créer la routine pour appliquer la traduction à l'ouverture du formulaire.
08/03/2018, 17h25
cschauss

Citation:

Envoyé par unparia

Bonjour
Tu devrais en profiter pour remettre en cause tes traductions;
Non résident ne se traduit par exemple en anglais pas par "not resident" (qui n'aurait aucun sens en anglais) mais par "non resident"

Merci pour l'information, je corrigerai

Citation:
Envoyé par Docmarti
Code:

1 2 3 4 5 6 7 8 9 10 11 12 13 Private Sub UserForm_Initialize() ColLangue = 4 ColName = 3 ColUserform = 1 Set f = Worksheets("UserFormCaptions") dern = f.Cells(Rows.Count, ColUserform).End(xlUp).Row For i = 2 To dern If f.Cells(i, ColUserform).Value <> Me.Name Then Else Me.Controls(f.Cells(i, ColName).Value).Caption = f.Cells(i, ColLangue).Value End If Next End Sub
Merci Docmarti,
Ce code est bien ce que je cherche.
Mais il y a un petit problème lorsque le type de contrôle est "Multipage"... Est-ce que ces contrôles doivent être traité différemment ?
Merci pour ton aide

08/03/2018, 17h39
Invité

Le multipage comporte des onglets (page) le traitement est forcement différent que ce soit dans excel qu'en vba!
08/03/2018, 17h41
Philippe Tulliez

Bonjour,

Citation:

mais mon problème n'est de trouver la colonne correspondant à la langue, mais plutôt de créer la routine pour appliquer la traduction à l'ouverture du formulaire

Pour afficher le libellé (propriété Caption) dans la langue de l'utilisateur, il faut pourtant connaître le numéro de la colonne où se trouve le libellé de la langue correspondante. En tout cas, c'est comme cela que je pratique depuis des années avec ou sans VBA et cela fonctionne parfaitement.
Et crois moi, les problèmes linguistiques en Belgique, on connaît :P
09/03/2018, 00h01
clementmarcotte

Bonjour Philippe,

J'ai oublié de dire que je ne te visais pas personnellement. Mais, je réalise de plus en plus que de trop pousser à "réinventer l'eau chaude", comme le dis si bien m@rina, alors que des outils mieux adaptés, et qui laissent les utilisateurs à leurs créations, en automatisant l'intendance, sont loin d'être optimales...

Et puis, les choses que l'on fait dans l'urgence, pour se dépanner, ont tendance à se perpétuer. Surtout avec Excel...

Citation:

Envoyé par cschauss

Mais il y a un petit problème lorsque le type de contrôle est "Multipage"... Est-ce que ces contrôles doivent être traité différemment ?

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
ColUserform = 1
ColTypename = 2
ColName = 3
ColLangue = 5
 
 
Set f = Worksheets("UserFormCaptions")
dern = f.Cells(Rows.Count, ColUserform).End(xlUp).Row
 For i = 2 To dern
  If f.Cells(i, ColUserform).Value = Me.Name Then
   If f.Cells(i, ColTypename).Value = "Page" Then
    t = Split(f.Cells(i, ColName).Value, ":") 'Exemple MultiPage1:0 (le nom du Multipage et l'index de la page)
    Me.Controls(t(0)).Pages(t(1)).Caption = f.Cells(i, ColLangue).Value
   Else
    Me.Controls(f.Cells(i, ColName).Value).Caption = f.Cells(i, ColLangue).Value
   End If
  End If
 Next

Code:

1
2
3
4
Pour utiliser le nom du Multipage et le nom de la page "MultiPage1:Page1"
 
  t = Split(f.Cells(i, ColName).Value, ":") '  MultiPage1:Page1 
    Me.Controls(t(0)).Pages(CStr(t(1))).Caption = f.Cells(i, ColLangue).Value

Code:

1
2
3
4
Pour utiliser le nom du Multipage et l'index de la page "MultiPage1:0"
 
 t = Split(f.Cells(i, ColName).Value, ":") '  MultiPage1:0 
    Me.Controls(t(0)).Pages(t(1)).Caption = f.Cells(i, ColLangue).Value

bonjour

Code:

1
2
3
4
5
6
7
8
Private Sub UserForm_Activate()
Dim langue As Single, colonne As Long
langue = (Application.LanguageSettings.LanguageID(msoLanguageIDUI))
Select Case langue
Case 1036, 2060, 11276, 3084, 9228, 12300, 15372, 5132, 13324, 6156, 14348, 58380, 8204, 10252, 4108, 7180: colonne = 3 'francais
Case 1033, 2057, 3081, 10249, 4105, 9225, 15369, 16393, 14345, 6153, 8201, 17417, 5129, 13321, 18441, 7177, 11273, 12297: colonne = 4 'anglais
Case 1031, 3079, 5127, 4103, 2055:  colonne = 5 'allemand
End Select

'les nom de controls etant en colonne 2 par exemple
tu peux soit boucler sur la plage soit boucler sur les controls avec "for each" la boucle for each faisant abstraction de la hiérachie au cas ou des controls aurait un autre parent que le userform c'est plus simple

Code:

1
2
3
4
5
6
7
For Each ctrl In Me.Controls
'cherche ta cellule correspondant au nom veritable du controls en colonne 2 et attribu lui la caption de la colonne de la langue determiné juste avant 
'......
'.......
'......
Next
End Sub

'ou

Code:

1
2
3
for each cel in plage'(plage a determiner)
me.controls(cel.value).caption=cel.offset(x)' x etant  la colonne determiné plus haut moins 1
next

tu pourrais meme ajouter par exemple un language forcé au cas ou un americain viendrais a utiliser le fichier avec un pc francais
bref ;)

1 pièce(s) jointe(s)

un petit test vite fait dans un userform
la langue est automatique en fonction du language system et tu a un bouton pour changer la langue successivement a chaque click

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
Option Explicit
Dim ind As Long
Private Sub CommandButton4_Click()'c'est le bouton pour changer la langue
ind = ind + 1
If ind = 6 Then ind = 3
change_langue ind
End Sub
Private Sub UserForm_Activate()
Dim langue As Single, colonne As Long, plage As Range, cel As Range
ind = 3
langue = (Application.LanguageSettings.LanguageID(msoLanguageIDUI))
Select Case langue
Case 1036, 2060, 11276, 3084, 9228, 12300, 15372, 5132, 13324, 6156, 14348, 58380, 8204, 10252, 4108, 7180: colonne = 3 'francais
Case 1033, 2057, 3081, 10249, 4105, 9225, 15369, 16393, 14345, 6153, 8201, 17417, 5129, 13321, 18441, 7177, 11273, 12297: colonne = 4 'anglais
Case 1031, 3079, 5127, 4103, 2055:  colonne = 5 'allemand
End Select
Set plage = Range("B2:B5").Cells
For Each cel In plage
Debug.Print cel
Me.Controls(cel.Text).Caption = Cells(cel.Row, colonne).Text
Next
End Sub
Private Sub change_langue(indexlangue)
Dim plage As Range, cel As Range
Set plage = Range("B2:B5").Cells
For Each cel In plage
Debug.Print cel
Me.Controls(cel.Text).Caption = Cells(cel.Row, indexlangue).Text
Next
End Sub

Pièce jointe 359107

Afficher UserForm Multilingue - Résolu

Bonjour,

Je tiens à tous vous remercier pour votre aide et le temps que vous m'aurez consacré.
Vous êtes super...

Voici ma Sub.

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
Private Sub UserForm_Initialize()
          Dim wkWord As Worksheet
          Dim intCol As Byte
          Dim rgeCel As Range
          Dim strCap As String
 
10        On Error GoTo UserForm_Initialize_Error
 
20        If GetSetting("XLFisc", "Parameter", "Language") = "" Then SaveSetting "XLFisc", "Parameter", "Language", "FR"
 
30        If GetSetting("XLFisc", "Parameter", "Language") <> "FR" Then
40            Set wkWord = ThisWorkbook.Worksheets("Wording")
50            intCol = wkWord.Range("1:1").Find(What:=GetSetting("XLFisc", "Parameter", "Language"), LookIn:=xlValues, LookAt:=xlWhole).Column - 2
 
60            Set rgeCel = wkWord.Range("B:B").Find(What:="ufBDDisplay_P", LookIn:=xlValues, LookAt:=xlWhole)
70            Do While rgeCel = Me.Name
80                strCap = rgeCel.Offset(0, intCol)
90                If rgeCel.Offset(0, 2) = "Form" Then
100                   If strCap <> "" Then Me.Caption = strCap & " - " & sCopyright
110               ElseIf rgeCel.Offset(0, 2) = "Page" Then
120                   Me.Controls(rgeCel.Offset(0, 3).Value).Pages(rgeCel.Offset(0, 1).Value).Caption = strCap
130               Else
140                   Me.Controls(rgeCel.Offset(0, 1).Value).Caption = strCap
150               End If
160               Set rgeCel = rgeCel.Offset(1, 0)
170           Loop
180       Else
190               Me.Caption = "Base de données - Personnes Privées  -  " & sCopyright
200       End If
 
UserForm_Initialize_Exit:
210       On Error GoTo 0
220       Set wkWord = Nothing
230       Set rgeCel = Nothing
240       Exit Sub
 
UserForm_Initialize_Error:
 
250       MsgBox "Error " & Err.Number & " (" & Err.Description & ") in procedure UserForm_Initialize, line " & Erl & "."
260       Resume UserForm_Initialize_Exit
End Sub

Bonne journée