Extraire une chaîne de caractères dans une macro EXCEL

Version imprimable

02/03/2018, 18h01
Calabianca

Extraire une chaîne de caractères dans une macro EXCEL

Bonjour à tous,

Dans ma macro, j'ai une variable Fichier qui contient cette valeur:
"D:\A graver\Catalogue France"\Bacchus_Dispo_France.xls"

A partir de là, j'aimerais récupérer "Bacchus" dans une autre variable que l'on pourrait appeler Pseudo.

J'ai bien essayé, mais je n'y arrive pas.

Si qqn a les quelques lignes de code pour le faire, cela m'arrangerait.
02/03/2018, 19h30
unparia

Bonjour
Réponse lorsque tu auras bien voulu (c'est un minimum) prendre le soin de mettre ici un copié/collé de ton vrai code.

Citation:

"D:\A graver\Catalogue France"\Bacchus_Dispo_France.xls"

ne saurait en aucun cas être sous VBA l'expression d'une chaîne de caractères.

PS :

Citation:

J'ai bien essayé, mais je n'y arrive pas.

Montre donc ce que tu as "essayé" .;)
02/03/2018, 19h59
kiki29

Salut, une occasion de lire et pratiquer : Manipuler les chaînes de caractères en VB6 et VBA Excel
03/03/2018, 11h17
Calabianca
Bonjour à tous (sauf vous 2),

J'ai trouvé tout seul...
Code:

1 2 3 4 5 Fichier = "D:\A graver\Catalogue France"\Bacchus_Dispo_France.xls" I = InStrRev(Fichier, "\") J = InStr(Fichier, "_") Pseudo = Mid(Fichier, I + 1, J - I - 1)
Et dans la foulée, j'ai même pu récupérer le nom du Pays
Code:

1 2 3 I = InStrRev(Fichier, "_") J = InStr(Fichier, ".xls") Pays = Mid(Fichier, I + 1, J - I - 1)
J'ai fait carrière au Chemin de Fer (Je n'ose plus dire "SNCF") où j'ai pratiqué le métier d'agent-circulation où il faut tout de même avoir l'esprit carré.
Lorsqu'on ne respectait pas les procédures, ce n'était pas un simple "Bug" qui pouvait arriver et on ne manquait pas de nous le rappeler à chaque occasion.
Durant ce grand nombre d'années, j'ai pu fréquenter de temps à autres quelques informaticiens sur lesquels je me suis fait une petite idée.
Néanmoins, intéressé par l'informatique, j'essaie d'apprendre et je ne suis donc qu'un autodidacte mais persévérant.
Je vois que mon préjugé sur votre caste n'était pas infondé...

Merci encore aux 2 "experts éminemment seniors" de m'avoir aidé...
03/03/2018, 11h20
unparia

Incroyable, mais vrai --->>
tu insistes avec cette ineptie en dépit de ce qui t'a été dit :

Code:

Fichier = "D:\A graver\Catalogue France"\Bacchus_Dispo_France.xls"

Citation:

Bonjour à tous (sauf vous 2),

tu peux le garder, ton "bonjour". Il ne m'intéresse pas du tout ;)

Citation:

Je vois que mon préjugé sur votre caste n'était pas infondé...

En ce qui concerne le regard que je pose sur certains dans certains cas : ce n'est pas du tout un "préjugé", mais le résultat de constats.
Bonne chance, donc. :coucou:
03/03/2018, 12h01
kiki29

Salut, à lire

Citation:

J'ai fait carrière au Chemin de Fer (Je n'ose plus dire "SNCF") où j'ai pratiqué le métier d'agent-circulation ...

Moi aussi dans un bureau d'étude du département signalisation à PMP, mais moi j'ai démissionné au bout de 2 ans ...

Citation:

Envoyé par unparia

Incroyable, mais vrai --->>
tu insistes avec cette ineptie en dépit de ce qui t'a été dit :

Code:

Fichier = "D:\A graver\Catalogue France"\Bacchus_Dispo_France.xls"

Sur le fond, bien sûr que si:

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
    ' On sélectionne la dispoliste du correspondant
Fichier = "Vrai"
MsgBox "Sélectionnez la dispoliste de votre correspondant dans la boîte de dialogue qui va s 'ouvrir.", vbOKOnly, "Recherche Dispoliste - " & Pays & " -"
Fichier = Application.GetOpenFilename("Excel Files (*.xls), *.xls")
Workbooks.Open Fichier
    If Fichier = "Faux" Then
    MsgBox "Pas de fichier trouvé!", vbExclamation + vbOKOnly, "Fichier inexistant!"
    Exit Sub
    End If
    If ActiveWorkbook.Sheets(2).Cells(1, 1) <> "LISTE TIMBRES" Then
    MsgBox "Opération abandonnée!", vbExclamation + vbOKOnly, "Fichier sélectionné invalide!"
    ActiveWorkbook.Close SaveChanges:=False
    Exit Sub
    End If
 
    I = InStrRev(Fichier, "\")
    J = InStr(Fichier, "_")
    Pseudo0 = Mid(Fichier, I + 1, J - I - 1)

La valeur qui est qui est retournée dans la variable "Fichier" (Quand on a sélectionné le Bon fichier) est bien de ce style...
Et cela fonctionne...

bonjour

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
Sub test1()
chemin = "D:\A graver\Catalogue France\Bacchus_Dispo_France.xls"
fichier = Mid(chemin, InStrRev(chemin, "\") + 1, Len(chemin))
nom = Split(fichier, "_")(0)
etat = Split(fichier, "_")(1)
pays = Replace(Split(fichier, "_")(2), ".xls", "")
extention = Replace(Split(fichier, "_")(2), pays, "")
 
Debug.Print "fichier =" & fichier
Debug.Print "nom =" & nom
Debug.Print "etat =" & etat
Debug.Print "pays =" & pays
Debug.Print "extention =" & extention
End Sub

résultat dans le debug

Citation:

fichier =Bacchus_Dispo_France.xls
nom =Bacchus
etat =Dispo
pays =France
extention =.xls

ou en simplifiant la coupe

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
Sub test1()
chemin = "D:\A graver\Catalogue France\Bacchus_Dispo_France.xls"
fichier = Mid(chemin, InStrRev(chemin, "\") + 1, Len(chemin))
coupe = Split(Replace(fichier, ".", "_"), "_")
nom = coupe(0)
etat = coupe(1)
pays = coupe(2)
extention = coupe(3)
 
Debug.Print "fichier =" & fichier
Debug.Print "nom =" & nom
Debug.Print "etat =" & etat
Debug.Print "pays =" & pays
Debug.Print "extention = ." & extention
End Sub

ce qui donne le meme resultat sauf que la on generalise l'extention par exemple cela peut etre .tartampion ca marche aussi

Citation:
Envoyé par patricktoulon
bonjour
Code:

1 2 3 4 5 6 7 8 9 10 11 12 13 14 Sub test1() chemin = "D:\A graver\Catalogue France\Bacchus_Dispo_France.xls" fichier = Mid(chemin, InStrRev(chemin, "\") + 1, Len(chemin)) nom = Split(fichier, "_")(0) etat = Split(fichier, "_")(1) pays = Replace(Split(fichier, "_")(2), ".xls", "") extention = Replace(Split(fichier, "_")(2), pays, "") Debug.Print "fichier =" & fichier Debug.Print "nom =" & nom Debug.Print "etat =" & etat Debug.Print "pays =" & pays Debug.Print "extention =" & extention End Sub
résultat dans le debug
Merci beaucoup Patrick,

Je n'avais besoin que du Pseudo et du Pays, Ainsi mes 6 lignes suffisent.
En tout cas, j'ai bien noté votre petite routine pour l'avenir, au cas où.

Encore merci et bonne fin de journée.

OK
il n'y a pas de soucise
perso il m'en faut qu'une (de ligne) et c'est la 3 qui te donne le nom

Code:

1
2
3
4
5
Sub test1()
chemin = "D:\A graver\Catalogue France\Bacchus_Dispo_France.xls"
nom = Split(Mid(chemin, InStrRev(chemin, "\") + 1, Len(chemin)), "_")(0)
Debug.Print "nom =" & nom
End Sub

j'oubliais (il te faut le pays)
moyenant une modif sur le chemin au depart tu utilise la meme ligne (1seule ligne) pour le pays
tout simplement

Code:

1
2
3
4
5
6
7
Sub test1()
chemin = Replace("D:\A graver\Catalogue France\Bacchus_Dispo_France.xls", ".", "_")'ici on remplace le "." par"_" pour arréter le split pay avant le point de l'extention 
nom = Split(Mid(chemin, InStrRev(chemin, "\") + 1, Len(chemin)), "_")(0)' le zero c'est la 1 ère partie donc le nom
pays = Split(Mid(chemin, InStrRev(chemin, "\") + 1, Len(chemin)), "_")(2)'le 2d c'est la 3èeme partie donc le pays 
Debug.Print "nom =" & nom
Debug.Print "pays =" & pays
End Sub

Salut.

Je propose une autre solution par les RegExp
Code:

1 2 3 4 5 6 7 8 9 10 Sub ExtractPseudoCountry() Dim RegExp As Object, Matches As Object Dim Filename As String Set RegExp = CreateObject("VBScript.RegExp") RegExp.Pattern = "\\(\w+)(?:_\w+_)(\w+)\.(?:\w+)$" Set Matches = RegExp.Execute("D:\A graver\Catalogue France\Bacchus_Dispo_France.xls") Debug.Print "Pseudo: " & Matches(0).SubMatches(0) Debug.Print "Pays: " & Matches(0).SubMatches(1) End Sub
Et si tu peux avoir autre chose que des lettres/chiffres dans le pseudo ou le pays, tu modifies simplement le pattern, par exemple comme ceci "\\([^\\]+)(?:_[^\\]+_)([^\\]+)\.(?:[^\\]+)$"

Explications du pattern présenté dans le code

Le $ à la fin du pattern spécifie que c'est la fin de la chaîne qui doit correspondre au pattern. Après avoir fixé cela, on lit les symboles de gauche à droite pour tester la fin de la chaine:

\\ signifie que la fin de chaîne doit commencer par \ (on le double pour qu'il soit considéré comme sa valeur littérale car c'est un méta caractère);
(\w+) signifie qu'on va extraire un premier groupe qui sera renvoyé dans Matches. \w signifie une lettre non accentuée ou un chiffre. + signifie au moins une fois. Les parenthèses forment le groupe. Dans le cas présent, c'est le groupe du pseudo;
(?:_\w+_) signifie la création d'un deuxième groupe qui ne sera pas envoyé dans Matches (à cause du ?: en début de groupe). Ce groupe doit commencer par _ puis doit contenir uniquement des lettres non accentuées ou des chiffres { signification de \w } et doit en contenir au moins un de ces caractères { signification de + } puis se terminer par _ Dans le cas présent, il permet d'isoler le statut;
(\w+) déjà vu plus haut. C'est le troisième groupe du pattern. Il sera renvoyé dans le Matches. Dans le cas présent, il représente le pays;
\. signifie le point. Il est échappé car c'est un méta caractère. L'échappement lui attribue sa valeur littérale et non symbolique. Il n'est pas renvoyé dans Matches car pas entre des ();
(?:\w+) représente le quatrième groupe qui ne sera pas, lui, repris dans le matches à cause du ?: au début du groupe.

On aurait pu inclure \. dans le quatrième groupe et avoir le pattern \\(\w+)(?:_\w+_)(\w+)(?:\.\w+)$.

Nous avons donc deux groupes qui sont renvoyés dans l'objet Matches. Matches contient donc un élément (l'élément 0) qui représente la fin de la chaine (le nom du fichier), et contient également deux submatches ( 0 et 1) contenant les deux groupes renvoyés (le pseudo et le pays). Tu remarqueras que les objets Matches et submatches sont numérotés à partir de 0.

Il conviendrait, pour éviter une erreur d'exécution, de tester matches.count>0. En l'absence du test, on considère que la chaine testée valide le pattern à tous les coups.