Comment positionner le curseur d'un scrollbar

Bonjour le forum,

J'ai un USF dans lequel j'ai un scrollbar. Je sais définir des valeurs mini (1) et maxi (variable) pour ce scrollbar. Ce que je souhaite faire c'est pouvoir positionner le curseur dans une certaine position et non à la valeur 1 par défaut.
J'ai bien essayé scrollbar1.value = la position que je souhaite, mais ça ne marche pas. Le curseur reste à 1.
scrollbar1.ControlFormat.value = la position souhaitée n'est pas accepté.

Bref, je n'ai rien trouvé de probant sur la toile qui me dise comment faire pour que le curseur se positionne comme je le souhaite.

Est-que quelqu'un à une solution ?

D'avance merci pour votre aide.

Bonjour
La propriété Value est celle à utiliser et la seule à utiliser.
Après : tu es seul à savoir ce que tu entends très exactement par "position". S'il s'agit de l'éloignement (en quelle unité logique ?) par rapport à une origine (propriété Left de la scrollbar) --->> calcul arithmétique incluant la propriété Width de la ScrollBar ...
cette phrase :

Citation:

la position souhaitée n'est pas accepté.

est inquiétante. On parle ici de valeur et non de "position".
Et cette valeur est nécessairement comprise entre celle minimum et celle maximum que TU as définies.

1 pièce(s) jointe(s)

Bonsoir,

Exemple

Code:

1
2
3
4
5
6
7
8
9
 
Private Sub UserForm_Initialize()
  n = 5:  début = 1
  For b = 1 To n * 2: Set Lbl(b).GrLabel = Me("Label" & b): Next b
  Me.ScrollBar1.Min = début
  Me.ScrollBar1.Max = [liste].Count - n + 1
  Me.ScrollBar1 = 2     ' positionne en 2
  Affiche
End Sub

Boisgontier
http://boisgontierjacques.free.fr

re

re
bonsoir

la valeur MAX de la scrool vertical de ton userform c'est le top +height du control le plus bas
et même principe pour la scrool horizontale left+width le plus a droite

bonjour,
dans ton "vbe", bouge ta scrollbar et regarde dans les proprietes : scrollLeft et scrollTop

@+JP

@unparia :
quand j'ai dit la position souhaitée n'est pas accepté, en fait j'aurais dû formuler la phrase autrement :
scrollbar1.ControlFormat.value = "la position que je souhaite en valeur numérique" n'est pas acceptée en tant que commande par vba. Désolé pour ne pas avoir été assez précis.

@boisgontierjacques :
merci d'être intervenu. En fait, je me suis fortement inspiré du code de ChoixListBoxPhotoExterne2.xls que j'ai récupéré sur ton site qui est pour moi une référence en la matière. J'en profite pour te remercier mille fois pour l'excellent travail et pour la qualité des informations.

Finalement, l'instruction .ScrollBar1 = "ma valeur" ou .ScrollBar1.Value = "ma valeur" fonctionne très bien, à condition de modifier l'ordre des instructions pour que la valeur soit attribuée avant les .min et .max.
En effet, la définition des valeurs mini et maxi sollicitent le ScrollBar1_Change(). Or, dans le ScrollBar1_Change() il y a une ligne qui redéfinie "ma valeur" = .ScrollBar1 qui n'a pas encore de valeur attribuée. D'où le passage de "ma valeur" à 1. C'est pourquoi je n'arrivais pas à positionner le curseur. En plaçant la valeur de ScrollBar1 en premier, ça fonctionne. Voici mon code au complet :

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
Dim début As Long, NbreAffich As Long, NomPh As String, NbreTrombi As Long
 
Private Sub UserForm_Initialize()
    If Nouveau Then
        NomPh = USFAdherent.ChoixPrenom & "_" & Left(USFAdherent.ChoixNom, 1) & "*.jpg"
    Else
        NomPh = USFAdherent.BoxPrenom & "_" & Left(USFAdherent.BoxNom, 1) & "*.jpg"
    End If
    NomPh = OteAccents(LCase(NomPh)) 'suppression des accents et mise en minuscules (la fonction est ailleurs dans un module)
    début = 1
    NbreTrombi = GetFileList(RepTrombi & "*.jpg")
    NbreAffich = 6
    With Me
      .ScrollBar1 = début 'à mettre AVANT les .min et .max !
      .ScrollBar1.Min = 1
      .ScrollBar1.Max = NbreTrombi - NbreAffich + 1
    End With
End Sub
 
Sub affiche()
  Dim Nom As String, i As Integer
  For i = 1 To NbreAffich
    Nom = FileList(i + début - 1)
    Me("Image" & i).Picture = LoadPicture(RepTrombi & Nom)
    Me("Image" & i).ControlTipText = Nom
    Me("Image" & i).BorderStyle = 0
    Me("Label" & i).Caption = Left(Nom, Len(Nom) - 4)
  Next i
  Me.Repaint
End Sub
 
Private Sub ScrollBar1_Change()
  début = ScrollBar1
  affiche
End Sub
 
Private Sub Image1_Click()
  With USFAdherent
    .BoxFichierTrombi.Value = Me.Image1.ControlTipText
    .Trombi.Picture = LoadPicture(RepTrombi & Me.Image1.ControlTipText)
    .Repaint
  End With
  Unload Me
End Sub
 
Private Sub Image2_Click()
  With USFAdherent
    .BoxFichierTrombi.Value = Me.Image2.ControlTipText
    .Trombi.Picture = LoadPicture(RepTrombi & Me.Image2.ControlTipText)
    .Repaint
  End With
  Unload Me
End Sub
 
Private Sub Image3_Click()
  With USFAdherent
    .BoxFichierTrombi.Value = Me.Image3.ControlTipText
    .Trombi.Picture = LoadPicture(RepTrombi & Me.Image3.ControlTipText)
    .Repaint
  End With
  Unload Me
End Sub
 
Private Sub Image4_Click()
  With USFAdherent
    .BoxFichierTrombi.Value = Me.Image4.ControlTipText
    .Trombi.Picture = LoadPicture(RepTrombi & Me.Image4.ControlTipText)
    .Repaint
  End With
  Unload Me
End Sub
 
Private Sub Image5_Click()
  With USFAdherent
    .BoxFichierTrombi.Value = Me.Image5.ControlTipText
    .Trombi.Picture = LoadPicture(RepTrombi & Me.Image5.ControlTipText)
    .Repaint
  End With
  Unload Me
End Sub
 
Private Sub Image6_Click()
  With USFAdherent
    .BoxFichierTrombi.Value = Me.Image6.ControlTipText
    .Trombi.Picture = LoadPicture(RepTrombi & Me.Image6.ControlTipText)
    .Repaint
  End With
  Unload Me
End Sub
 
Function GetFileList(FileSpec As String) As Variant
 
Dim Filecount As Integer
Dim Filename As String
 
Application.Volatile
 
Filecount = 0
Filename = Dir(FileSpec)
ReDim FileList([TotalListe].Value + 1)
 
If Filename = "" Then Exit Function
 
Do While Filename <> ""
    Filecount = Filecount + 1
    FileList(Filecount) = Filename
    If Filename Like NomPh Then début = Filecount
    Filename = Dir()
Loop
 
If Filecount - début < 5 Then début = Filecount - 5
GetFileList = Filecount
End Function

Problème résolu.
Merci à tous.