ERREUR 424 VBA

Version imprimable

ERREUR 424 VBA

Bonjour à tous,

Malgré mes efforts de recherche (pourtant je suis quelqu'un très curieux), je ne comprends pas pourquoi le message Erreur d'exécution 424 - objet requis apparaît.

Voici mon code :

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
Sub recherche()
Dim feuille As Worksheet
Dim ligne As Range
Dim cherche As Variant
 
Dim pe As Worksheet
Dim ce As Worksheet
Dim c As Worksheet
Dim acepe As Worksheet
Dim fg As Worksheet
Dim cdp As Worksheet
Dim a As Worksheet
Dim rdpece As Worksheet
Dim pece As Worksheet
 
Set pe = Worksheets("Produits d'exploitation")
Set ce = Worksheets("Charges d'exploitation")
Set c = Worksheets("Commissions")
Set acepe = Worksheets("Autres charges et prod expl")
Set fg = Worksheets("Frais Généraux")
Set cdp = Worksheets("Charges de personnel")
Set a = Worksheets("Amortissements")
Set rdpece = Worksheets("Repr de prov et charges exc")
Set pece = Worksheets("Provisions et charges exc")
 
Application.ScreenUpdating = False
Sheets("Acceuil").Range("R2").ClearContents
cherche = InputBox("Quel numéro de compte cherchez-vous?", "Numéro de compte")
 
For Each feuille In Array(pe, ce, c, acepe, fg, cdp, a, rdpece, pece)
For Each ligne In feuille.Rows("1:1000")
If Cells(ligne, 1).Value = cherche Then
feuille.Cells(ligne, 1).Select
End If
Next
Next
Sheets("Acceuil").Range("R2") = Selection.Value
 
If Sheets("Acceuil").Range("R2") = "" Then
MsgBox "Le compte que vous recherchez n'existe pas", vbInformation ' je ne sais pas si le message d'information est bien placé
End If
Application.ScreenUpdating = True
 
End Sub

Comme vous avez compris, je veux rechercher un numéro comptable via INPUTBOX dans l'ensemble des feuilles. Bien entendu un numéro comptable est rattaché à une seule feuille.
Et pour finir, si la recherche n'aboutit pas, je veux avoir le message qui me dit que le compte n'existe pas.

Je vous remercie pour votre aide

Bonjour,

feuille doit être déclaré en tant que Variant, tu ne peux pas faire un For Each en laissant feuille en tant que Worksheet

attention aussi à la ligne 32, est-ce normal de travailler sur la feuille active plutôt que sur feuille.Cells(ligne,1) ?

il n'est pas nécessaire de sélectionner la cellule pour ensuite affecter la valeur de "selection" à ta cellule R2 ... surtout que cette "valeur" est égale à ta variable "cherche"
et pour gagner en efficacité, il serait opportun de prévoir une sortie des tes deux boucles For Each quand tu as trouvé ton occurence, ça ne sert à rien de finir de balayer ta feuille et de balayer ensuite les suivantes
en dernier lieu, plutôt que de boucler ligne par ligne, utilise FIND() pour vérifier si ta valeur existe

à main levée, je verrai quelque chose dans ce style si j'ai bien compris la finalité
Code:

1 2 3 4 5 6 7 8 9 10 11 12 13 14 15 16 17 18 19 20 21 22 23 24 25 26 27 28 29 30 31 32 Sub recherche() Dim feuille As Variant, cherche As Variant Dim ValeurTrouve As Range Dim pe As Worksheet, ce As Worksheet, c As Worksheet, acepe As Worksheet Dim fg As Worksheet, cdp As Worksheet, a As Worksheet, rdpece As Worksheet Dim pece As Worksheet Set pe = Worksheets("Produits d'exploitation") Set ce = Worksheets("Charges d'exploitation") Set c = Worksheets("Commissions") Set acepe = Worksheets("Autres charges et prod expl") Set fg = Worksheets("Frais Généraux") Set cdp = Worksheets("Charges de personnel") Set a = Worksheets("Amortissements") Set rdpece = Worksheets("Repr de prov et charges exc") Set pece = Worksheets("Provisions et charges exc") Application.ScreenUpdating = False cherche = InputBox("Quel numéro de compte cherchez-vous?", "Numéro de compte") For Each feuille In Array(pe, ce, c, acepe, fg, cdp, a, rdpece, pece) Set ValeurTrouve = feuille.Range("A1:A1000").Find(cherche, , xlValues, xlWhole) If Not ValeurTrouve Is Nothing Then Exit For Next feuille If Not ValeurTrouve Is Nothing Then Sheets("Acceuil").Range("R2") = cherche Else MsgBox "Le compte que vous recherchez n'existe pas", vbInformation End If Application.ScreenUpdating = True End Sub
et j'éviterai même de passer par tes variables Worksheet pour directement construire un Array contenant mes Worksheets("toto"), mais ça c'est une question d'envie, ça ne change rien au procédé

ERREUR 13 VBA

Merci joe.levrai.

Par contre, un nouveau message d'erreur apparaît avec le code (Erreur d'exécution 13 - incompatibilité de type):

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
Sub recherche()
Dim feuille As Variant
Dim ValeurTrouve As Range
Dim cherche As Variant
 
Set pe = Worksheets("Produits d'exploitation")
Set ce = Worksheets("Charges d'exploitation")
Set c = Worksheets("Commissions")
Set acepe = Worksheets("Autres charges et prod expl")
Set fg = Worksheets("Frais Généraux")
Set cdp = Worksheets("Charges de personnel")
Set a = Worksheets("Amortissements")
Set rdpece = Worksheets("Repr de prov et charges exc")
Set pece = Worksheets("Provisions et charges exc")
 
Application.ScreenUpdating = False
Sheets("Acceuil").Range("R2").ClearContents
cherche = InputBox("Quel numéro de compte cherchez-vous?", "Numéro de compte")
 
For Each feuille In Array(pe, ce, c, acepe, fg, cdp, a, rdpece, pece)
Set ValeurTrouve = feuille.Range("A1:A1000").Find(cherche, xlValues, xlWhole)
If Not ValeurTrouve Is Nothing Then Exit For
Next feuille
If Not ValeurTrouve Is Nothing Then
MsgBox "Le numéro " & cherche & "a été trouvé", vbInformation
Else
MsgBox "Le compte que vous recherchez n'existe pas", vbInformation
End If
Application.ScreenUpdating = True
 
End Sub

07/10/2017, 10h45
joe.levrai

Bonjour,

c'est les aléas d'écrire à la volée

j'ai oublié une virgule dans la déclarations des paramètres de find

Code:

Set ValeurTrouve = feuille.Range("A1:A1000").Find(cherche, , xlValues, xlWhole)

Citation:

Envoyé par joe.levrai

Bonjour,

c'est les aléas d'écrire à la volée

j'ai oublié une virgule dans la déclarations des paramètres de find

Code:

Set ValeurTrouve = feuille.Range("A1:A1000").Find(cherche, , xlValues, xlWhole)

Bonjour Joe.Levrai,

Il n'y a plus de message d'erreur.

Par contre j'ai une derrière chose à demander avant de clôturer cette discussion, après avoir chercher le compte et s'il a bien été trouvé, j'aimerais afficher directement la feuille concernée (mieux avec la cellule sélectionnée).
Code:

1 2 3 4 5 6 7 8 9 10 11 12 13 14 15 16 17 18 19 20 21 22 23 24 25 26 27 28 29 30 Sub recherche() Dim feuille As Variant Dim ValeurTrouve As Range Dim cherche As Variant Set pe = Worksheets("Produits d'exploitation") Set ce = Worksheets("Charges d'exploitation") Set c = Worksheets("Commissions") Set acepe = Worksheets("Autres charges et prod expl") Set fg = Worksheets("Frais Généraux") Set cdp = Worksheets("Charges de personnel") Set a = Worksheets("Amortissements") Set rdpece = Worksheets("Repr de prov et charges exc") Set pece = Worksheets("Provisions et charges exc") Application.ScreenUpdating = False cherche = InputBox("Quel numéro de compte cherchez-vous?", "Numéro de compte") For Each feuille In Array(pe, ce, c, acepe, fg, cdp, a, rdpece, pece) Set ValeurTrouve = feuille.Range("A1:A1000").Find(cherche, , xlValues, xlWhole) If Not ValeurTrouve Is Nothing Then Exit For Next feuille If Not ValeurTrouve Is Nothing Then MsgBox "Le compte que vous recherchez a été trouvé", vbInformation Else MsgBox "Le compte que vous recherchez n'existe pas", vbInformation End If Application.ScreenUpdating = True End Sub

09/10/2017, 12h50
RyuAutodidacte

bonjour,

Essayes :

Code:

Application.Goto ValeurTrouve, True
09/10/2017, 12h59
MolikDLuffy

Citation:

Envoyé par RyuAutodidacte

bonjour,

Essayes :

Code:

Application.Goto ValeurTrouve, True

Je dois le mettre à quel niveau?

Car j'ai essayé de le mettre après le MSGBOX et il y a le message d'erreur 1004

Chez moi a a marché :

Code:

1
2
3
4
5
6
7
8
Next feuille
If Not ValeurTrouve Is Nothing Then
MsgBox "Le compte que vous recherchez a été trouvé", vbInformation
Application.Goto ValeurTrouve, True
Else
MsgBox "Le compte que vous recherchez n'existe pas", vbInformation
End If
Application.ScreenUpdating = True

Citation:
Envoyé par RyuAutodidacte
Chez moi a a marché :
Code:

1 2 3 4 5 6 7 8 Next feuille If Not ValeurTrouve Is Nothing Then MsgBox "Le compte que vous recherchez a été trouvé", vbInformation Application.Goto ValeurTrouve, True Else MsgBox "Le compte que vous recherchez n'existe pas", vbInformation End If Application.ScreenUpdating = True
Moi ça ne marche pas... Bizarre.

Actuellement j'ai x feuilles masquées et j'exécute cette macro sur la seule feuille non masquée intitulée "Accueil"

Est-ce que ça peut-être à cause de ça?

09/10/2017, 13h20
MolikDLuffy

Problème Résolu

Comme je le pensais, il faut que j'affiche les feuilles concernées pour que application.goto fonctionne

Merci de ton aide

Bonne semaine et à bientôt
09/10/2017, 13h30
RyuAutodidacte

Ok
J'avais pas fait attention que t'es feuilles étaient masquées,
En effet il faut afficher la feuille concernée avant
09/10/2017, 13h36
MolikDLuffy

Citation:

Envoyé par RyuAutodidacte

Ok
J'avais pas fait attention que t'es feuilles étaient masquées,
En effet il faut afficher la feuille concernée avant

Tu ne pouvais pas savoir car je ne l'avais pas mentionné :oops:

Merci encore pour ton aide précieuse. J'ai mis des pouces ;)