Filtre en cascade Excel VBA

Version imprimable

31/08/2017, 15h32
Maxado56

6 pièce(s) jointe(s)

Filtre en cascade Excel VBA

Bonjour à tous,
Merci encore à tous pour votre aide ces derniers temps

J'ai un outil que j'ai developpé dans mon entreprise, qui me sert à effectuer les réceptions de matières premières (3 fournisseurs, 11 produits différents, 3 agents)
Bien sûre j'ai mis des valeurs erronnés pour garder une certaine confidentialité.

Mon outil fonctionne mais j'aimerais bien l'optimiser encore plus
En effet je ne maîtrise pas les filtres en cascade sur une feuille Excel et sur un formulaire Userform.

1/ (Feuille Commandes)Je voudrais que lorsque l'on rentre via la liste deroulante le nom du fournisseur, que sur la liste deroulante du type de produit, n'apparaissent seulement les produits de ce fournissseur (actuellment tous les produits apparaissent)
Pièce jointe 308092

(Feuille Produits)J'ai une base qui existe pour faire la correspondace Fournisseur - Produit
Pièce jointe 308094

2/ (Feuille Enregsitrement) J'ai crée un Userform pour que les agents rentrent les différentes réceptions, en appuyant sur le bouton "Enregistrer" et qui agrémente cette même feuille "Enregsitrement". Mon souhait serait que lorsqu'il rentre via la liste déroulante le type de produit, que sur la liste déroulante du N° de lot, n'apparaissent seulement les n° de lots de ce type de produit.
Pièce jointe 308099

(Feuille Commandes) En ce moment, la liste propose tous les N° de lot de la feuille "Commandes", mais je voudrais qu'il prenne en compte le type de produit pour affiner la recherche. Ici, c'est les propriétés de l'Userform1, puis ComboBox1 qui sont impactées
Pièce jointe 308112
Le code de la combox :
Pièce jointe 308119

Voici le fichier pour avoir plus d'informations
Pièce jointe 308124

PS: Vous pourrez voir que lorsque l'on fait un enregsitrement sur le formulaire, c'est assez long, je ne sais pas ce qui est lent dans l'userform...

Merci d'avance de votre aide précieuse...

Bien cordialement
Bonne journée

Maxado 56
31/08/2017, 16h12
parmi

Bonjour,

Désolé, mais je n'ouvre pas les fichiers joints avec macros...

Lorsque tu sélectionnes un item dans le combobox1 (par exemple), tu vides le 2e et tu boucles pour le remplir.
Tu vérifies donc si ta liste de données correspond à la valeur du 1er combobox.
C'est tout.

2 pièce(s) jointe(s)

Bonjour,

Il y au moins 2 raisons:
-La méthode de tri
-Il faut trier dans un Array() et non pas sur le ComboBox

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
 
Option Compare Text
Private Sub UserForm_Initialize()
  Dim temp()
  Set f = Sheets("BD")
  Set champ = f.Range("A2:A" & f.[A65000].End(xlUp).Row)
  temp = Application.Transpose(champ)
  Tri temp, LBound(temp), UBound(temp)
  Me.ComboBox1.List = temp
End Sub
 
Sub Tri(a(), gauc, droi)          ' Quick sort
 ref = a((gauc + droi) \ 2)
 g = gauc: d = droi
 Do
     Do While a(g) < ref: g = g + 1: Loop
     Do While ref < a(d): d = d - 1: Loop
     If g <= d Then
       temp = a(g): a(g) = a(d): a(d) = temp
       g = g + 1: d = d - 1
     End If
 Loop While g <= d
 If g < droi Then Call Tri(a, g, droi)
 If gauc < d Then Call Tri(a, gauc, d)
End Sub

Il est préférable d'alimenter un ComboBox par List ou Column plutôt qu'avec Additem

Boisgontier
http://boisgontierjacques.free.fr

01/09/2017, 09h51
Maxado56

Suite sujet

Bonjour,
Merci tout d'abord pour vos réponses rapides,

1/ Cher parmi, je comprend votre logique mais est ce qu'il y a un code VBA lié à cette logique ?

2/ Cher boisgontierjacques, j'ai essayé de transposer votre macro combobox sur mon outil, mais je n'ariive pas du tout à la faire fonctionner, je suis un peu perdu...

Il y a d'autres méthodes pour remplir un combobox sans doublon, mais bon... je te propose celle-ci

Donc, un Userform avec 2 combobox nommés par défaut et des données en Feuil1, en colonnes A et B

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
Private Sub ComboBox1_Click()
    Dim I As Long, nbLignes As Long
 
    With Sheets("Feuil1")
        nbLignes = .Cells(.Rows.Count, "A").End(xlUp).Row
        Me.ComboBox2.Clear
 
        For I = 2 To nbLignes
            If .Range("A" & I) = Me.ComboBox1.Text Then
                Me.ComboBox2.AddItem .Range("B" & I)
            End If
        Next
    End With
End Sub
 
Private Sub UserForm_Initialize()
    Dim I As Long, nbLignes As Long
 
    With Sheets("Feuil1")
        nbLignes = .Cells(.Rows.Count, "A").End(xlUp).Row
        For I = 2 To nbLignes
            'Vérifie que la donnée n'est pas déjà dans la liste
            If Not IsInCombo(.Range("A" & I), Me.ComboBox1) Then
                Me.ComboBox1.AddItem .Range("A" & I).Value
            End If
        Next
    End With
End Sub
 
Function IsInCombo(Valeur, Combo As Control) As Boolean
    Dim I As Long
 
    For I = 0 To Combo.ListCount - 1
        If Combo.List(I) = Valeur Then
            IsInCombo = True
            Exit Function
        End If
    Next
End Function

1 pièce(s) jointe(s)

Bonjour,

>j'ai essayé de transposer votre macro combobox sur mon outil, mais je n'ariive pas du tout à la faire fonctionner, je suis un peu perdu...

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
 
    Dim f, Tbl()
    Set f = Sheets("Commandes")
    Tbl = Application.Transpose(f.Range("C2:C" & f.[C65000].End(xlUp).Row).Value)
    'Tri le contenu du ComboBox par ordre alphabétique
    Tri Tbl, LBound(Tbl), UBound(Tbl)
    Me.ComboBox3.List = Tbl
    For i = 1 To 3 'on lance une boucle de valeur mini 1 et maxi 8
    Me.Controls("TextBox" & i).Visible = True 'affiche les données dans les textbox
  Next i
End Sub
 
    Sub Tri(a(), gauc, droi)          ' Quick sort
      Dim ref, g, d, temp
      ref = a((gauc + droi) \ 2)
       g = gauc: d = droi
       Do
         Do While a(g) < ref: g = g + 1: Loop
         Do While ref < a(d): d = d - 1: Loop
         If g <= d Then
           temp = a(g): a(g) = a(d): a(d) = temp
           g = g + 1: d = d - 1
         End If
       Loop While g <= d
       If g < droi Then Call Tri(a, g, droi)
       If gauc < d Then Call Tri(a, gauc, d)
     End Sub

Boisgontier
http://boisgontierjacques.free.fr

01/09/2017, 16h48
Maxado56

4 pièce(s) jointe(s)

Mise en application sur la macro

Bonjour,
Merci pour vos réponses,

La macro ne s'adapte pas à mon formulaire, j'explique un peu plus précisément mon besoin.

Voici le formulaire avec les deux ComboBox en question
Pièce jointe 308371

Voici la base de données sur lesquelles les ComboBox vont s'alimenter
- ComboBox2 --> Colonne B
- ComboBox3 --> Colonne C

Pièce jointe 308377

Je voudrais que lorsque que l'on remplie la ComboBox2 (un des 11 Types de Produits) (Colonne B), ils n'apparaissent ensuite sur la ComboBox3 (Colonne C) seulement les N° de lot du Type de produit sélectionné en ComboBox2. Et ce tri serait fait d'après le tableau ci-dessus avec les colonnes B et C.
Actuellement, sur la ComboBox3, tous les N° de lot apparaissent, ce qui est pas très pratique

Voici le code associé aux ComboBox 2 et ComboBox3:
Pièce jointe 308379

Je redonne le fichier:
Pièce jointe 308381

1 pièce(s) jointe(s)

Bonjour,

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
 
Private Sub ComboBox2_Click()
    Dim f, BD(), Tbl(), i, n
    Set f = Sheets("Commandes")
    BD = f.Range("a2:C" & f.[a65000].End(xlUp).Row).Value
    For i = LBound(BD) To UBound(BD)
      If BD(i, 2) = Me.ComboBox2 Then n = n + 1: ReDim Preserve Tbl(1 To n): Tbl(n) = BD(i, 3)
    Next i
    Me.ComboBox3.Clear
    If n > 0 Then
      'Tri le contenu du ComboBox par ordre alphabétique
      Tri Tbl, LBound(Tbl), UBound(Tbl)
      Me.ComboBox3.List = Tbl
    End If
End Sub
 
    Sub Tri(a(), gauc, droi)          ' Quick sort
      Dim ref, g, d, temp
      ref = a((gauc + droi) \ 2)
       g = gauc: d = droi
       Do
         Do While a(g) < ref: g = g + 1: Loop
         Do While ref < a(d): d = d - 1: Loop
         If g <= d Then
           temp = a(g): a(g) = a(d): a(d) = temp
           g = g + 1: d = d - 1
         End If
       Loop While g <= d
       If g < droi Then Call Tri(a, g, droi)
       If gauc < d Then Call Tri(a, gauc, d)
     End Sub

Boisgontier
http:/boisgontierjacques.free.fr