[VB6]Envoi de page html dans un courriel

Version imprimable

28/06/2006, 16h09
fearless

[VB6]Envoi de page html dans un courriel

Bonjour

- J'ai une page HTML sur un serveur distant.
- J'ai des images aussi sur le serveur.

J'aimerais pouvoir envoyer ma page HTML par courriel en code VB6. J'utilise Outlook comme messagerie.

J'ai configurer Outlook en mode HTML

Ce que j'ai essayer jusqu'ici qui n'a pas fonctionner ;

- J'ai écris le code HTML dans le message du courriel(je vois seulement le texte)
- J'ai placer en pièces jointes la page HTLM (je ne la vois pas directement ds le message ...)

Alors, avez-vous d'autres idées pour pouvoir faire automatiquement comme dans Explorer ;
Fichier - Envoyer - Page de courrier électronique.

P.S en code j'ouvre deja Outlook, je place le courriel, le sujet, donc pas de problemes de ce coter !

Merci a tous !

bonjour

j'espere que cet exemple pourra t'aider

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
Sub envoirPageHTML_CorpsMessageOutlook()
'Necessite d'Activer la reference Microsoft Outlook xx.x Object Library
Dim OlApp As New Outlook.Application
Dim OlItem As Outlook.MailItem
Dim S As String
'necessite d'Activer la reference Microsoft Internet Controls
Dim IE As InternetExplorer
 
Set IE = CreateObject("InternetExplorer.Application")
 
With IE
    .Visible = False
    .Navigate "http://www.developpez.com"
    Do Until .ReadyState = READYSTATE_COMPLETE
    DoEvents
    Loop 'attend la fin du chargement
End With
 
S = IE.document.documentElement.innerHTML
DoEvents
 
IE.Quit
Set IE = Nothing
 
Set OlItem = OlApp.CreateItem(olMailItem)
 
With OlItem
    .To = "destinataire@mail.fr"
    .Subject = "le titre"
    .HTMLBody = S
    .Display
    .Save
    .Send
End With
 
End Sub

bonne soiree
michel

28/06/2006, 18h02
ThierryAIM

Hormis qu'il manque peut-être

Code:

Private Const READYSTATE_COMPLETE=&H4

:bravo:
28/06/2006, 18h12
SilkyRoad

bonjour Thierry

pour ma part, j'active la reference "Microsoft Outlook xx.x Object Library"
et dans ce cas la déclaration de la constante n'est pas necessaire ...;o)

bonne soiree
michel
28/06/2006, 19h04
fearless

Wow merci !

Tout fonctionne a merveille !