[awk] Utiliser un fichier de sortie comme fichier d'entrée dans un script bash

Bonjour,

je suis nouvelle sur le site et j'espere être au bon endroit.

Je dois écrire un script sous Bash et je n'arrive pas trouver mon problème sur internet. Je vous explique: J'ai deux lignes avec awk et j'aimerai lire mon output de ma premiere commande et executer ma deuxieme ligne avec cet output (qui est donc mon input ici).

Premiere ligne: je veux modifier ma colonne 2 du fichier1 en changeant les "_" par "-". Ma ligne marche :

Code:

---

awk 'BEGIN {FS=OFS=";"} {gsub(/_/,"-",$2)}1 file1.txt

---

Deuxieme ligne: je compare deux fichiers differents dont mon fichier1 modifié précédement. Ma ligne marche aussi :

Code:

---

awk 'BEGIN {FS=OFS=";"} FNR==NR {a[$2]=$0; next}{print $0,a[$2]?a[$2]:"NA"}' file2.txt file1.txt >file3.txt

---

Mais j'aimerai pouvoir le faire dans un script en obtenant toutes mes modifications dans mon fichier3.

J'aurai par la suite d'autre modifications à faire sur ma colonne2 du fichier1 donc j'aimerai pouvoir à chaque fois reutiliser mon fichier de sortie..

Je n'arrive pas à trouver sur internet comment lire mon output dans un script et le reutiliser dans ma deuxieme commande.

Quelqu'un pour m'aider??

Merci Beaucoup !!!

Bonjour et Bienvenue,

Pense à utiliser les balise code ( bouton avec le # ) pour tes lignes de code ;)

Sinon, pour répondre à ta question, ton problème est simple, dans l'ordre, les actions à réaliser:
-Traiter le fichier2: FNR==NR {a[$2]=$0; next}.
-Modification du fichier1 à la volée: {gsub(/_/,"-",$2)}.
-Intersection des 2 fichiers: {print $0,a[$2]?a[$2]:"NA"}.

Bon là, tout est écrit et faisable en un seul awk...

Merci beaucoup pour ta rapide réponse !!

Deux petites questions me taraude: J'ai du mal à visualiser comment on sait que ta deuxieme ligne à la volèe ne s'applique qu'a mon fichier1? et si je veux aussi passée cette même colonne en majuscule, je mets le code à la suite aussi, juste avant de comparer mes deux fichiers?

Merci beaucoup en tout cas !!

J'ai du mal à comprendre ton incompréhension, je n'ai fait que te donner l'ordre dans lequel exécuter tes propres lignes de code.
Il semblerait que tu n'as pas compris le rôle des variables FNR et [C]NR[C] ainsi que l'utilisation que tu en fais.
Si on fait simple:
Awk est un automate qui exécute séquentiellement des blocs de codes selon la véracité d'une condition de chaque ligne du flux en entrée, ce qui donne par exemple:

Code:

---

1 2 3 4 5 6

BEGIN{code} #Ici on exécute du code avant la lecture de la toute première ligne de flux COND1 {code1} #Ici, une ligne de flux est dans $0 et on exécute le code1 si la COND1 est vrai COND2 {code2} #On exécute code2 si COND2 est vrai ... ... END{code} #Ici, on exécute du code lorsque tous les flux sont épuisés

---

Les blocs BEGIN en END sont facultatifs bien sûr et dans tous les cas BEGIN sera toujours exécuté ainsi que END sauf sortie prématuré du programme suite à une exception ou l'instruction exit.
Après tu as des instructions tels que next, qui permet de passer au cycle suivant avec une nouvelle ligne de flux (ou d'aller directement au bloc END, si on avait déjà lu la dernière ligne de tous les flux).
La variable FNR est le compteur de ligne du flux en cours (chaque fichier est un flux)
La variable NR est le compteur de ligne traité par le programme (indépendamment de chaque flux)
Et donc, la comparaison FNR==NR nous permet de savoir que nous sommes en train de lire le premier (et uniquement le premier) flux (ou fichier si tu préfères).

Merci beaucoup effectivement le FNR==NR m'avait un peu échapé.. C'est beaucoup plus clair.

et si je veux rajouter une ligne pour les majuscules toujours sur ma colonne 2 du fichier 1, je fais un truc comme ca? je peux rajouter autant de fonction que je veux?
J'ai essayé j'ai une erreur de syntaxe quelque part..

Code:

---

awk 'BEGIN {FS=OFS=";"} FNR==NR {a[$2] = $0; next} {gsub(/_/,"-",$2)} {tolupper($2)} {print $0,a[$2]?a[$2]:"NA"}' $File2 $File1 > file3.csv

---

En tout cas merci beaucoup pour ton aide, pas facile de s'y mettre seule mais challenging !!!

tolupper n'existe pas, c'est toupper, et cette fonction ne modifie pas la chaine, elle renvoie une copie, donc c'est $2=toupper($2).
et autant centraliser dans un même bloc de code quand ça concerne plusieurs actions sans conditions particulières pour une même ligne, donc:

Code:

---

awk 'BEGIN {FS=OFS=";"} FNR==NR {a[$2] = $0; next} {gsub(/_/,"-",$2)} {tolupper($2)} {print $0,a[$2]?a[$2]:"NA"}' $File2 $File1 > file3.csv

---

devient:

Code:

---

awk 'BEGIN {FS=OFS=";"} FNR==NR {a[$2] = $0; next} {gsub(/_/,"-",$2);$2=toupper($2);print $0,a[$2]?a[$2]:"NA"}' $File2 $File1 > file3.csv

---

Super, Ca marche !!!

Merci beaucoup, je commence à comprendre le fonctionnement !!!

Thanks