[VBA-E]Creer une bd access

Version imprimable

coucou,

apres un recherche j'ai trouvé comment remplir une table Access

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
Sub OuvrirAccess()
 
    'necessite d'activer la reference
    'Microsoft ActiveX Data Objects 2.0 Library
    Dim Conn As New ADODB.Connection
    Dim rsT As New ADODB.Recordset
 
        With Conn
            .Provider = "Microsoft.JET.OLEDB.4.0"
            .Open ThisWorkbook.Path & "\bd1.mdb"
        End With
 
        With rsT
            .ActiveConnection = Conn
            .Open "Table1", LockType:=adLockOptimistic
        End With
 
        With rsT
            .AddNew
            .Fields("clé").Value = Sheets(1).Cells(1, 1).Value
            .Update
        End With
 
        rsT.Close
        Set rsT = Nothing
        Conn.Close
        Set Conn = Nothing
 
End Sub

je voudrai savoir s'il est possible sous excel de creer un BD automatiquement ou au moins une table avec ses champs car ca je n'ai pas reussi à trouver :?

Merci d'avance

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
Private Sub Command1_Click()
'Creer une base par ADOX
'-- Cocher la référence :Microsoft ADO Ext 2.x for dll
Dim NewBase As ADOX.Catalog
Dim NewTable As ADOX.Table
 
    Set NewBase = New ADOX.Catalog
    NewBase.Create "Provider=Microsoft.Jet.OLEDB.4.0;" & _
                   "Data Source=c:\base.mdb;" & _
                   "Jet OLEDB:Engine Type=5;"
 
    Set NewTable = New ADOX.Table
    With NewTable
        .Name = "Table1"
        .Columns.Append "Champ1", adInteger
        .Columns.Append "Champ2", adWChar, 50
    End With
    NewBase.Tables.Append NewTable
    Set NewTable = Nothing
    Set NewBase = Nothing
End Sub

26/06/2006, 14h12
Elstak

hmm rien à ajouter...

si peut etre quand meme : merci :mouarf:
26/06/2006, 14h22
Commodore

peut etre ceci pourra t'aider. c'est un bon exemple de manipulation d'access depuis excel.

[edit] :mouarf: le temps que je zippe ya eu plein de reponses [/edit]
26/06/2006, 14h30
Elstak

Oué en effet, t'es hyper long !!

non je plaisante, j'ai regardé et ptet que ca m'aidera

merci ;)