Comment formater et calculer des textbox créées dynamiquement?

Version imprimable

03/07/2017, 15h46
jppouma

Comment formater et calculer des textbox créées dynamiquement?

Bonjour la communauté,
J’ai un petit (GROS !!!) souci de formatage et de calcul de textbox dans un UserForm.
Je vous explique…
Je crée dynamiquement des textbox par appui sur un bouton CommandButton qui me génère une ligne de textbox dans l’ordre : Nom de la société, Monant HT, Code TVA (qui est un combobox), TVA et Montant TTC.
J’utilise pour créer ces rubriques dynamiques, un module de classe qui pour le coût fonctionne très bien…
Je souhaite pouvoir, après chaque saisie d’un textbox (en l’occurrence Montant HT) pouvoir formater - certaines de mes textbox, avec ce format : "### ### ##0.00 €".
De même, je souhaiterai effectuer – toujours après saisie (du combobox Code TVA cette fois), un calcul simple (du type Montant TTC = Montant HT +TVA – avec un taux de TVA donné par le combobox Code TVA ).
J'ai bien pensé à utiliser un module de classe utilisant des "Property Get et Set", mais je ne vois pas comment déclencher ce module de classe.
Mon souci principal est le déclenchement de l’action après saisie (AfterUpdate) puisque cette commande n’est pas disponible dans les modules de classe.
Question… COMMENT FAIRE ???
Si parmi cette formidable communauté quelqu’un a une idée… je suis preneur.
Merci par avance pour vos réponses.
Jppouma.

Bonjour,

rien ne t'empêche, lors de la création d'un nouveau textbox, de le relier à un module de classe.
Après, pour gérer le format, tu peux utiliser les évènements "KeyPress" ou "Change".

Ci - dessous un petit exemple de ce que j'avais fait à mes débuts pour gérer un textbox au format Euros (la fonction AfficherAlerte gérait l'affichage d'un message d'alerte dans un labelbox):

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
Option Explicit
Public WithEvents MonTextbox As MSForms.TextBox
Private Sub MonTextbox_KeyPress(ByVal KeyAscii As MSForms.ReturnInteger)
 
    'Transforme le "." en ","
    If KeyAscii = 46 Then KeyAscii = 44
 
    'Refuse les caractères autres que numériques (ou virgule)
    If KeyAscii <> 44 And (KeyAscii < 48 Or KeyAscii > 57) Then
        KeyAscii = 0
        MonTextbox.BackColor = &HFF&
        Call AfficherAlerte("Caractère interdit")
        Exit Sub
    End If
 
    'Refuse la saisie d'une deuxième virgule
    If KeyAscii = 44 And InStr(MonTextbox, ",") > 0 Then
        KeyAscii = 0
        MonTextbox.BackColor = &HFF&
        Call AfficherAlerte("Une seule virgule possible")
        Exit Sub
    End If
 
    'Refuse une virgule si le textbox est vide
    If KeyAscii = 44 And Len(MonTextbox) = 0 Then
        KeyAscii = 0
        MonTextbox.BackColor = &HFF&
        Call AfficherAlerte("Pas de virgule si le textbox est vide")
        Exit Sub
    End If
 
    'Empêche de saisir plus de 10 chiffres avant la virgule
    If KeyAscii <> 44 Then
        If MonTextbox <> "" Then
            If Len(Int(MonTextbox)) > 9 Then
            If MonTextbox.SelStart < InStr(MonTextbox, ",") Or InStr(MonTextbox, ",") = 0 Then
                KeyAscii = 0
                MonTextbox.BackColor = &HFF&
                Call AfficherAlerte("Pas plus de 10 chiffres avant la virgule")
                Exit Sub
            End If
        End If
        End If
    End If
 
    'Empêche de saisir plus de 2 chiffres après la virgule
    If Left(Right(MonTextbox.Value, 3), 1) = "," And MonTextbox.SelStart > Len(MonTextbox.Value) - 3 Then
        KeyAscii = 0
        MonTextbox.BackColor = &HFF&
        Call AfficherAlerte("Pas plus de 2 chiffres après la virgule")
        Exit Sub
    End If
 
 
End Sub
Private Sub MonTextbox_Change()
    MonTextbox.BackColor = &H80000005
    Call ResetAlerte
End Sub

05/07/2017, 07h52
jppouma

Merci pour ton aide GeoTrouvePas.
Comme tu me le suggères, je relie bien mes textbox à un module de classe...
Mais utiliser "Change" lors de la saisie n'est pas pertinent. Dès le premier caractère tapé, ca me formate ma textbox du style "1,00 €258" alors que j'aurais souhaité avoir "1 258,00 €".
Je vois pas bien comment faire avec "KeyPress".
Pour ce qui est du contrôle des caractères, j'avais déjà une petite procédure, mais merci quand même pour tes propositions.
Je tourne en rond sur mon problème... et pas de solution en vue.
jppouma.
05/07/2017, 14h37
patricktoulon

re
je l'ai déjà démontré comment gérer le format évolutif lorsque qu'on tape le chiffre
sert toi du tag pour mémoriser le chiffre tapé tel quel et fait le formatage du chiffre du tag dans le value

pour l'évolution c'est simple c'est le chr(keyascii)du keypress
je te fait un exemple quand je rentre

peu etre dans ce genre la
exemple

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
Private Sub TextBox1_KeyPress(ByVal KeyAscii As MSForms.ReturnInteger)
    If KeyAscii = 46 Then KeyAscii = 44
    TextBox1.Tag = TextBox1.Tag & Chr(KeyAscii)
    TextBox1.Value = Format(TextBox1.Tag, "### ### ##0.00 €")
End Sub
Private Sub TextBox1_KeyUp(ByVal KeyCode As MSForms.ReturnInteger, ByVal Shift As Integer)
    If InStr(TextBox1.Value, "€") > 0 Then TextBox1 = Split(TextBox1.Value, "€")(0) & "€"
End Sub
Private Sub TextBox1_KeyDown(ByVal KeyCode As MSForms.ReturnInteger, ByVal Shift As Integer)
    If KeyCode = 8 Then ' si on tape la touche back
       TextBox1.Tag = Mid(TextBox1.Tag, 1, Len(TextBox1.Tag) - 2)
     TextBox1.Value = Format(TextBox1.Tag, "### ### ##0.00 €")
        End If
End Sub

05/07/2017, 21h20
jppouma

Merci pour ta réponse patricktoulon,
Je test ta méthode demain.
Il reste la problématique que j'évoquais dans mon message initial, à savoir le calcul des textbox... "AfterUpdate".
Si il te reste quelques idées sur le sujet...
Encore merci.
jppouma.

Implémentation des événements Enter, Exit, BeforeUpdate et AfterUpdate

Bonjour,

Je t'ai bricolé un exemple d'implémentation de ces événements.

ouvre un nouveau classeur
Insère un UserForm (UserForm1)
pose sur cet Userform (vers le haut) un bouton de commande (CommandButton1)
Insère un module de classe (Classe1)

Ensuite...
Le code de l'UserForm :

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
Option Explicit
 
Dim Cl(4) As New Classe1
 
Private Sub CommandButton1_Click()
Dim i&, Ctrl As Control
 
    For i = 1 To 5
        Set Ctrl = Me.Controls.Add("forms.TextBox.1", "TextBox" & i, True)
        Cl(i - 1).Add Ctrl
        With CommandButton1
            Ctrl.Move .Left, .Top + .Height + i * 20, 100, 20
        End With
    Next
End Sub
 
Private Sub UserForm_QueryClose(Cancel As Integer, CloseMode As Integer)
Dim i&
 
    For i = 0 To 4
        Cl(i).Clear
        Set Cl(i) = Nothing
    Next i
End Sub

Le code de la Classe :

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
Option Explicit
 
    Private Type GUID
        Data1 As Long
        Data2 As Integer
        Data3 As Integer
        Data4(0 To 7) As Byte
    End Type
 
    #If VBA7 And Win64 Then
        Private Declare PtrSafe Function ConnectToConnectionPoint Lib "shlwapi" Alias "#168" _
                 (ByVal punk As stdole.IUnknown, _
                 ByRef riidEvent As GUID, _
                 ByVal fConnect As Long, _
                 ByVal punkTarget As stdole.IUnknown, _
                 ByRef pdwCookie As Long, _
                 Optional ByVal ppcpOut As LongPtr) As Long
    #Else
        Private Declare Function ConnectToConnectionPoint Lib "shlwapi" Alias "#168" _
                 (ByVal punk As stdole.IUnknown, _
                 ByRef riidEvent As GUID, _
                 ByVal fConnect As Long, _
                 ByVal punkTarget As stdole.IUnknown, _
                 ByRef pdwCookie As Long, _
                 Optional ByVal ppcpOut As Long) As Long
    #End If
 
    Private cCook As Long
    Private cObj As Object
    Private WithEvents cTBx As MSForms.TextBox
    Private cColorInit As Long
 
    Private Sub ConnectEvent(ByVal Connect As Boolean)
    Dim cGuid As GUID
        With cGuid
            .Data1 = &H20400
            .Data4(0) = &HC0
            .Data4(7) = &H46
        End With
        ConnectToConnectionPoint Me, cGuid, Connect, cObj, cCook, 0&
    End Sub
 
    Public Sub Add(NewCtrl As Object)
        Set cObj = NewCtrl
        Set cTBx = NewCtrl
        cColorInit = NewCtrl.BackColor
        Call ConnectEvent(True)
    End Sub
 
    Public Sub Clear()
        If (cCook <> 0) Then Call ConnectEvent(False)
        Set cObj = Nothing
    End Sub
 
    Public Sub cTBx_Entree()
'Attribute cTBx_Entree.VB_UserMemId = -2147384830
        cTBx.BackColor = vbBlue
    End Sub
 
    Public Sub cTBx_Sortie(ByVal Cancel As MSForms.ReturnBoolean)
'Attribute cTBx_Sortie.VB_UserMemId = -2147384829
        cTBx.BackColor = cColorInit
    End Sub
    Public Sub cTBx_AvantMiseAjour(ByVal Cancel As MSForms.ReturnBoolean)
'Attribute cTBx_AvantMiseAjour.VB_UserMemId = -2147384831
        MsgBox "Before_Update"
    End Sub
 
    Public Sub cTBx_ApresMiseAjour()
'Attribute cTBx_ApresMiseAjour.VB_UserMemId = -2147384832
        cTBx.Value = Format(Replace(cTBx.Value, ".", ","), "### ### ##0.00 €")
    End Sub

La manipulation :

Clic droit sur le module de classe / Supprimer
Cliquer sur Exporter
Ouvrir le fichier Classe1.cls avec ton éditeur de texte (bloc notes ou autre)
enlever les apostrophes pour dé-commenter les lignes Attribute cTBx_XXXXXX.VB_UserMemId = -XXXXXXXXXXX (dans chaque événement)
Enregistrer le fichier, le fermer
importer le fichier Classe1.cls dans le classeur (Fichier/importer un fichier sous VBE)
tester

EDIT : Attention si les TextBox sont encapsulés dans différents conteneurs (Frame, MultiPage, Pages)

EDIT 2 : ce code est également fonctionnel avec des ComboBox (mauvaise lecture de la demande).

06/07/2017, 09h27
patricktoulon

re

Citation:

Il reste la problématique que j'évoquais dans mon message initial, à savoir le calcul des textbox... "AfterUpdate".

n'oublie pas que dans le tag de ton/tes textboxs la valeur ne sera pas formaté alors d'après toi comment devrais tu faire le calcul

tag ou value hein ????

la j'ai tout dis ;)

Citation:

Envoyé par patricktoulon

tag ou value hein ????

L'un, ou l'autre conviennent.

Code:

1
2
3
4
5
6
7
Sub Test()
Dim str1 As String, str2 As String, result As Double
    str1 = Format("123456,57", "### ### ##0.00 €")
    str2 = Format("123456,57", "### ### ##0.00 €")
    result = CDbl(str1) + CDbl(str2)
    Debug.Print Format(result, "### ### ##0.00 €")
End Sub

06/07/2017, 21h04
jppouma

Tout d'abord merci à tous ceux qui m'ont répondu et fait part de leur expérience... (soit GeoTrouvePas, patricktoulon et pijaku).
Je suis loin d'être un expert en VBA (je n'ai que 3 mois d'expérience en VBA et en autodidacte... mais beaucoup plus à l'aise avec du 4D !!!). Donc pas évident de suivre vos méthodes sans être obligé d'utiliser la doc en ligne ou sur bouquin.
Première réponse à patricktoulon : J'ai utilisé ton code pour le formatage... petit bug sur la partie touche back mais je regarde pour faire la correction qui s'impose.
Pour ta remarque sur le calcul, j'utiliserai le tag après l'avoir converti en double (CDbl). Bonne réponse???

Pour pijaku, je suis encore à digérer ton code...
J'aimerai bien le comprendre en détail avant de le copier et de le coller dans mon code.
Je vais donc faire comme tu me le propose... faire un exemple et de le tracer en débug.

En tout cas, merci pour vos aides (TRES) précieuses.
Dès que j'aurai fait le tour de vos propositions, je posterai à nouveau, et je n’oublierai pas de valider le "Résolu" si c'est le cas (ce dont je ne doute pas!!!).
jppouma
07/07/2017, 08h34
pijaku

Bonjour,

Citation:

Envoyé par jppouma

Pour pijaku, je suis encore à digérer ton code...
J'aimerai bien le comprendre en détail avant de le copier et de le coller dans mon code.
Je vais donc faire comme tu me le propose... faire un exemple et de le tracer en débug.

En cas de difficulté n'hésite surtout pas.

Bonjour,

Reçu par MP :

Citation:

Envoyé par jppouma

Je te remercie pour ton code concernant ma demande "Comment formater et calculer des textbox créées dynamiquement?"
Tu me dis qu'il fonctionne aussi pour les combobox... mais ta variable cTBx est uniquement formatée pour les textbox.
D'ou erreur lors de la création d'un combobox.
Ensuite je me prends la tête pour faire mon calcul entre mes textbox
je me cite : "De même, je souhaiterai effectuer – toujours après saisie (du combobox Code TVA cette fois), un calcul simple (du type Montant TTC = Montant HT +TVA, avec un taux de TVA donné par le combobox Code TVA ).
J'ai bien pensé à utiliser un module de classe utilisant des "Property Get et Set", mais je ne vois pas comment déclencher ce module de classe."
J'avoue que je plante lamentablement
Tu m'as gentiment proposé de l'aide en cas d'échec... Ben voilà...

En ce qui concerne le calcul suite à changement dans la combobox, tu n'as pas besoin de mes codes Exit, AfterUpdate etc...

Après leur remplissage, tu règles la propriété Style de tes combobox sur fmStyleDropDownList (2) ==> cela empêche des saisies erronées
tu utilises leur événement Change pour faire ton calcul...

Pour cela, tu peux utiliser un module de classe, tout bête, pour tes ComboBox.
Si tu as besoin, reviens je te ferais un exemple...

EDIT :
Allez, un exemple.
Dans un nouveau classeur :

Un UserForm avec dedans :

Trois textBox : TextBox1, textBox2, TextBox3
Un ComboBox : ComboBox1
Un Module standard (Module1)
Un Module de classe (Classe1)

Le code du module standard (Module1)

Code:

Public USF As MSForms.UserForm

Le code de l'UserForm :
Code:

1 2 3 4 5 6 7 8 9 10 11 12 Option Explicit Dim CB As New Classe1 Private Sub UserForm_Initialize() Set USF = Me With Me.ComboBox1 .List = Array(1, 2, 3) .Style = 2 End With Set CB.CBBx = Me.ComboBox1 End Sub
Le code de la classe (Classe1)
Code:

1 2 3 4 5 6 7 8 Option Explicit Public WithEvents CBBx As MSForms.ComboBox Private Sub CBBx_Change() USF.TextBox3 = CDbl(USF.TextBox2) + CDbl(USF.TextBox1) End Sub
Cet exemple te montre le principal souci qui est de pouvoir reconnaître, dans la Classe, les noms des textbox.
Pour cela il te faudra utiliser une convention de nommage avec, par exemple, un numéro de ligne que tu pourras stocker dans le Tag de la Combo...