Excel choix Système SAP

Version imprimable

23/05/2017, 09h12
foxleman

Excel choix Système SAP
Bonjour,

j'utilise plusieurs types de connexion SAP et j'aimerais faire plusieurs choses :
- Identifier si le système est déjà connecté.
  exemple: "If APO is connect then..."
- Sélectionner un système connecté
  exemple: "with APO system..."
Types de système utilisé:
- SAP P93
- SAP P94
- SAP APO
pour me connecter, j’utilise : Set Connection = Appl.OpenConnection("Système utilisé", True)
merci d'avance

Fox Leman

Bonjour,

Je ne sais pas si ça peut t'aider, mais ici on utilise 2 systèmes PRD et PBW (qui passe par le web donc que je ne peux automatiser simplement...)
Je vérifie donc si une des sessions ouvertes est PRD et si elle n'est pas occupée à rouler une transaction.
Si elle est occupée, je sors de la Sub

NB: Je n'utilise pas OpenConnection

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
    Set SapGuiAuto = GetObject("SAPGUI")
    If Not IsObject(SapGuiAuto) Then
        Exit Sub
    End If
    
    Set AppliSAP = SapGuiAuto.GetScriptingEngine()
    If Not IsObject(AppliSAP) Then
        Exit Sub
    End If
    
    'Choisir la Session PRD non utilisée, si ouverte
    For Each Connection In AppliSAP.Children
        If Not Connection.DisabledByServer And Left(Connection.Description, 3) = "PRD" Then
            For Each TmpSession In Connection.Children
                If TmpSession.Busy = False Then  'Vérifie si la session est déjà occupée à rouler une transaction
                    Set Session = TmpSession
                    GoTo FoundSession
                End If
            Next
        End If
    Next

FoundSession:
    If Session Is Nothing Then
        MsgBox "Ouvrir une session SAP-PRD et recommencer" & vbCrLf & _
                "S'il y a une session ouverte, elle est probablement en cours d'exécution", vbExclamation, "Erreur de connexion"
        Exit Sub
    End If
.......................

Super ce bout de code, je ne savais pas le faire :applo:. Je l'ai adapté en une fonction pour qu'il soit un peu + souple d'usage, si ça peut servir à d'autres:

Code de test:

Code:

1
2
3
4
5
6
Sub test()
Set session = get_active_session("NSP", "001", "BCUSER", "EN")
If Not session Is Nothing Then
    MsgBox "déjà connecté au système " + session.Info.SystemName
End If
End Sub

La fonction:

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
Function get_active_session(systemID As String, clientNumber As String, userID As String, languageCode As String, Optional selectNotBusyOne As Boolean = False) As Object


    Set get_active_session = Nothing

    On Error Resume Next
    Set SapGuiAuto = GetObject("SAPGUI")
    If err.Number <> 0 Then
        ' première fois si SAP GUI n'a pas encore été démarré (donc aucune session)
        Exit Function
    End If
    If Not IsObject(SapGuiAuto) Then
        Exit Function
    End If

    Set AppliSAP = SapGuiAuto.GetScriptingEngine()
    If Not IsObject(AppliSAP) Then
        Set SapGuiAuto = Nothing
        Exit Function
    End If

    'Choisir la Session PRD non utilisée, si ouverte
    For Each connection In AppliSAP.Children
        If Not connection.DisabledByServer Then
            For Each TmpSession In connection.Children
            If TmpSession.Info.SystemName = systemID _
                And TmpSession.Info.client = clientNumber _
                And TmpSession.Info.user = userID _
                And TmpSession.Info.language = languageCode _
                Then
                If selectNotBusyOne = False Then
                    Set get_active_session = TmpSession
                    GoTo theend
                ElseIf selectNotBusyOne = True And TmpSession.Busy = False Then
                    'cas où la session n'est pas occupée à rouler une transaction
                    Set get_active_session = TmpSession
                    GoTo theend
                End If
            End If
            Next
        End If
    Next

    Exit Function

theend:
    Set AppliSAP = Nothing
    Set SapGuiAuto = Nothing
End Function

24/05/2017, 11h33
foxleman

Bonjour,

c'est exactement ce que je cherchais, un grand merci à tous pour votre aide.
26/05/2017, 09h29
sandraros

petite correction

J'ai modifié le code ci-dessus pour gérer le cas où le SAP GUI n'a pas encore été démarré (autour de Set SapGuiAuto = GetObject("SAPGUI"))
26/05/2017, 17h04
parmi

Bien vu ;)
09/12/2019, 15h47
sandraros

Attention tester TmpSession.Busy avant d'accéder à TmpSession.Info !

Pour information, je viens de voir que mon code posté le 24/05/2017, 11h02 n'est pas tout à fait correct, mais je n'arrive pas à le corriger dans le forum, il faut absolument tester TmpSession.Busy avant d'accéder à TmpSession.Info car si la session est busy l'accès à Info se met en attente jusqu'à ce qu'elle ne soit plus busy.
04/01/2020, 18h25
ASTRO81800

COMPLEMENt D'INFOS

Bonjour je fouille désespérément les sites pour trouver une réponse a ma question.
J'essaye de me connecter a SAP a travers les différents code que j'ai pu dénicher. Le plus proche du résulta me bloque sur la ligne suivante:

Code:

Set oConnection = SAPGuiApp.OpenConnection("..SAP2000 Production PGI", True)

la question est la suivante. A quoi correspond le string ("..SAP2000 Production PGI", True) ?

Ma fenetre SAP se lance bien mais la sa plante

Merci d'avance de vos retours.

question subsidiaire ou pourrais je trouver des tutos pour créer des JOB SAP directement. J'ai pas mal de doc sur l'ABAP mai spas sur les jobs qui me permettrai d'automatiser des extractions.