Comment modifier des listes dans une feuille avec une textbox

Version imprimable

22/03/2017, 13h12
debutant033

Comment modifier des listes dans une feuille avec une textbox
Bonjour à tous,

j'ai créer un userform pour pouvoir modifier une liste de nom sur une feuil protégé par mot de passe.
j'arrive à enlever la protection de la feuil avec le userform mais je rencontre encore un petit problème.
Mon problème est que lorsque je sélectionne un nom dans ma listbox le prenom et le nom vont dans ma textbox1 et textbox2.
quand je fais ma modification dans la textbox1 par exemple, et que je clic sur le bouton ok la nouvelle valeur de mes textbox
ne remplace pas les ancienne valeur sur la feuil. En vrai rien ne se passe. J'ai essayé de coder avec le code suivant :
Code:

1 2 3 Private Sub CommandButton2_Click() ListBox1.List(List.ListIndex).Value = TextBox1.Value End Sub
pouvez vous m'aidez à résoudre mon problème. Je vous en remercie par avance.
22/03/2017, 13h38
parmi

Bonjour,

Ton problème n'est pas très clair...
La listbox est sur la feuille ?

Quoiqu'il en soit, tu as une erreur dans ton code au niveau du ListIndex

Code:

ListBox1.List(ListBox1.ListIndex).Value = TextBox1.Value
22/03/2017, 13h49
debutant033

bonjour parmi,

quelle parti de mon message tu n'as pas compris ? non la listbox n'est pas sur la feuil elle est sur un userform.
Dans mon code je devrai retirer ce que tu as surligné en rouge ? si oui, qu'est ce que je devrais mettre à la place?
22/03/2017, 14h02
parmi
ListIndex est la ligne sélectionnée de Listbox1 et non pas de List.
C'est pourquoi j'ai mis en rouge la modification.

Lorsque tu cliques sur ton bouton OK, qu'est-ce que tu veux faire ? modifier la listbox ou écrire sur la feuille ?
De plus, est-ce que ta listbox a 2 colonnes ? Si oui, et que tu veuilles modifier une seule valeur d'une seule colonne, il faut la spécifier.
Code:

1 2 ListBox1.List(ListBox1.ListIndex, 0).Value = TextBox1.Value ' 0 étant la première colonne ListBox1.List(ListBox1.ListIndex, 1).Value = TextBox2.Value ' 1 étant la deuxième colonne
22/03/2017, 14h23
debutant033

clairement, sur mon userform j'ai une listbox qui m'affiche une liste de nom. dans ma listbox il y a 4 colonne (nom,prenom,identifiant et statut). ces info se trouvent toutes sur la feuil1. quand je clic sur un nom, les info vont respectivement dans les textbox 1,2,3 et 4. Ensuite je décide de modifier l'identifiant et le statut du nom que j'ai sélectionné dans la listbox. Ensuite quand je clic sur le bouton ok, je voudrais que les modifications que j'ai faite dans la textbox 3 et 4 se retrouve sur la feuil1 mais pas à l suite de la liste mais que cela remplace les ancienne valeur qui figurait sur la même ligne que le nom selectionné dans la listbox. J'espère que c'est un peu plus claire. sinon, je peux envoyer le fichierqui vas avec.
22/03/2017, 14h37
parmi

Comment charges-tu ta listbox ?
Si tu utilises un Range, chaque ligne de la listbox correspond donc à une ligne (+ x) de ta feuille (Ligne 2 de ta feuille = Ligne 0 de la listbox, par exemple)
Si c'est le cas, ça simplifie le code
22/03/2017, 14h49
debutant033

je mis dans la propriete de la listbox que rowsource=A2:D500. et la liste apparait automatiquement dans la listbox dès l'ouverture de l'userform.

Enlève le RowSource de la listbox et charge-la comme dans Userform_Initialize()
Si tu veux changer le texte dans la listbox, j'ai mis une procédure.
Ça ne donne pas grand chose, mais bon... ça donne un exemple

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
Private Sub CommandButton1_Click()
    Dim Ligne As Long
 
    If ListBox1.ListIndex = -1 Then Exit Sub    'si aucun item sélectionné
 
    Ligne = ListBox1.ListIndex + 2
 
    Range("A" & Ligne) = TextBox1
    Range("B" & Ligne) = TextBox2
    Range("C" & Ligne) = TextBox3
    Range("D" & Ligne) = TextBox4
End Sub
 
'Charge les textbox avec les données de la ligne sélectionnée
Private Sub ListBox1_Click()
    TextBox1 = ListBox1.List(ListBox1.ListIndex, 0)
    TextBox2 = ListBox1.List(ListBox1.ListIndex, 1)
    TextBox3 = ListBox1.List(ListBox1.ListIndex, 2)
    TextBox4 = ListBox1.List(ListBox1.ListIndex, 3)
 
End Sub
 
'FACULTATIF
'Modifie la listbox, colonne 1 (On pourrait utiliser la procédure Exit ou AfterUpdate aussi)
Private Sub TextBox1_Change()
    ListBox1.List(ListBox1.ListIndex, 0) = TextBox1
End Sub
 
'Charge la listbox avec les données des colonnes A à D de la feuille
'à partir de la ligne 2 (si entêtes en ligne 1)
Private Sub UserForm_Initialize()
    Dim nbLignes As Long
 
    ListBox1.ColumnCount = 4    'détermine le nombre de colonnes
    nbLignes = Cells(Rows.Count, "A").End(xlUp).Row
    ListBox1.List = Range("A2:D" & nbLignes).Value
End Sub

Citation:

Envoyé par parmi

Enlève le RowSource de la listbox et charge-la comme dans Userform_Initialize()

Salut,

Je proposes une alternative, en conservant le RowSource (que j'aime bien)...

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
Option Explicit
 
Private Enable_Events As Boolean
 
Private Sub CommandButton1_Click()
Dim Rng As Range
    If ListBox1.ListIndex = -1 Then Exit Sub
    Set Rng = Range(ListBox1.RowSource).Cells(ListBox1.ListIndex + 1, 1)
    Enable_Events = True
    Rng.Value = TextBox1
    Rng.Offset(0, 1).Value = TextBox2
    Rng.Offset(0, 2).Value = TextBox3
    Rng.Offset(0, 3).Value = TextBox4
    Enable_Events = False
End Sub
 
Private Sub ListBox1_Click()
    If Enable_Events Then Exit Sub
    TextBox1 = ListBox1.List(ListBox1.ListIndex, 0)
    TextBox2 = ListBox1.List(ListBox1.ListIndex, 1)
    TextBox3 = ListBox1.List(ListBox1.ListIndex, 2)
    TextBox4 = ListBox1.List(ListBox1.ListIndex, 3)
End Sub

En fait, c'est exactement le même code que toi, parmi, mais l'on conserve ici le RowSource...

23/03/2017, 08h09
unparia

Bonjour Franck
Ce que tu proposes est en effet la solution la plus simple à mettre en oeuvre :plusser:
L'autre (que tu connais bien ;)) est plus amusante et conviviale mais nécessite des contrôles additionnels et un code plus lourds.
Amitiés
23/03/2017, 08h40
pijaku

Bonjour Jacques,

Citation:

Envoyé par unparia

Ce que tu proposes est en effet la solution la plus simple à mettre en oeuvre :plusser:

Merci !
C'est surtout celle que je préfères...

Citation:

Envoyé par unparia

L'autre (que tu connais bien ;)) est plus amusante et conviviale mais nécessite des contrôles additionnels et un code plus lourds.

Oui, en effet !
Mais, à ce propos, il faudrait certainement la terminer un jour.
Pour cela, pourrais tu te renseigner si la "fameuse" propriété des vrais contrôles fenêtres (ListBox, Frame) pourrait être dévoilée?

Amicalement,

Bonjour à tous,

merci pour votre aide. j'ai testé les deux codes mais les deux poses un problème.

le 1er code, celui de parmi : il fonctionne modifie bien mais modifie uniquement dans la colonne A.
ci-dessous le code que j'ai tapé
Code:

1 2 3 4 5 6 7 8 9 10 11 12 13 14 15 16 17 18 19 20 21 22 23 24 25 26 27 28 Private Sub ListBox1_Click() TextBox1.Value = ListBox1.List(ListBox1.ListIndex) TextBox2.Value = ListBox1.List(ListBox1.ListIndex, Row + 1) TextBox3.Value = ListBox1.List(ListBox1.ListIndex, Row + 2) TextBox4.Value = ListBox1.List(ListBox1.ListIndex, Row + 3) End Sub Private Sub CommandButton2_Click() Feuil10.Activate Feuil10.Unprotect Password:="231294" Dim ligne As Long If ListBox1.ListIndex = -1 Then Exit Sub ligne = ListBox1.ListIndex + 2 Range("A" & ligne) = TextBox1 Range("B" & ligne) = TextBox2 Range("C" & ligne) = TextBox3 Range("D" & ligne) = TextBox4 Feuil10.Protect Password:="231294" End Sub
Le deuxième code, celui de pijaku:
marche très bien.

dans le 1er code est ce que le code que j'ai mal tapé le code ?

Citation:

Envoyé par debutant033

dans le 1er code est ce que le code que j'ai mal tapé le code ?

C'est toi qui t'es fourvu...

Que vient faire Row dans cette partie du code de parmi?

Code:

1
2
3
4
5
6
Private Sub ListBox1_Click()
TextBox1.Value = ListBox1.List(ListBox1.ListIndex)
TextBox2.Value = ListBox1.List(ListBox1.ListIndex, Row + 1)
TextBox3.Value = ListBox1.List(ListBox1.ListIndex, Row + 2)
TextBox4.Value = ListBox1.List(ListBox1.ListIndex, Row + 3)
End Sub

Pour rappel, parmi avait écrit :

Code:

1
2
3
4
5
6
7
'Charge les textbox avec les données de la ligne sélectionnée
Private Sub ListBox1_Click()
    TextBox1 = ListBox1.List(ListBox1.ListIndex, 0)
    TextBox2 = ListBox1.List(ListBox1.ListIndex, 1)
    TextBox3 = ListBox1.List(ListBox1.ListIndex, 2)
    TextBox4 = ListBox1.List(ListBox1.ListIndex, 3)
End Sub