Boucler sur les éléments d'une variable (type utilisateur)

Version imprimable

14/03/2017, 17h41
Soguy46

Boucler sur les éléments d'une variable (type utilisateur)
Bonjour,

J'ai crée un type
Code:

1 2 3 4 5 6 7 Type type_Budget M1 As Double M2 As Double M3 As Double M4 As Double end type
J'ai créé ma variable

Code:

Mon_budget as type_budget

Je voudrais maintenant boucler pour accéder à tous les champs de ma variable M1, M2, etc...
J'ai essayé ça
Code:

1 2 3 4 for i = 1 to 4 Mon_budget.M&i = "toto" next i
Mais évidemment ça ne marche pas.... j'ai essayé plusieurs trucs mais je ne vois pas... et je n'arrive pas à trouver les mots clés pour chercher dans le forum.

Merci d'avance si vous avez une idée,

Soguy

Bonjour,

à ma connaissance, ce n'est pas possible.

un contournement, c'est de créer une fonction chargée de remplir cette valeur, et de la transmettre à la procédure appelante

Il suffit pour cela de fournir à la fonction un tableau de valeurs, en respectant bien l'ordre

Un exemple à adapter (attention, en Base 0 !) réalisé à la va-vite
Code:

1 2 3 4 5 6 7 8 9 10 11 12 13 14 15 16 17 18 19 20 21 22 23 24 25 ' la structure Type type_Budget M1 As Double M2 As Double M3 As Double M4 As Double End Type ' la procédure principale Sub Toto() Dim UnBudget As type_Budget UnBudget = RempliMonType(Array(1, 2, 3, 4)) Debug.Print UnBudget.M1 Debug.Print UnBudget.M2 Debug.Print UnBudget.M3 Debug.Print UnBudget.M4 End Sub ' la fonction de rempliassage Function RempliMonType(LesValeurs As Variant) As type_Budget RempliMonType.M1 = LesValeurs(0) RempliMonType.M2 = LesValeurs(1) RempliMonType.M3 = LesValeurs(2) RempliMonType.M4 = LesValeurs(3) End Function

14/03/2017, 18h30
boisgontierjacques

1 pièce(s) jointe(s)

Bonjour,

Une alternative à l'utilisation des variables structurées, un module de classe BD qui gère des enregistrements.

boisgontier
14/03/2017, 20h16
Invité

Bonsoir,
C'est toujours la même chose! On présente une problématique, un bout de code et voila!

Hors une présentation succincte des tenants et des aboutissants nous permettrait peut-être de faire des propositions même autres comme celle de boisgontierjacques qui me paraît une alternative convenable!
15/03/2017, 05h34
Soguy46

Salut à tous et merci pour les réponses!
@joe.levrai : si c'est pas possible je ne cherche pas plus loin. Merci d'avoir pris le temps de rédiger un petit bout de code.
@boisgontierjacques : je ne connaissais pas du tout les classes, je m'y plonge à fond car ça m'ouvre de grandes possibilités pour mon code! Je vais surement tout réécrire en ce sens!
@dysorthographie : désolé de ne pas avoir écrit un message qui te convienne. J'avais une question précise sur la rédaction d'une ligne, ce que joe.levrai a bien compris je crois. Je ne cherchais pas à résoudre une problématique plus générale sur mon code, car tout simplement je ne savais pas que c'était possible. Je n'ai qu'un fichier de plusieurs dizaine de feuilles et de procédures à partager. Heureusement @boigontierjacques a compris que je me fourvoyais et m'a apporté de nouveaux éclairages au-delà de mes connaissances.
15/03/2017, 16h44
Pierre Fauconnier

Salut.

Si tu veux travailler sur les classes perso => http://fauconnier.developpez.com/art...neral/classes/
15/03/2017, 18h20
Soguy46

hehe j'avais déjà trouvé! ;-) Un grand bravo pour votre site que je fréquente tout le temps pour apprendre le VBA.

J'suis en train de réfléchir à la manière de structurer mes données. Je viendrais proposer un code complet prochainement pour voir si ça marche.

Bonjour,

tu peux mettre un tableau dans un type personnalisé :
Code:

1 2 3 4 5 6 7 8 9 10 Type type_Budget M(1 To 4) As Double End Type Sub test() Dim Mon_budget(1 To 10) As type_Budget, i As Long For i = 1 To 4 Mon_budget(1).M(i) = 12 + i Next i End Sub
J'ai mis Mon_budget en tant que tableau mais ça peut être une variable simple bien sûr.
eric

15/03/2017, 23h09
Soguy46

Merci Eriiiic, très élégant, j'avais jamais vu ça. Il faudra que je teste ça. Je sens que j'ai beaucoup de code à réécrire!

De rien, si besoin tu peux aussi le définir sans dimension et faire un Redim ensuite :

Code:

1
2
3
4
5
6
7
8
9
10
Type type_Budget
    M() As Double
End Type
 
Sub test()
    Dim Mon_budget(1 To 10) As type_Budget, i As Long
    For i = 1 To 10
        ReDim Mon_budget(i).M(1 To 4)
    Next i
End Sub

16/03/2017, 03h21
clementmarcotte

Citation:

Envoyé par Soguy46

Merci Eriiiic, très élégant, j'avais jamais vu ça.

Moi non plus. C'est à garder en réserve. :plusser: pour eriiic

1 pièce(s) jointe(s)

Bonjour,

Solution avec Array emboîtés

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
 
Sub TriTableauEmboités()
  n = 5
  Dim Tbl(): ReDim Tbl(1 To n)
  For i = 1 To n
    Tbl(i) = Array(Cells(i, 1), Cells(i, 2), Cells(i, 3))
  Next i
  '---- Tri Bubble
  For i = 1 To n
    For j = i To n
      If Tbl(j)(0) < Tbl(i)(0) Then
        tmp = Tbl(j): Tbl(j) = Tbl(i): Tbl(i) = tmp
      End If
    Next j
  Next i
  '--  transfert feuille
  ' ou [J1:L5] = Application.Transpose(Application.Transpose(Tbl))
  For lig = 1 To n
     For col = 0 To 2
        Cells(lig, col + 10) = Tbl(lig)(col)
     Next col
   Next lig
End Sub

Il y a aussi les dictionnaires multi-colonnes

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
 
Sub DicoMultiColonnes()
  Set d = CreateObject("Scripting.Dictionary")
  a = [A2:C6]
  For i = LBound(a) To UBound(a)
     d.Item(a(i, 1)) = Array(a(i, 1), a(i, 2), a(i, 3))
  Next i
  '--accès à la ville de Charlie
  [k2] = d("Charlie")(1)
 '---Affichage d'une ligne
  a = d("Charlie")
  For i = 0 To 2: Cells(2, 10 + i) = a(i): Next i
  '---suppression d'une ligne
  d.Remove ("Dupont")
  '----- affichage du tableau dans le tableur
  b = Application.Transpose(Application.Transpose(d.items)) ' dictionnaire dans array b(1 to n,1 to 3)
  [O2].Resize(UBound(b), UBound(b, 2)) = b
  'MsgBox b(1, 2) ' accès à un item de b(,)
End Sub

Boisgontier

1 pièce(s) jointe(s)

bonjour,

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
' la structureType type_Budget
    M1 As Double
    M2 As Double
    M3 As Double
    M4 As Double
End Type
Dim a As type_Budget
Public Dico As Object
Property Let Mon_bud(Cle As String, value As Variant)
Select Case Cle
    Case "M1": a.M1 = value
    Case "M2": a.M2 = value
    Case "M3": a.M3 = value
    Case "M4": a.M4 = value
End Select
End Property
Property Get Mon_bud(Cle As String) As Variant
Select Case Cle
    Case "M1": Mon_bud = a.M1
    Case "M2": Mon_bud = a.M2
    Case "M3": Mon_bud = a.M3
    Case "M4": Mon_bud = a.M4
End Select
End Property
Property Let Mon_budget(Cle As String, value As Variant)
If TypeName(Dico) = "Nothing" Then Set Dico = CreateObject("Scripting.Dictionary")
Dico(Cle) = value
End Property
Property Get Mon_budget(Cle As String) As Variant
If TypeName(Dico) = "Nothing" Then Set Dico = CreateObject("Scripting.Dictionary")
Mon_budget = Dico(Cle)
End Property
Property Get Mon_budgetAll() As type_Budget
If TypeName(Dico) = "Nothing" Then Set Dico = CreateObject("Scripting.Dictionary")
K = Dico.Keys
Mon_budgetAll.M1 = Dico(K(0)): Mon_budgetAll.M2 = Dico(K(1))
Mon_budgetAll.M3 = Dico(K(2)): Mon_budgetAll.M4 = Dico(K(3))
End Property
Sub test()
Set Dico = Nothing
For i = 1 To 4
  Mon_budget("M" & i) = 10
Next i
K = Dico.Keys
For i = 0 To Dico.Count - 1
 Debug.Print Mon_budget(CStr(K(i)))
Next i
Dim mbg As type_Budget
mbg = Mon_budgetAll
For i = 1 To 4
  Mon_bud("M" & i) = 10
Next i
For i = 1 To 4
 Debug.Print Mon_bud("M" & i)
Next i
End Sub

16/03/2017, 12h00
Soguy46

Merci @dysorthographie pour ces dernières propositions. Je découvre encore un nouveau truc qui m'inspire à fond: les dictionnaires. Je crois que j'aurais besoin de ça dans un autre contexte. Je me penche sur ton code... pas tout compris à 100 % mais ça va venir.

Je viens de créer un nouveau post pour présenter ma problématique plus complètement :
https://www.developpez.net/forums/d1...l/#post9094987

Bonne journée,