Remplir une cellule avec un userform

Version imprimable

Voir 40 message(s) de cette discussion en une page

Bonjours à tous

ci dessous un code qui permet de remplir une feuille à l'aide d'un userform

J'ai 2 combobox cb_lofc et cb_sem qui correspondent à mes données sur la 1ère ligne et la 1ère colonne respectivement
A l'aide d'un array j'ai essayé de rechercher :
- la donnée selectionnée dans Cb_sem dans la première colonne
- celle selectionnée dans cb_lofc dans ma première ligne

pour objenir une cellule (i,j) et la renseigner avec une partie des données sélectionnées dans la listbox (celles entre parenthèses) lb_codi

Or il ne se passe rien au click, mais alors rien,

Aussi je ne vois pas comment lui dire de renseigner uniquement les données entre parenthèses de la listbox

Merci d'avance
Code:

1 2 3 4 5 6 7 8 9 10 11 12 13 14 15 16 17 18 19 20 21 22 23 24 25 26 Private Sub Valider_Click() Dim derl% Dim derc% Dim ress() Dim i As Integer, j As Integer, k As Integer f1 = "Ressources" derl = Worksheets(f1).Cells(Rows.Count, 1).End(xlUp).Row derc = Worksheets(f1).Cells(1, Cells.Columns.Count).End(xlToLeft).Column ress = Worksheets(f1).Range(Cells(1, 1), Cells(derl, derc)).Value For i = LBound(ress, 1) To UBound(ress, 1) If ress(i, 1) = Cb_sem.Value Then For j = LBound(ress, 2) To UBound(ress, 2) If ress(1, j) = CB_lofc.Value Then For k = 0 To Lb_codi.ListCount - 1 If Lb_codi.Selected(k) = True Then ress(i, j) = ress(i, j) & ";" & Lb_codi.List(k) End If Next End If Next End If Next End Sub

10/03/2017, 13h39
MarcelG

Bonjour et bienvenu sur le Forum,

Je sais que les pièces jointes sont limitées.
Mais là, je suis un peu perdu.

Pourrais-tu joindre un classeur simplifié et reporter les résultats que tu voudrais voir affichés en les explicitant précisément.
10/03/2017, 13h56
nananinanana

2 pièce(s) jointe(s)

Ci joint le fichier en xls ou xlsm

(Il n'y pas de quoi!)

Au risque de me montrer abrupt, je dirais que ton développement présente beaucoup d'approximations et de complications
- Si tu veux activer des procédures, ton classeur doit pouver les activer donc extension ".xlsm"
- Tu nommes un formulaire de la même façon qu'une feuille de travail ("Ressources")
Dans ce cas, pourquoi pas Usf_Ressources?
- Un formulaire doit être chargé avant d'être affiché
Code:

1 2 Load Usf_Ressources Usf_Ressources.Show
- Les objets doivent bien être attachés en utilisant la méthode With à bon escient
Exemple

Remplacer
Code:

1 2 3 4 5 6 7 8 f1 = "Ressources" derc = Worksheets(f1).Cells(1, Cells.Columns.Count).End(xlToLeft).Column codi = Worksheets(f1).Range(Cells(1, 2), Cells(1, derc)).Value With CB_lofc For i = LBound(codi, 2) To UBound(codi, 2) .AddItem codi(1, i) Next End With
par
Code:

1 2 3 4 5 6 7 With Worksheets("Ressources") derc = .Cells(1, .Columns.Count).End(xlToLeft).Column codi = .Range("B1", .Cells(1, derc)).Value End With For i = LBound(codi, 2) To UBound(codi, 2) CB_lofc.AddItem codi(1, i) Next i
Plus clair, non?
Bien regarder l'attachement des objets précédés par "."

Enfin, je trouve ton code lié à la validation de ton formulaire bien compliqué.
Pourrais-tu retourner l'amont et l'aval de ton développement.
A savoir à travers un exemple
Ce que tu choisis dans ton formulaire pour les 3 contrôles ComboBox et ListBox
Ce que tu souhaites voir apparaître dans la feuille "Ressources" en fonction de ces choix

A plus.

10/03/2017, 15h34
nananinanana

Je sais bien pour le xlsm ... pas besoin d'être un génie.
J'ai posté les deux car visiblement les xlsm de sont jamais ouvert, on me dit préférer le xls

Je vais essayer de modifier comme proposé et de formuler à travers un exemple mon besoin

Merci

EDIT : Load Usf_Ressources génère une erreur 9 (l'indice n'appartient pas à la section)
10/03/2017, 15h39
MarcelG

le "on" qui te dit de préférer les "xls" ne doit pas connaître grand chose à Excel en général, et VBA en particulier.

Pourquoi cette susceptibilité? Je n'ai pas parlé de "génie".

Cb_sem est chargé avec les données colonne 1
Cb_lofc avec les données ligne 1
LB_codi avec des données dans une feuille annexe

Je clique sur la cellule D5 (cells(5,4)) mon userform apparaît
Je vois apparaître dans Cb_sem la donnée D1 , (cells(1,4))
Je vois apparaître dans Cb_sem la donnée A5, (cells(5,1))
Or je peux changer les données de mon combobox alors je crée un tableau "ress" pour traiter la situation

Code:

1
2
3
4
5
With Worksheets("Ressources")
derl = .Cells(Rows.Count, 1).End(xlUp).Row
derc = .Cells(1, Cells.Columns.Count).End(xlToLeft).Column
Ress = .Range(Cells(1, 1), Cells(derl, derc)).Value
End With

Supposons que je veuille remplir la lofc 105 semaine 6 ( cellule F8 - cells(8,6)) je selectionne 105 dans cb_lofc et 6 dans cb_sem

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
For i = LBound(Ress, 1) To UBound(Ress, 1) 'je boucle sur mon table de haut en bas
    If Ress(i, 1) = Cb_sem.Value Then 'si je trouve la valeur de mon tableau sur la colonne 1 = 6 alors 
        For j = LBound(Ress, 2) To UBound(Ress, 2) 'je boucle de gauche à droite
            If Ress(1, j) = CB_lofc.Value Then ' Si la valeur sur la 1ère ligne = 105 alors 
                For k = 0 To Lb_codi.ListCount - 1 'je boucle sur les items de la listbox
                    If Lb_codi.Selected(k) = True Then 'si il est selectionné
                    Ress(i, j) = Ress(i, j) & ";" & Lb_codi.List(k) 'alors la cellule F8 cells(8,6) est allimentée par les éléments selectionnés dans la listbox
                    End If
                Next
            End If
        Next
    End If
Next

10/03/2017, 16h23
MarcelG

Et quel résultat veux-tu voir apparaître en cellule F8?
Explicitement.

Au temps pour moi
Comme écrit dans ton code, c'est la concaténation des éléments sélectionnés de ta Listbox
Il devrait y avoir plus simple pour sélectionner cette cellule et la compléter.

Je te reviens au plus tard lundi-matin.
10/03/2017, 16h30
nananinanana

Supposons avoir sélectionné les items
Contrôle épreuve hydraulique (CE)
Contrôle hélium (CH)
alors je voudrais voir apparaître CE;CH

Merci beaucoup pour le temps consacré !
10/03/2017, 17h59
unparia
Bonjour MarcelG
Je ne veux pas intervenir dans cette discussion.
Je te demande toutefois de corriger cette assertion :
Citation:
- Un formulaire doit être chargé avant d'être affiché

Code:

1 2 Load Usf_Ressources Usf_Ressources.Show

Salut,

Voici les modifications que j'ai apportées.
Etudie les codes suivants ligne par ligne, presque mot à mot.

Evènement SelectionChange

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
Private Sub Worksheet_SelectionChange(ByVal Target As Range)
 
If Target.Count > 1 Then Exit Sub
 
Dim derl%, derc%
 
With Worksheets("Ressources")
        derl = .Cells(.Rows.Count, 1).End(xlUp).Row
        derc = .Cells(1, Cells.Columns.Count).End(xlToLeft).Column
        If Not Application.Intersect(Target, .Range(.Cells(2, 2), .Cells(derl, derc))) Is Nothing Then
                Load Usf_Ressources
                Usf_Ressources.Show
        End If
End With
 
End Sub

Code associé au formulaire

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
Option Explicit
 
Private Sub UserForm_Initialize()
 
Dim derl%
Dim derc%
Dim codi(), lof()
Dim i As Integer
 
With Worksheets("Paramètres")
        derl = .Cells(.Rows.Count, 2).End(xlUp).Row
        codi = .Range("B2:C" & derl).Value
End With
 
With Lb_codi
        For i = LBound(codi, 1) To UBound(codi, 1)
                .AddItem codi(i, 2) & " (" & codi(i, 1) & ")"
                .MultiSelect = fmMultiSelectMulti
                .ListStyle = fmListStyleOption
        Next
End With
 
 
With Worksheets("Ressources")
 
        'Items de la Combobox Cb_sem
        derl = .Cells(Rows.Count, 1).End(xlUp).Row
        codi = .Range("A2:A" & derl).Value
        For i = LBound(codi, 1) To UBound(codi, 1)
                Cb_sem.AddItem codi(i, 1)
        Next
 
         'Items de la Combobox Cb_lofc
        derc = .Cells(1, .Columns.Count).End(xlToLeft).Column
        codi = .Range("B1", .Cells(1, derc)).Value
 
        For i = LBound(codi, 2) To UBound(codi, 2)
                CB_lofc.AddItem codi(1, i)
        Next
 
        'Valeurs par défaut
        CB_lofc.Value = .Cells(1, ActiveCell.Column).Value
        Cb_sem.Value = .Cells(ActiveCell.Row, 1).Value
 
End With
 
End Sub
 
Private Sub Valider_Click()
 
Dim i As Integer
Dim lavaleur As String
Dim d As Byte, e As Byte
 
lavaleur = ""
 
For i = 0 To Lb_codi.ListCount - 1
        With Lb_codi
                If .Selected(i) = True Then
                        d = InStr(.List(i), "(") + 1
                        e = InStr(.List(i), ")")
                        lavaleur = lavaleur & ";" & Mid(.List(i), d, e - d)
                End If
        End With
Next i
 
With ActiveCell
        'ôter le 1er ";"
        .Value = Right(lavaleur, Len(lavaleur) - 1)
        'ajustement de la largeur de colonne
        .Columns.AutoFit
End With
 
Me.Hide
Unload Me
 
End Sub

Pour ce qui est de la nomination des contrôles, comme toujours, je conseille de préfixer les noms par des lettres indiquant la nature du contrôle.
Exemple : Btn_Valider

Voir, et étudier, les 2 tutoriels sur les formulaires et les contrôles dans l'espace de Silkyroad
Espace Silkyroad

Et reviens si nécessaire.

10/03/2017, 19h08
MarcelG

Bonjour Unparia,

Quelle façon de s'exprimer!!
A vos ordres!

En effet, j'ai l'habitude - sans doute mauvaise - d'utiliser les 2 méthodes Load et Show successivement comme Hide et Unload.

Code:

Usf_Ressources.Show

suffit. Ironie : il l'est indiqué dans les tutoriels que j'ai cités.

Et donc

Code:

Me.Hide

devrait donc logiquement suffire.
10/03/2017, 20h15
unparia

A MarcelG

Citation:

Et donc

Code : Sélectionner tout - Visualiser dans une fenêtre à part

Me.Hide

devrait donc logiquement suffire.

Voudrais-tu s'il te plait avoir l'extrême obligeance et bonté (j'espère que cette formule ne provoquera pas ton apparente susceptibilité) de corriger également ce que tu as écrit là ?
Non seulement La méthode Hide appliquée à un userform ne le décharge pas, mais de surcroît : le seul fait de l'appliquer à un userform non encore chargé le .... chargerait.
Pour être plus clair et très précis : toute évocation d'un userform, voire de l'un de ses contrôles ou propriétés a pour effet de le charger (pas forcément de le montrer également), même s'il n'est pas encore chargé. Seule l'application de l'instruction Unload le déchargera.
10/03/2017, 20h23
MarcelG

Pour charger le formulaire

Code:

Monformulaire.Show

Pour le décharger (si écrit dans le code associé)

Code:

Unload Me

C'est bien cela?

Merci
10/03/2017, 20h26
unparia

C'est bien cela, en précisant que
Monformulaire.Show chargera ET montrera

D'accord.

Ces méthodes sont par ailleurs stipulées dans le tutoriel de Silkyroad.

Tu évoques la conséquence de son ouverture si l'on affecte une méthode sur un formulaire

Cela dit, sauf erreur et je m'en rappelle maintenant, il existe une procédure pour agir sur un formulaire sans avoir à l'ouvrir.
En utilisant les composants du projet VBA.

A toute fin utile.
Code:

1 2 3 4 5 6 7 8 9 10 11 12 13 14 15 16 17 Dim i As Byte With ThisWorkbook.VBProject.VBComponents 'Type 100 : Microsoft Excel Objets (Worksheets et ThisWorkbook) 'Type 1 : Modules 'Type 2 : Modules de classe 'Type 3 : Userforms (Feuilles) For i = 1 To .Count With .Item(i) 'Debug.Print .Name If .Type = 3 Then .... End With Next i End With
Maintenant, ces considérations prises en compte, notre ami pourra revenir pour des éclaircissements éventuels.

10/03/2017, 20h54
unparia

"ouvrir" ?
Charger est autre chose. Charger est ajouter l'userform à la collection UserForms (laquelle est vide au départ)
Cette instruction (exemple) toute bête, alors même que la collection UserForms est encore totalement vide (et que donc UserForm1 n'est pas chargé) :

Code:

UserForm1.CommandButton1.Caption = "coucou"

fera que UserForm1 sera chargé avec son bouton de commande affichant "coucou" (et figurera dans la collection UserForms) et le restera tant que ne sera exécutée une instruction Unload

EDIT : La méthode à laquelle tu fais allusion est autre chose encore et modifie les composants eux-mêmes, ainsi que leur code, éventuellement. Elle n'est que très rarement à appliquer (et pas dans le cas ici concerné).
10/03/2017, 23h18
MarcelG

Je n'ai pas choisi le bon terme. Don't act.
Je voulais simplement rebondir sur le fait que l'on pouvait agir sur un ou plusieurs formulaires sans le(s). charger.
Il m'est arrivé d'utiliser le code que j'ai reporté pour uniformiser les couleurs des formulaires d'un projet par exemple.

Mais je n'ai pas dit qu'il s'appliquait ici.

Au demeurant, je crois qu'il serait sage de s'en tenir là afin de ne pas s'éloigner de la problématique de notre ami.
10/03/2017, 23h35
unparia

Citation:

afin de ne pas s'éloigner de la problématique de notre ami.

Bien.
Et pourtant .... tout passe par une compréhension claire des choses de base. Cela me parait essentiel. Le reste est ensuite pur tricotage.
Je quitte donc maintenant cette discussion.
13/03/2017, 08h41
nananinanana

Bonjour à tous,

Merci à vous 2 pour vos informations qui sont pour mon apprentissage complémentaires.

Cependant le code fourni n'est valable pour pour activecell, ce qui represente pour moi toute la difficulté est justement de pouvoir agir sur la plage entière et c'est ce que j'ai voulu expliquer à travers mon exemple

merci tout de même pour le code il me permet de comprendre comment récupérer les valeurs entre parenthèses

Voir 40 message(s) de cette discussion en une page