Récupérer des informations d'un texte dans un tableau

Version imprimable

23/02/2017, 15h51
Grdcolas

Récupérer des informations d'un texte dans un tableau

Bonjour,

Dans une cellule contenant du texte, je cherche à recupérer plusieurs informations (respectant un format particulier) dans un tableau, mais étant nouveau dans le monde du VBA, je ne sais pas par où commencer.

Comme un exemple vaut bien plus qu'une explication, voici ce que je cherche à faire :

Dans une cellule (Par exemple A1), j'ai ce texte :

"(b) Monter les joints (04-100) et (04-130) neufs sur le piston (04-110).
(c) Placer la cale pelable (04-120) sur le piston (04-110). Le côté non pelable de la cale doit être orienté vers les rondelles élastiques (04-140)."

Et je voudrais recupérer, dans un tableau, seulement les repères des pièces, soit :

En B1 : 04 - 100
En B2 : 04 - 130
En B3 : 04 - 110

et ainsi de suite.

Le top du top serait qu'il n'y ait pas de doublon et que les valeurs soient classées, mais ca je peut plus facilement me débrouiller tout seul.

Merci beaucoup de votre aide,

Cordialement,

Grdcolas
23/02/2017, 16h02
Marc-L

Bonjour.

Manipuler les chaînes de caractères en VB6 et VBA Excel

Les Expressions Rationnelles appliquées en VBA …

_________________________________________________________________________________________________________
Je suis Paris, Istanbul, Berlin, Nice, Bruxelles, Charlie, …
23/02/2017, 16h04
Grdcolas

Merci Marc-L je vais lire tout ça !
23/02/2017, 19h37
davido84

Citation:

Le top du top serait qu'il n'y ait pas de doublon et que les valeurs soient classées

Concernant la gestion des doublons, c'est jouable avec l'utilisation d'une expression rationnelle.
Elle te ramènera les données dans l'ordre d'apparition de la dernière occurrence comme ceci :
04-100
04-130
04-120
04-110
04-140

Par contre, si par classement tu entends "tri", une expression rationnelle ne pourra le faire (ou alors en intégrant le motif dans une boucle mais c'est bancal) donc le plus simple est de les trier dans la feuille de calcul.

A+

1 pièce(s) jointe(s)

Bonjour,

Je me suis créé il y a quelques années une fonction matricielle personnalisée basée sur les expressions rationnelles; ça pourrait être une bonne base de départ pour toi.
Sur l'image, j'ai sélectionné les cases B1 à B11 puis rempli la formule en B1 validée par Ctrl+Maj+Entrée.
ça ne gère pas les doublons et si tu ne connais pas à l'avance le nombre d'éléments attendus, il faut que tu sélectionnes suffisamment de cases où appliquer cette formule matricielle (d'où les #N/A).

A toi d'adapter sous Excel ou VBA selon tes besoins.

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
'Cocher Outils => Références => Microsoft VBScript Regular Expressions 5.5
'Fonction matricielle permettant d'extraire une ou plusieurs infos d'un texte à l'aide d'un "pattern" (motif) basé sur les expressions rationnelles
'Cette fonction renverra la/les info(s) pour toutes les occurrences du pattern dans le texte: une ligne par occurrence; une colonne par info au sein de l'occurrence
'Renvoie #VALEUR si rien n'est trouvé.
Function SplitWithRegExp(str As String, pattern As String)
    Dim regExType As New VBScript_RegExp_55.RegExp
    regExType.pattern = pattern
    regExType.Global = True 'True matches all occurrences, False matches the first occurrence
    Dim matches As VBScript_RegExp_55.matchCollection
    Dim match As VBScript_RegExp_55.match
    Dim subMatch
    Dim tabMatch() 'As String
    Dim i As Long
    Dim j As Long
 
    i = 1
    j = 1
 
'    If regExType.Test(str) Then
    Set matches = regExType.Execute(str)
 
    ReDim tabMatch(1 To matches.Count, 1 To VBA.Len(VBA.Replace(pattern, "\(", "")) - VBA.Len(VBA.Replace(VBA.Replace(pattern, "\(", ""), "(", "")))
 
    For Each match In matches
 
        For Each subMatch In match.SubMatches
           tabMatch(i, j) = subMatch
           j = j + 1
        Next subMatch
        j = 1
        i = i + 1
    Next match
 
    SplitWithRegExp = tabMatch
'    End If
 
    Set regExType = Nothing
    Set matches = Nothing
    Set match = Nothing
    Set subMatch = Nothing
    Erase tabMatch
End Function

Formule en B1:B11:

Code:

=SIERREUR(SplitWithRegExp(A1; "\((\d{2}\-\d{3})\)"); "")

Pièce jointe 247840

24/02/2017, 11h11
Grdcolas

Merci Promethee25 ! Ca marche nickel !
25/02/2017, 10h19
davido84

Pour info, dans le pattern

Code:

"\((\d{2}\-\d{3})\)"

le trait d'union n'a pas besoin d'être échappé : "-" suffit.
D'autre part, un pattern bien pensé t'évitera de récupérer les doublons.

A+
25/02/2017, 10h56
Promethee25

Bonjour,

Oui, pour le "-", je mets toujours le caractère d'échappement car ça m'évite d'avoir à me rappeler s'il est nécessaire ou non. :P
Par contre, pourrais-tu nous expliquer quelle expression rationnelle (interprétable par la librairie VBA) permettrait de se passer des doublons car VBA ne sait pas gérer les éléments les plus complexes des expressions rationnelles donc je ne vois pas.
25/02/2017, 12h38
davido84

Il est vrai que la librairie VBScript Regular Expressions 5.5 utilisable en VBA ne permet pas le traitement d'expression rationnelle que peut offrir un autre langage de programmation.
Néanmoins tu peux t'en tirer dans le cas présent en utilisant les références arrières.

Teste ce pattern :

Code:

\((\d{2}-\d{3})\)(?!(.|\n)*\1)

A+
25/02/2017, 13h03
Promethee25

Intéressant, merci pour l'info.
Je pensais que VBA ne gérait que les parenthèses non capturantes "(?:...)" et aucune autre expression sur base de '(?...)'.
25/02/2017, 22h16
davido84

Non, tu peux utiliser les assertions avant positives (?=) et négatives (?!) à l'intérieur de parenthèses capturantes ou non.

Dans le pattern fourni, tu peux modifier la partie

Code:

(?!(.|\n)*\1)

comme ceci

Code:

(?!(?:.|\n)*\1)

afin de ne pas ramener une sous-correspondance inutile, et cela ne changera rien au rôle du ?!

Par contre, et si j'ai bien compris le but de ta fonction qui est de ramener dans un tableau l'ensemble des sous-correspondances, quelques remarques pèle-mêle :
1) subMatch n'est pas un objet donc la boucle For Each ne me paraît pas appropriée et pas besoin du Set subMatch = Nothing.
2) Pour redimensionner les colonnes de ton tableau tu peux te caler sur le SubMatches.Count du 1er Item de matches.
3) Tu peux passer les propriétés Global, MultiLine et IgnoreCase dans les arguments de ta fonction et les utiliser comme arguments optionnels afin de la rendre adaptable aux différents cas de figure.
4) Erase tabMatch me semble inutile

A+