Séquence dans Toad 11

Quelque chose de ce goût là :

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
grant create sequence to <votre_user>;
 
create table suivi_envoi
( ref_envoi        varchar2(10)
, num_envoi        varchar2( 4)
);
 
create or replace procedure p_create_sequence(sequence_name varchar2)
authid current_user
is
    pragma autonomous_transaction;
 
begin
    execute immediate 'create sequence ' || p_create_sequence.sequence_name || ' nocache nocycle';
 
exception
    when others then
        raise;
 
end;
/
 
create or replace trigger tgbi_suivi_envoi
before insert on suivi_envoi
for each row
declare
    c$_annee_envoi     constant varchar2(  4) := substr(:new.ref_envoi, -4);
    v$_sql                      varchar2(500);
    v$_val_sequence             number(10)     := 0;
    e$_sequence_not_exists      exception;
    pragma exception_init(e$_sequence_not_exists, -2289);
 
begin
    v$_sql := 'select seq_suivi_envoi_' || c$_annee_envoi || '.nextval from dual';
    execute immediate v$_sql into v$_val_sequence;
    :new.num_envoi := to_char(v$_val_sequence, 'fm0000');
 
exception
    when e$_sequence_not_exists then
        p_create_sequence('seq_suivi_envoi_' || c$_annee_envoi);
        v$_sql := 'select seq_suivi_envoi_' || c$_annee_envoi || '.nextval from dual';
        execute immediate v$_sql into v$_val_sequence;
        :new.num_envoi := to_char(v$_val_sequence, 'fm0000');
end;
/

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
select count(*)
  from user_sequences
 where sequence_name like 'SEQ$_SUIVI$_ENVOI%' escape '$';
 
  COUNT(*)
----------
         0
 
select * from suivi_envoi;
-- aucune ligne sélectionnée
 
 
insert into suivi_envoi (ref_envoi) values ('03-10/2016');
insert into suivi_envoi (ref_envoi) values ('03-11/2016');
insert into suivi_envoi (ref_envoi) values ('03-12/2016');
select * from suivi_envoi;
 
REF_ENVOI  NUM_
---------- ----
03-10/2016 0001
03-11/2016 0002
03-12/2016 0003
 
select count(*)
  from user_sequences
 where sequence_name like 'SEQ$_SUIVI$_ENVOI%' escape '$';
 
  COUNT(*)
----------
         1
 
insert into suivi_envoi (ref_envoi) values ('01-01/2017');
insert into suivi_envoi (ref_envoi) values ('01-02/2017');
insert into suivi_envoi (ref_envoi) values ('01-02/2017');
select * from suivi_envoi;
 
REF_ENVOI  NUM_
---------- ----
03-10/2016 0001
03-11/2016 0002
03-12/2016 0003
01-01/2017 0001
01-02/2017 0002
01-02/2017 0003
 
select count(*)
  from user_sequences
 where sequence_name like 'SEQ$_SUIVI$_ENVOI%' escape '$';
 
  COUNT(*)
----------
         2
 
rollback;
-- Annulation (rollback) terminée.
 
select * from suivi_envoi;
-- aucune ligne sélectionnée
 
select count(*)
  from user_sequences
 where sequence_name like 'SEQ$_SUIVI$_ENVOI%' escape '$';
 
  COUNT(*)
----------
         2

Après je ne suis pas complètement fan de la solution, je pense que mnitu aurait a y redire.