[awk] Calcul moyennes de temps

Version imprimable

23/12/2016, 16h46
karon

[awk] Calcul moyennes de temps

Bonjour,

J'ai un fichier sous cette forme

NOMA,00:00:23
NOMB,00:20:00
NOMC,02:00:00
NOMA,02:10:12
NOMB,03:40:30

J'aimerais trouver avec la commande awk le moyen d'obtenir un fichier sous cette forme :

NOMA,temps_moyen
NOMB,temps_moyen
NOMC,temps_moyen

Merci par avance et Joyeuses Fêtes...
23/12/2016, 17h54
N_BaH

Bonjour,

tu dois créer un tableau qui prendra le premier champ en indice, et qui prendra l'addition des heures, minutes (converties en secondes) et les secondes en valeur.
à la fin (END) du script awk, il faut afficher chaque indice du tableau, et convertir en heures:minutes:secondes le total des secondes.

Un exemple

Voici le code auquel je suis arrivé :

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
 
#!/bin/sh
 
awk 'BEGIN {
     FS=";"}
     {if ($1 in A)
        {
         split($2,sec,":");
         second[$1]=second[$1]+sec[1]*3600+sec[2]*60+sec[3];
         cpt[$1]++;
         next;
        }
     else
        {
         split($2,sec,":");
         second[$1]=second[$1]+sec[1]*3600+sec[2]*60+sec[3];
         traitement[$1]=$1;
         cpt[$1]++;
        }
     A[$1]=""}
     END {
         for (x in A) {
         tmp=second[x]/cpt[x];
         printf "%s;%02d:%02d:%02d\n", traitement[x], int(tmp/3600), int(tmp/60%60), int(tmp%60);
        }
        }
     ' liste.20161223

J'aimerais avoir vos remarques...

24/12/2016, 04h54
N_BaH

je ne comprends pas l'intérêt des tableaux A (et donc de la condition d'existence de $1 dans ce tableau), et traitement.
il devrait suffire de travailler avec les tableaux second, et cpt.

vu qu'il n'y a que du awk, tu peux changer le shebang pour #!/usr/bin/awk -f, et adapter légèrement le script; le nom du fichier sera passé en argument.
24/12/2016, 12h20
karon

Merci

Merci pour les infos.

Pour le shebang, cela vient du fait que c'est une toute petite partie d'un script plus important.

Pour le tableau, là j'aurais besoin d'un petit exemple.

Encore merci 😊

Bonjour,

Voici une idée, reste plus qu'a inclure la partie transformation en seconde, pour l'addition, et la conversion en heure avant affichage:
Code:

1 2 3 4 5 6 7 8 9 10 $ cat /tmp/file1.txt NOMA,23 NOMB,20 NOMC,02 NOMA,12 NOMB,40 $ awk -F\, '{A[$1]++;B[$1]+=$2}END{OFS=FS;for (i in A){print i,B[i]/A[i]}}' /tmp/file1.txt NOMA,17.5 NOMB,30 NOMC,2

salut,

le même genre de solution, mais avec la moyenne sous forme horaire :

Code:

1
2
3
4
awk -F',' '{nb[$1]++; "date -u +%s -d \"01/01/1970 " $2 " +0000\"" |& getline z; val[$1]+=z} END {for(i in nb){v=val[i]/nb[i]; "date -u +%H:%M:%S -d@" v |& getline z; print i "," z}}' fichier
NOMA,01:05:17
NOMB,02:00:15
NOMC,02:00:00

la version dépliée :

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
{
   nb[$1]++;
   "date -u +%s -d \"01/01/1970 " $2 " +0000\"" |& getline z;
   val[$1] += z
}
 
END {
   for (i in nb) {
      v = val[i] / nb[i];
      "date -u +%H:%M:%S -d@" v |& getline z;
      print i "," z
   }
}

...et par avance un bon réveillon à tous ;)

Bon, ok, tout en gnu awk (sinon pas marrant :aie: ) :

Code:

1
2
3
4
5
6
$ cat /tmp/file1.txt 
NOMA,00:00:23
NOMB,00:20:00
NOMC,02:00:00
NOMA,02:10:12
NOMB,03:40:30

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
$ cat /tmp/awkfile1.sh 
#!/bin/sh
TZ=UTC awk -F\, '{
	gsub(/:/," ",$2)
	A[$1]++
	B[$1]+=strftime("%s",mktime("1970 01 01 "$2))
}
END{
	OFS=FS
	for (i in A){
		print i,strftime("%H:%M:%S",B[i]/A[i])
	}
}' /tmp/file1.txt

Code:

1
2
3
4
$ /tmp/awkfile1.sh 
NOMA,01:05:17
NOMB,02:00:15
NOMC,02:00:00

Bonne Fête à tous.

24/12/2016, 15h36
BufferBob

Citation:

Envoyé par disedorgue

Bon, ok, tout en gnu awk (sinon pas marrant :aie: )

en plus d'être faux ouai, j'avais des résultats incohérents pour avoir oublié le -u à date :aie: